By SpoHo - 2/2/2014
Hi!
In my project I'm testing 4 Brands (represented by logos) and 12 Attributes. I want to test each brand in combination with all of the 12 Attributes - but in a random order.
I looked at the example of presnting pairs of stimuli, but I couldn't make the transfer to my problem. Do you have any hints for me?
|
By Dave - 2/2/2014
You'll have to provide more details about your procedure first.
"In my project I'm testing 4 Brands (represented by logos) and 12 Attributes.I want to test each brand in combination with all of the 12 Attributes - but in a random order."The above description does not allow anyone to actually infer what you are trying to do.
|
By SpoHo - 2/2/2014
Allright, sorry!
I attached a picture how my test looks like.
Logos and attributes are selected randomly. I want that each attribute is being tested with each logo - exactly one time (12 x 4 = 48 trials).
Thanks again for your quick response! |
By Dave - 2/2/2014
This should be fairly easy:
<block myblock>
/ trials = [1-48=mytrial]
</block>
<trial mytrial>
/ stimulusframes = [1=mybrand, myattribute]
/ trialduration = 100
</trial>
<text mybrand>
/ items = branditems
/ select = list.branditemlist.nextvalue
/ position = (50%, 40%)
</text>
<text myattribute>
/ items = attributeitems
/ select = list.attributeitemlist.nextvalue
/ position = (50%, 60%)
</text>
<item branditems>
/ 1 = "Brand 1"
/ 2 = "Brand 2"
/ 3 = "Brand 3"
/ 4 = "Brand 4"
</item>
<item attributeitems>
/ 1 = "Attribute 1"
/ 2 = "Attribute 2"
/ 3 = "Attribute 3"
/ 4 = "Attribute 4"
/ 5 = "Attribute 5"
/ 6 = "Attribute 6"
/ 7 = "Attribute 7"
/ 8 = "Attribute 8"
/ 9 = "Attribute 9"
/ 10 = "Attribute 10"
/ 11 = "Attribute 11"
/ 12 = "Attribute 12"
</item>
<list branditemlist>
/ items = (1,1,1,1,1,1,1,1,1,1,1,1,
2,2,2,2,2,2,2,2,2,2,2,2,
3,3,3,3,3,3,3,3,3,3,3,3,
4,4,4,4,4,4,4,4,4,4,4,4)
/ selectionmode = random
</list>
<list attributeitemlist>
/ items = (1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12)
/ selectionmode = list.branditemlist.currentindex
</list>
|
By SpoHo - 2/2/2014
that works like a charm thank you!! :)
I don't want my participants to get tired during the experiment during the test, so i thought of splitting the test into 3 blocks of 15, 15 and 18 trials.
Would it be possible to keep the randomization up over the different blocks?
|
By Dave - 2/2/2014
> Would it be possible to keep the randomization up over the different blocks?
Yes. You'll want to refer to the documentation on the <list> element's /resetinterval attribute.
|
By SpoHo - 2/2/2014
I'm sorry - I don't get it.
We are busines customers of yours, and we need to set this project up by tomorrow so I hope you can help me out on this :(
|
By Dave - 2/2/2014
<expt myexpt>
/ blocks = [1=myblock1; 2=myblock2; 3=myblock3]
</expt>
<block myblock1>
/ trials = [1-15=mytrial]
</block>
<block myblock2>
/ trials = [1-15=mytrial]
</block>
<block myblock3>
/ trials = [1-18=mytrial]
</block>
<trial mytrial>
/ stimulusframes = [1=mybrand, myattribute]
/ trialduration = 100
</trial>
<text mybrand>
/ items = branditems
/ select = list.branditemlist.nextvalue
/ position = (50%, 40%)
</text>
<text myattribute>
/ items = attributeitems
/ select = list.attributeitemlist.nextvalue
/ position = (50%, 60%)
</text>
<item branditems>
/ 1 = "Brand 1"
/ 2 = "Brand 2"
/ 3 = "Brand 3"
/ 4 = "Brand 4"
</item>
<item attributeitems>
/ 1 = "Attribute 1"
/ 2 = "Attribute 2"
/ 3 = "Attribute 3"
/ 4 = "Attribute 4"
/ 5 = "Attribute 5"
/ 6 = "Attribute 6"
/ 7 = "Attribute 7"
/ 8 = "Attribute 8"
/ 9 = "Attribute 9"
/ 10 = "Attribute 10"
/ 11 = "Attribute 11"
/ 12 = "Attribute 12"
</item>
<list branditemlist>
/ items = (1,1,1,1,1,1,1,1,1,1,1,1,
2,2,2,2,2,2,2,2,2,2,2,2,
3,3,3,3,3,3,3,3,3,3,3,3,
4,4,4,4,4,4,4,4,4,4,4,4)
/ selectionmode = random
/ resetinterval = 0
</list>
<list attributeitemlist>
/ items = (1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12,
1,2,3,4,5,6,7,8,9,10,11,12)
/ selectionmode = list.branditemlist.currentindex
</list>
|
By SpoHo - 2/3/2014
Thank you so much Dave. Our Project is running fine now!
|
|