By Lucie1043 - 12/8/2015
Hi,
I am trying to program a matching to sample task on Inquisit 4. The procedure is as follows :
in a matching to sample trial, a sample stimulus "A1" (e.g. the word red) is presented in the upper middle section of the screen with three comparison stimuli "B1" (e.g. color BLUE), "B2" (e.g. color RED), "B3" (e.g. color GREEN). In this example, the partcipant is expected to select stimulus B2 in the presence of stimulus A1
The comparison stimuli are presented in the lower left, lower middle and lower right portions of the screen. They are randomly positioned.
How should I write the script in order to have the comparison stimuli randomly positioned and one of the comparison stimuli always matching the sample stimulus?
I would really appreciate your help with this matter!
Lucie
|
By Dave - 12/8/2015
In essence, you do something along the following lines:
<block myblock>
/ trials = [1-3=matchtrial]
</block>
<trial matchtrial>
/ ontrialend = [list.nomatch.reset(); ]
/ stimulusframes = [1=a, b_match, b_nomatch1, b_nomatch2]
/ inputdevice = mouse
/ validresponse = (b_match, b_nomatch1, b_nomatch2)
/ correctresponse = (b_match)
</trial>
<text a>
/ items = aitems
/ position = (50%, 10%)
</text>
<item aitems>
/ 1 = "RED"
/ 2 = "GREEN"
/ 3 = "BLUE"
</item>
<text b_match>
/ items = aitems
/ select = text.a.currentindex
/ hposition = list.randomhpos.nextvalue
/ vposition = 60%
</text>
<text b_nomatch1>
/ items = aitems
/ select = list.nomatch.nextvalue
/ hposition = list.randomhpos.nextvalue
/ vposition = 60%
</text>
<text b_nomatch2>
/ items = aitems
/ select = list.nomatch.nextvalue
/ hposition = list.randomhpos.nextvalue
/ vposition = 60%
</text>
<list randomhpos>
/ items = (25%, 50%, 75%)
/ selectionrate = always
</list>
<list nomatch>
/ items = (1,2,3)
/ selectionrate = always
/ not = (text.a.currentindex)
</list>
|
|