By tecnika - 11/22/2015
Hi,
I am quite new to Inquisit and I don't know all the functions. I am trying to programme a Negative Priming Stroop task, where the word is the colour of the ink of the next word. In other words the ink colour is determined by the previous word. The words need to be randomised as the ink colour of the first word. Any idea how to record the position of a random sequence and use it as variable for the selection of the ink colour?
Many thanks,
Elena
|
By Dave - 11/22/2015
You can select a random display (i.e. ink) color at the start of the block and then move on from there according to the *word* selected. A minimal example follows below:
<values>
/ displaycolor = 1
</values>
*** randomly select 1 out of 4 display colors at the start of the block ***
<block myblock>
/ screencolor = (black)
/ onblockbegin = [values.displaycolor=noreplace(1,2,3,4);
text.mytext.textcolor=list.displaycolor.nextvalue; ]
/ trials = [1-4=mytrial]
</block>
*** at the end of the trial set display color for the next trial according to the *word* item selected in current trial ***
<trial mytrial>
/ ontrialend = [values.displaycolor=text.mytext.currentindex;
text.mytext.textcolor=list.displaycolor.nextvalue; ]
/ stimulusframes = [1=mytext]
/ validresponse = (57)
/ posttrialpause = 500
</trial>
<list displaycolor>
/ items = (red, green, blue, yellow)
/ selectionmode = values.displaycolor
</list>
<text mytext>
/ items = myitems
/ fontstyle = ("Arial", 10%, true)
/ txbgcolor = (black)
</text>
<item myitems>
/ 1 = "Red"
/ 2 = "Green"
/ 3 = "Blue"
/ 4 = "Yellow"
</item>
|
By tecnika - 11/22/2015
Thank you very much!!
|
|