Hi, i'm trying to dynamically set the "beginresponsetime"-property, but the following doesn't seem to work. The debug-window will show 500, but the time used is 1000.

<values>
/ ast = 500
</values> 

<trial testtrial>
/ responsetime = 1000
/ ontrialbegin = [trial.testtrial.beginresponsetime = values.ast]
</trial> 

Can you help me with that? Thank you.

Dynamically setting that property / changing it at runtime currently does not work. Thus you need to pursue a different approach. You can achieve the same thing by using the /isvalidresponse attribute:

<values>
/ ast = 0
</values>

<trial testtrial>
/ ontrialbegin = [values.ast = noreplace(2000,2000,4000,4000)]
/ stimulustimes = [0=debug; 2000=a; 4000=b]
/ isvalidresponse = [trial.testtrial.latency>=values.ast]
/ validresponse = (57)
/ responsetime = 0
</trial>

<block myblock>
/ trials = [1-4=testtrial]
</block>
 
<text a>
/ items = ("2000 ms elapsed")
</text>

<text b>
/ items = ("4000 ms elapsed")
</text>

<text debug>
/ items = ("Response will be accepted after <%values.ast%> ms.")
/ position = (50%, 10%)
</text>

Regards,

~Dave

That did it.

Thank you very much for the fast reply.