Millisecond Forums

Slider Element Start Position

https://forums.millisecond.com/Topic13806.aspx

By JRB - 7/17/2014

Hi,
I am using the slider element in my Inquisit script to get some participant ratings. I was wondering if there was any way to force the slider itself (i.e. the part you move to indicate your response on the scale) to start in the "0" position? At this point, the survey opens with the slider at the midpoint of the scale. In the example below it is not a HUGE issue, but is is when I have an a 'range' of 1-4, and the slider is automatically positioned at 3 (which could would bias responses).

Is there something simple I am missing to fix this?

<slider Lazy>
/ caption = "Lazy:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Sloppy>
/ caption = "Sloppy:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Motivated>
/ caption = "Motivated:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider PPH>
/ caption = "Poor personal hygeine:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider OverIndulgent>
/ caption = "Over-indulgent:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider SelfDisciplined>
/ caption = "Self-disciplined:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<surveypage NOS>
/caption = "Please indicate the extent to which you the believe each of the following characteristics describes the patient by moving the markers to the appropriate places on the lines below:"
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ questions = [1=Lazy; 2=Sloppy; 3=Motivated; 4=PPH; 5=OverIndulgent; 6=SelfDisciplined]
/ response = free
</surveypage> 

<survey NOSSurvey>
/ pages = [1=NOS]
/ itemspacing = 2%
/ response = anyresponse 
/ recorddata = true
/ showpagenumbers = false
/ showquestionnumbers = false
/ nextbuttonposition = (90,90)
</survey>

I would also like to know if there is a way to present an image for a specific amount of time (e.g., 4 seconds), and then once that time has elapsed, to have some text automatically appear on the same page as the image (this might be to vague for anyone to answer) - I've been looking into it, but have been unsuccessful so far. 

Thank you for any help!

Jo
By Dave - 7/17/2014

> I was wondering if there was any way to force the slider itself (i.e. the part you move to indicate your response on the scale) to start in the "0" position?

Yes, via the <slider> element's /defaultresponse attribute:

<slider q1>
/ caption="How do you feel about bananas?"
/ defaultresponse = "0"
/ labels=("Cold", "Hot")
/ range = (0, 4)
/ increment = 1
</slider>

> I would also like to know if there is a way to present an image for a specific amount of time (e.g., 4 seconds), and then once that time has elapsed, to have some text automatically appear on the same page as the image

You would do so using the <trial> element's /stimulustimes attribute:

<trial mytrial>
/ stimulustimes = [0=mypicture; 4000=mytext]
...
</trial>
By JRB - 7/17/2014

Thanks! That all works fine now. 
With the "/ stimulustimes = [0=mypicture; 4000=mytext]" you suggested though, is there a way to have a "Next" button at the end? For example, I want participants to see an image for only 4 seconds, then the text pops up (which is working), but I want them to be able to read this text for as long as they need, and then move forward when they are ready (rather than having something like an automatic timeout or trialduration which will force them to move on). 

I haven't been able to find a way to do this using this attribute yet. 
By Dave - 7/17/2014

Yes. Simply set up a simple <text> element to serve as your "Next" button, display it along with the other stimuli and define it as the <trial>'s expected response

<trial mytrial>
/ stimulustimes = [0=mypicture; 4000=mytext, mynextbutton]
/ inputdevice = mouse
/ validresponse = (mynextbutton)
...
</trial>
By JRB - 7/21/2014

Perfect. Thank you.

The way the script is now, my blocks (and trials) are not randomised - they are simply presented in the order of the exp1 exp2 etc. Now, I am trying to randomise "targetblock1", "targetblock2" "targetblock3". When I have a go at changing the script myself I can easily get the blocks to randomise, but not without replacement - so the blocks repeat themselves in different orders instead of presenting the 3 of them in random order (e.g., sometimes it might show targetblock1 followed by targetblock3 followed by targetblock1). So far, I have tried to use "resetinterval", but I haven't had any luck. How can I get my script to randomise in the way I want?

Hopefully I have explained myself properly. Let me know if I am not making sense :) 

I've included my whole script if you need to have a look at it (which doesn't include my attempts to randomise):

******************************************************************************
Instructions
******************************************************************************

<page intro>
^^^Welcome to our study of the Neural Processing of Doctor-Patient Interactions.
^^^Thank you for participating.
^^^Please click NEXT to continue.
</page>

<page intro1>
^During this study, you will be asked to read some descriptions which summarise a conversation between a doctor and a patient during a routine check-up, and then, to view an image of each patient on the computer screen. Finally, you will be asked to complete some self-report questionnaires about all the information you viewed.
^^^Physiological signals will be recorded from your head throughout this task. 
^^^Please click NEXT to receive more instructions.
</page>

<page intro2>
^^In moment, you will be asked to read the first description summarising a conversation between a doctor and a patient, and to view an image of this patient.
^^^Please try to keep your eyes focused on the screen throughout this task.
^^^When you are ready, please click NEXT to begin. 
</page>

<page intro4>
^^In a moment, you will be asked to read another description summarising a conversation between a doctor and a different patient, and to view an image of this patient. 
^^^All instructions will appear on the screen in front of you.
^^^When you are ready, please click NEXT to begin.
</page>

<page test>
^^^You will now be asked to mimic the facial expressions of people in different images.
^^^It is important that you hold your eyes on the image and follow the instructions until the image disappears. 
^^^Please click NEXT to view and mimic the first image. 
</page>

<page end>
^^^This is the end of the this phase of the study.
^^^Please click NEXT to exit the study and then let the experimenter know you have finished. The experimenter will then set up the final stage of the study, where you will be asked to complete some final questionnaires about yourself.
^^^Thank you!
</page>

<instruct>
/ fontstyle = ("Ariel", 5%)
/ inputdevice = mouse
/ nextlabel = ("Next")
/ prevkey = (noresponse)
/ txcolor = (0, 0, 0)
/ windowsize = (100%, 100%)
</instruct>

*************************************************************
TTL Parallel Signal
*************************************************************
<port targetsignal1>
/ port = lpt1
/ subport = data
/ items = ("00000001")
/ erase = false
/ select = picture.targetpic1.currentindex
</port>

<port targetsignal2>
/ port = lpt1
/ subport = data
/ items = ("00000010")
/ erase = false
/ select = picture.targetpic2.currentindex
</port>

<port targetsignal3>
/ port = lpt1
/ subport = data
/ items = ("00000100")
/ erase = false
/ select = picture.targetpic3.currentindex
</port>

*************************************************************
Items
*************************************************************

<shape targetWhite>
/color = (white)
/position = (50, 50)
/ size = (80%, 80%)
</shape>

<picture targetPic1>
/ items = targetPicItem1
/ position = (20, 50)
/ size = (70%, 70%)
/ select = noreplace
</picture>

<item targetPicItem1>
/ 1 = "obesewoman3.jpg"
</item>

<picture targetPic2>
/ items = targetPicItem2
/ position = (20, 50)
/ size = (70%, 70%)
/ select = noreplace
</picture>

<item targetPicItem2>
/ 1 = "obesewoman4.jpg"
</item>

<picture targetPic3>
/ items = targetPicItem3
/ position = (20, 50)
/ size = (70%, 70%)
/ select = noreplace
</picture>

<item targetPicItem3>
/ 1 = "normalwoman2.jpg"
</item>

<item TargetPic5Items>
/ 1 = "SmileTest.jpg"
/ 2 = "FrownTest.jpg"
/ 3 = "DisgustTest.jpg"
</item>

<picture TargetPic5>
/ items = targetPic5Items
/ position = (50, 50)
/ size = (65%, 65%)
/ select = sequence
</picture>

*************************************************************
Description1
*************************************************************

<item description>
/ 1 = "NoEffortDescription.jpg"
</item>

<picture description1>
/ items = description
/ position = (60, 50)
/ size = (50%, 50%)
/ select = noreplace
</picture>

*************************************************************
Description2
*************************************************************
<item descriptionB>
/ 1 = "LongTermEffortDescription.jpg"
</item>

<picture description2>
/items = descriptionB
/position = (60, 50)
/ size = (70%, 70%)
/ select = noreplace
</picture>

*************************************************************
Next Button
*************************************************************
<text nextbutton>
/ items = ("Next")
/ txcolor = (0, 0, 0)
/ txbgcolor = (200, 200, 200)
/ fontstyle = ("Ariel", 25)
/ position = (95, 95)
</text>

<text descriptioncaption1>
/ items = ("Read the following information about the patient carefully before clicking NEXT to continue:")
/ txcolor = (0, 0, 0)
/ txbgcolor = (transparent)
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ position = (61, 15)
</text>

<text descriptioncaption2>
/ items = ("Read the following information about the patient carefully before clicking NEXT to continue:")
/ txcolor = (0, 0, 0)
/ txbgcolor = (transparent)
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ position = (58, 10)
</text>

<text intro3>
/ items = ("You will now be asked to complete some questions about the all of the
information you just viewed about the patient.


All instructions will appear on the screen in front of you.


When you are ready, please click NEXT to begin.")
/ txcolor = (0, 0, 0)
/ txbgcolor = (transparent)
/ fontstyle = ("Ariel", 5%)
/ position = (45, 50)
</text>

***************************************************************************
Survey Page Emotions Slider
***************************************************************************

<slider Disgust>
/ caption = "Disgust:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Anger>
/ caption = "Anger"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Contempt>
/ caption = "Contempt"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Pity>
/ caption = "Pity:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Sympathy>
/ caption = "Sympathy:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<surveypage Emotions>
/caption = "Please indicate how much you feel the following emotions toward the patient by moving the markers to the appropriate places on the line below:"
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ questions = [1=Disgust; 2=Anger; 3=Contempt; 4=Pity; 5=Sympathy]
/ response = free
</surveypage> 

<Survey EmotionSurvey>
/ pages = [1=Emotions]
/ itemspacing = 5%
/ response = anyresponse 
/ recorddata = true
/ showpagenumbers = false
/ showbackbutton = false
/ showquestionnumbers = false
/ nextbuttonposition = (90,90)
/ finishlabel = "Next"
</survey>

 
**************************************************************
NOS Stereotypes
**************************************************************
<slider Lazy>
/ caption = "Lazy:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Sloppy>
/ caption = "Sloppy:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider Motivated>
/ caption = "Motivated:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider PPH>
/ caption = "Poor personal hygeine:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider OverIndulgent>
/ caption = "Over-indulgent:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<slider SelfDisciplined>
/ caption = "Self-disciplined:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Not at all", "Extremely")
/ range = (0, 100)
/ defaultresponse = "0"
/ increment = 10
/ slidersize = (50, 5)
/ showtooltips = true
/ required = false
</slider>

<surveypage NOS>
/caption = "Please indicate the extent to which you the believe each of the following characteristics describes the patient by moving the markers to the appropriate places on the lines below:"
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ questions = [1=Lazy; 2=Sloppy; 3=Motivated; 4=PPH; 5=OverIndulgent; 6=SelfDisciplined]
/ response = free
</surveypage> 

<survey NOSSurvey>
/ pages = [1=NOS]
/ itemspacing = 2%
/ response = anyresponse 
/ recorddata = true
/ showpagenumbers = false
/ showbackbutton = false
/ showquestionnumbers = false
/ nextbuttonposition = (90,90)
/ finishlabel = "Next"
</survey>

***************************************************************************
SDS 
***************************************************************************
<slider SDS1>
/ caption = "Renting a room in your home to the patient:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS2>
/ caption = "Working on the same project as the patient:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS3>
/ caption = "Having the patient as your neighbor:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS4>
/ caption = "Having the patient care for your children for a couple of hours:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS5>
/ caption = "Having a family member marry the patient:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS6>
/ caption = "Introducing the patient to a friend of yours:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<slider SDS7>
/ caption = "Recommending the patient for a job for a friend:"
/fontstyle = ("Ariel", 16, true, false, false, false, 5, 0)
/labels = ("Definitely Unwilling", "Probably Unwilling", "Probably Willing", "Definitely Willing")
/ range = (1, 4)
/ defaultresponse = "1"
/ increment = 4
/ slidersize = (50, 5)
/ showtooltips = false
/ required = false
</slider>

<surveypage SDSA>
/caption = "Please indicate the extent to which you would be willing or unwilling to engage in the following situations using the scales below:"
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ questions = [1=SDS1; 2=SDS2; 3=SDS3; 4=SDS4]
/ response = free
</surveypage> 

<surveypage SDSB>
/caption = "Please indicate the extent to which you would be willing or unwilling to engage in the following situations using the scales below:"
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
/ questions = [1=SDS5; 2=SDS6; 3=SDS7]
/ response = free
</surveypage> 

<survey SDSSurvey>
/ pages = [1=SDSA; 2=SDSB]
/ itemspacing = 12%
/ response = anyresponse 
/ recorddata = true
/ showpagenumbers = false
/ showbackbutton = false
/ showquestionnumbers = false
/ nextbuttonposition = (90,90)
/ finishlabel = "Next"
</survey>


********************************************************************************
Recognise
********************************************************************************

<dropdown RecogniseQuestion> 
/caption = "Do you recognise the person in the image you just viewed from other places besides this study (e.g. the internet, TV, magazines)?"
/options = ("yes", "no")
/position = (9, 10) 
/ fontstyle = ("Ariel", 20, true, false, false, false, 5, 0)
</dropdown>

<surveypage Recognise1>
/questions = [1=RecogniseQuestion]
</surveypage>

<survey RecogniseSurvey>
/ pages = [1=Recognise1]
/ response = anyresponse 
/ recorddata = true
/ showpagenumbers = false
/ showbackbutton = false
/ showquestionnumbers = false
/ nextbuttonposition = (90,90)
/ finishlabel = "Next"
</survey>

***************************************************************************
Electrode Signal Test
***************************************************************************

<caption relaxinstruct1>
/caption = "                                Please RELAX your face."
/subcaption = "


In a moment, an image will appear on the screen. Remain relaxed until this image appears."
/ fontstyle = ("Ariel", -40, true, false, false, false, 5, 0)
/position = (10, 30) 
</caption>

<caption relaxinstruct2>
/caption = "Please RELAX your face."
/ fontstyle = ("Ariel", -40, true, false, false, false, 5, 0)
/position = (35, 50) 
</caption>

<caption smileinstruct>
/caption = "Please mimic this image by making your BIGGEST SMILE possible. HOLD THIS EXPRESSION until the image disappears."
/position = (10, 10) 
</caption> 

<caption frowninstruct>
/caption = "Please mimic this image by FROWNING (do this by moving your eyebrows downward). HOLD THIS EXPRESSION until the image disappears."
/position = (10, 10) 
</caption> 

<caption noseinstruct>
/caption = "Please mimic this image by WRINKLING your NOSE UPWARD. HOLD THIS EXPRESSION until the image disappears."
/position = (10, 10) 
</caption> 

<surveypage Smile>
/questions = [1=smileinstruct] 
/stimulusframes = [1=TargetPic5]
/timeout = 8000 
</surveypage>

<surveypage Frown>
/questions = [1=frowninstruct] 
/stimulusframes = [1=TargetPic5]
/timeout = 8000
</surveypage>

<surveypage Nose>
/questions = [1=Noseinstruct] 
/stimulusframes = [1=TargetPic5]
/timeout = 8000 
</surveypage>

<surveypage Relax1>
/ questions = [1=relaxinstruct1]
/timeout = 10000
</surveypage>

<surveypage Relax2>
/ questions = [1=relaxinstruct2]
/timeout = 10000
</surveypage>


******************************************************************
Test Survey
******************************************************************

<Survey TestSurvey>
/ pages = [1=Relax1; 2=Smile; 3=Relax1; 4=Frown; 5=Relax2; 6=Nose; 7=Relax2]
/ responsefontstyle = ("Ariel", -30, true, false, false, false, 5, 0)
/ itemfontstyle = ("Ariel", -30, true, false, false, false, 5, 0)
/ itemspacing = 2%
/ showpagenumbers = false
/ showquestionnumbers = false 
/ showbackbutton = false
/ nextbuttonposition = (100, 100) 
/ nextlabel = "Next"
</survey> 

******************************************************************
Trials
******************************************************************

<trial targettrial1>
/ stimulustimes = [0= targetwhite; 4000=targetPic1, targetsignal1; 8000=description1; 8000=descriptioncaption1; 8000=nextbutton]
/ inputdevice = mouse
/ validresponse = (nextbutton)
</trial>

<trial targettrial2>
/ stimulustimes = [0= targetwhite; 4000=targetPic2, targetsignal2; 8000=description2; 8000=descriptioncaption2; 8000=nextbutton]
/ inputdevice = mouse
/ validresponse = (nextbutton)
</trial>

<trial targettrial3>
/ stimulustimes = [0= targetwhite; 4000=targetPic3, targetsignal3; 8000=nextbutton]
/ inputdevice = mouse
/ validresponse = (nextbutton)
</trial>

<trial intro3trial>
/stimulustimes = [0=intro3; 0=nextbutton]
/ inputdevice = mouse
/ validresponse = (nextbutton)
</trial>

******************************************************************
   Blocks
******************************************************************

<block targetblock1>
/trials = [1=targettrial1; 2=intro3trial]
</block>

<block targetblock2>
/trials = [1=targettrial2; 2=intro3trial]
</block>

<block targetblock3>
/trials = [1=targettrial3; 2=intro3trial]
</block>

***********************************************************************
  Experiment
***********************************************************************
<expt 1>
/preinstructions = (intro, intro1, intro2)
/blocks = [1=targetblock1; 2=EmotionSurvey; 3=NOSSurvey; 4=SDSSurvey; 5=RecogniseSurvey]
/recorddata = true
</expt>

<expt 2>
/preinstructions = (intro4)
/blocks = [1=targetblock2; 2=EmotionSurvey; 3=NOSSurvey; 4=SDSSurvey; 5=RecogniseSurvey]
/recorddata = true
</expt>

<expt 3>
/preinstructions = (intro4)
/blocks = [1=targetblock3; 2=EmotionSurvey; 3=NOSSurvey; 4=SDSSurvey; 5=RecogniseSurvey]
/recorddata = true
</expt>

<expt 4>
/preinstructions = (test)
/blocks = [1=testsurvey]
/postinstructions = (end)
</expt>
By Dave - 7/21/2014

JRB,

<expt> elements aren't <block>s. You don't randomize <expt> elements. Instead you use an <expt> element's /blocks attribute to randomize the <block>s it runs, as in

<expt>
/ blocks = [1-3=noreplace(blocka, blockb, blockc)]
...
</expt>

or

<expt>
/ blocks = [1,3,5=noreplace(blocka, blockb, blockc); 2,4,6=noreplace(blockd, blocke, blockf)]
...
</expt>

etc.

all of which you will find documented in the language reference for the /blocks attribute.
By JRB - 7/21/2014

Wow, that was so much simpler than I expected. Thanks again!