By sunm - 12/20/2013
Hello,
I'm attempting to create a Reading The Eyes of the Mind task, where a picture of a pair of eyes shows up on screen, and the user is given 4 emotion words at each corner (upper-left, upper-right, lower-left, lower-right) and are told to infer the emotion being expressed through the eyes. E.G. Below:
  So I have a set of <items> of 36 pictures, and 4 sets of <text> for upper-left text, upper-right, lower-left, and lower-right as answer choices. There are correct answers. The issue is, if I want to randomize the trials, I don't have a way of guaranteeing that: 1. The set of 4 text answer choices (arrogant/grateful/sarcastic/tentative for picture 1; dominant/friend/guilty/horrified for picture 2) will always be grouped together. 2. The set of 4 text answer choices will be grouped with its corresponding picture.
Any help on this? Thank you!
|
By Dave - 12/20/2013
See the "How to present stimulus pairs" topic in the documentation. Of course, this not only applies to literal "pairs" but any number of to-be-grouped stimuli.
|
By sunm - 12/20/2013
Great, thanks Dave. That answers my original 2 questions. Now the four words show up consistently with their corresponding picture.
However, the correct response needs to be tied to the text and pictures as well. Is there a way for Inquisit to do this without having to make a separate trial object for every set of stimuli (words+picture)? |
By Dave - 12/20/2013
Yes, in exactly the same way. Encode the correct responses in e.g. a <list> element or <counter>, link it to the stimuli and validate via the <trial>'s /iscorrectresponse attribute:
<block myblock>
/ trials = [1-2=mytrial]
</block>
<trial mytrial>
/ stimulusframes = [1=mypicture, word1, word2, word3, word4]
/ inputdevice = mouse
/ validresponse = (word1, word2, word3, word4)
/ iscorrectresponse = [trial.mytrial.response == list.cresp.nextvalue]
</trial>
<picture mypicture>
/ items = ("A.jpg", "B.jpg")
/ select = noreplace
/ size = (25%, 25%)
</picture>
<text word1>
/ items = ("A1", "B1")
/ select = picture.mypicture.currentindex
/ position = (20%, 10%)
</text>
<text word2>
/ items = ("A2", "B2")
/ select = picture.mypicture.currentindex
/ position = (80%, 10%)
</text>
<text word3>
/ items = ("A3", "B3")
/ select = picture.mypicture.currentindex
/ position = (20%, 90%)
</text>
<text word4>
/ items = ("A4", "B4")
/ select = picture.mypicture.currentindex
/ position = (80%, 90%)
</text>
<list cresp>
/ items = ("word1", "word4")
/ selectionmode = picture.mypicture.currentindex
</list>
|
|