By Pawel Wisniewski - 2/2/2015
Hello.
My name is Pawel Wisniewski and I come from Poland. I am a student from The University of SociaI Sciences and Humanities and I am writing my master thesis. I am going to conduct a survey in which people will judge the pictures on 5 point Likert scale (from huge emotion to small). I want to use 30 negative pictures, 30 positive, 30 neutral and 5, at the beginning, as a training (without the score). Every emotion (positive/negative/neutral) shouldn't be presented more then 2 times in a row. Every picture should be shown on the screen for 2-3 seconds and after that the examined person should be allowed to judge that picture.
Could someone help me to write or adapt a proper script? I will appreciate for any help...
|
By Dave - 2/2/2015
Set up three <likert> elements -- one for good, one for bad, one for neutral -- as well as three <picture> elements (good, bad, neutral) with 30 items each. Use a <list> for trial-selection to impose the "no more than 2 times the same emotion in a row" constraint. In a nutshell:
<block testblock>
/ trials = [1-90 = list.triallist]
</block>
<list triallist>
/ items = (likert.goodlikert, likert.badlikert, likert.neutrallikert)
/ poolsize = 90
/ maxrunsize = 2
</list>
<likert goodlikert>
/ stimulustimes = [0=goodpic]
/ anchors = [1="good"; 3="neutral"; 5="bad"]
/ numpoints = 5
/ beginresponsetime = 3000
/ position = (50%, 75%)
</likert>
<likert badlikert>
/ stimulustimes = [0=badpic]
/ anchors = [1="good"; 3="neutral"; 5="bad"]
/ numpoints = 5
/ beginresponsetime = 3000
/ position = (50%, 75%)
</likert>
<likert neutrallikert>
/ stimulustimes = [0=neutralpic]
/ anchors = [1="good"; 3="neutral"; 5="bad"]
/ numpoints = 5
/ beginresponsetime = 3000
/ position = (50%, 75%)
</likert>
<picture goodpic>
/ items = gooditems
</picture>
<picture badpic>
/ items = baditems
</picture>
<picture neutralpic>
/ items = neutralitems
</picture>
<item gooditems>
/ 1 = "good01.jpg"
...
/ 30 = "good30.jpg"
</item>
<item baditems>
/ 1 = "bad01.jpg"
...
/ 30 = "bad30.jpg"
</item>
<item neutralitems>
/ 1 = "neutral01.jpg"
...
/ 30 = "neutral30.jpg"
</item>
All you need to do in addition is add the things for your 5-item practice block. You should be able to do that after working through the tutorials included in the Inquisit documentation.
|
By Wisniewski Pawel - 2/4/2015
Hi, buddy. It works!!!! You have saved my time. I appreciate that. You're great!!!
|
By Dave - 2/4/2015
Glad to hear it's working!
|
|