Millisecond Forums

Slider questions

https://forums.millisecond.com/Topic18297.aspx

By Nesard - 2/9/2016

Hi,

I'm making an experiment where a 15 random pictures sequence is shown. Bellow each picture, there are two slider questions (they are named p1 and p2 in the code bellow). I need these questions to work like this:

1. The first question must be answered before the second question. So, the second question should be blocked or invisible until the first question has been answered.
2. There should be a "Confirm Answer" button bellow each question. So, once the first question has been confirmed, the second question should be unblocked. And once the second question has been confirmed, the next picture should be shown.
3. Once the first question has been confirmed, this one should be blocked, so that people can't go back and change the answer of the first question.

I'm currently using slider tags for this questions. But if it is easier to do this with other tags, like radio buttons or likert scales, I wouldn't mind to use them.

This is what I have so far:
<values>
/responsestoring = true
</values>

<defaults>
/screencolor = (255, 255, 255)
/font = ("Helvetica", -16, 700, 0, 49)
/txbgcolor=(255,255,255)
</defaults>

<expt>
/ blocks = [1 = POFA;]
</expt>

<block POFA>
/ preinstructions = (instruccionesPOFA)
/ trials = [1-15 = list.triallist]
/ recorddata = true
</block>

*POFA*
<item POFApositives>
/1 = "POFA/positivoHombre-014H.tif"
/2 = "POFA/positivoHombre-029H.tif"
/3 = "POFA/positivoHombre-034H.tif"
/4 = "POFA/positivoMujer-001M.tif"
/5 = "POFA/positivoMujer-042M.tif"
</item>

<item POFAnegatives>
/1 = "POFA/negativoHombre-015H.tif"
/2 = "POFA/negativoHombre-026H.tif"
/3 = "POFA/negativoHombre-032H.tif"
/4 = "POFA/negativoMujer-008M.tif"
/5 = "POFA/negativoMujer-064M.tif"
</item>

<item POFAneutrals>
/1 = "POFA/neutralHombre-021H.tif"
/2 = "POFA/neutralHombre-028H.tif"
/3 = "POFA/neutralHombre-033H.tif"
/4 = "POFA/neutralMujer-006M.tif"
/5 = "POFA/neutralMujer-013M.tif"
</item>

*QUESTIONS*
<slider p1>
/ caption="¿Cuál crees que es el estado emocional de esta persona?"
/ labels=("Negativo", "Neutral", "Positivo")
/ range = (1, 3)
/ position = (10, 70)
/ slidersize = (30,10)
/ increment = 1
/ required = true
/ defaultresponse = "Text"
</slider>

<slider p2>
/ caption="¿Qué tan seguro estás de tu respuesta?"
/ labels=("Nada seguro", "Seguro", "Totalmente seguro")
/ range = (1, 3)
/ position = (50, 70)
/ slidersize = (30,10)
/ increment = 1
/ required = true
</slider>

**************** INSTRUCTION DEFINITION AND INSTRUCTION PAGES ******************

<instruct>
/windowsize = (65%, 85%)
/ fontstyle = ("Helvetica", 2.5%, false, false, false, false, 5, 1)
/ txcolor = (black)
/ finishlabel = "Presiona la tecla Enter continuar"
/ nextkey = (28)
/ nextlabel = "Presiona la tecla Enter para continuar"
/ prevkey = (57)
/ prevlabel = "Presiona la barra espaciadora para volver atrás"
</instruct>

<page pre_video>
A cotinuación verás algunos estímulos visuales. Por favor presta atención a las imágenes que verás e intenta distraerte lo menos posible.^^

Cuando estés listo, presiona la tecla Enter.
</page>

<page instruccionesPOFA>
A continuación verás una serie de fotografías de diferentes personas.
Abajo de cada imágen encontrarás dos preguntas, las cuales debes responder usando las barras horizontales que se encuentran abajo de las mismas.^^

En la barra de la izquierda deberás indicar como crees que se está sintiendo cada persona según su expresión facial.
Usa el mouse para indicar tu respuesta, teniendo en cuenta que:^^

El EXTREMO IZQUIERDO significa ESTADO EMOCIONAL MUY NEGATIVO^^
El EXTREMO DERECHO significa ESTADO EMOCIONAL MUY POSITIVO^^

En la barra de la derecha deberás indicar que tan seguro estás de tu interpretación
de los estados emocionales de cada persona. Usa el mouse para indicar tu respuesta, teniendo en cuenta que:^^

El EXTREMO IZQUIERDO significa NADA SEGURO^^
El EXTREMO DERECHO significa MUY SEGURO^^

Después de que indiques tu respuesta en ambas barras, presiona el botón "Siguiente" para pasar a la siguiente fotografía.

Avanza tan rápido como puedas respondiendo con la primer impresión que te genere cada imágen. Si piensas demasiado tu respuesta se generarán resultados difíciles de interpretar.^^
</page>

*******************************************************************************************************************
*******************************************************************************************************************
DATA: this section contains data file information
*******************************************************************************************************************
*******************************************************************************************************************

********************
raw data
********************
<data>
/ file = "experimentoPiloto.iqdat"
/ columns = [build, date, time, subject, group, blockcode, blocknum, trialcode, trialnum,stimulusitem, latency, response]
/ separatefiles = true
</data>

****************************************** STIMULI ***********************************************************************

<surveypage positive>
/ questions=[1 = p1; 2 = p2]
/ stimulusframes = [1-5 = POFApositive]
/ finishlabel = "Siguiente"
</surveypage>

<surveypage negative>
/ questions=[1=p1; 2=p2]
/ stimulusframes = [1-5 = POFAnegative]
/ finishlabel = "Siguiente"
</surveypage>

<surveypage neutral>
/ questions=[1=p1; 2=p2]
/ finishlabel = "Siguiente"
/ stimulusframes = [1-5 = POFAneutral]
</surveypage>

<picture POFApositive>
/items = POFApositives
/select = noreplace
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

<picture POFAnegative>
/items = POFAnegatives
/select = noreplace
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

<picture POFAneutral>
/items = POFAneutrals
/select = noreplace
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

*******************************************************************************************************************
*******************************************************************************************************************
LISTS
*******************************************************************************************************************
*******************************************************************************************************************
<list itemnumbers>
/selectionmode = sequence
</list>

<list triallist>
/ items = (surveypage.positive, surveypage.neutral, surveypage.negative)
/ poolsize = 15
/ maxrunsize = 2
</list>

Can you help me with this?
Thanks.
By Dave - 2/9/2016

If you want to use <surveypage> and <slider> elements for this, you need *two separate* <surveypage>s: One displaying the image + 1st question (<slider>), followed by a 2nd page also displaying the image and the 2nd question (another <slider>).

<values>
/responsestoring = true
/ positiveitem = 1
/ negativeitem = 1
/ neutralitem = 1
</values>

<defaults>
/screencolor = (255, 255, 255)
/font = ("Helvetica", -16, 700, 0, 49)
/txbgcolor=(255,255,255)
</defaults>

<expt>
/ blocks = [1 = POFA;]
</expt>

<block POFA>
/ preinstructions = (instruccionesPOFA)
/ trials = [1-15 = list.triallist]
/ recorddata = true
</block>

*POFA*
<item POFApositives>
/1 = "POFA/positivoHombre-014H.tif"
/2 = "POFA/positivoHombre-029H.tif"
/3 = "POFA/positivoHombre-034H.tif"
/4 = "POFA/positivoMujer-001M.tif"
/5 = "POFA/positivoMujer-042M.tif"
</item>

<item POFAnegatives>
/1 = "POFA/negativoHombre-015H.tif"
/2 = "POFA/negativoHombre-026H.tif"
/3 = "POFA/negativoHombre-032H.tif"
/4 = "POFA/negativoMujer-008M.tif"
/5 = "POFA/negativoMujer-064M.tif"
</item>

<item POFAneutrals>
/1 = "POFA/neutralHombre-021H.tif"
/2 = "POFA/neutralHombre-028H.tif"
/3 = "POFA/neutralHombre-033H.tif"
/4 = "POFA/neutralMujer-006M.tif"
/5 = "POFA/neutralMujer-013M.tif"
</item>

*QUESTIONS*
<slider p1>
/ caption="¿Cuál crees que es el estado emocional de esta persona?"
/ labels=("Negativo", "Neutral", "Positivo")
/ range = (1, 3)
/ position = (10, 70)
/ slidersize = (30,10)
/ increment = 1
/ required = true
/ defaultresponse = "Text"
</slider>

<slider p2>
/ caption="¿Qué tan seguro estás de tu respuesta?"
/ labels=("Nada seguro", "Seguro", "Totalmente seguro")
/ range = (1, 3)
/ position = (50, 70)
/ slidersize = (30,10)
/ increment = 1
/ required = true
</slider>

**************** INSTRUCTION DEFINITION AND INSTRUCTION PAGES ******************

<instruct>
/windowsize = (65%, 85%)
/ fontstyle = ("Helvetica", 2.5%, false, false, false, false, 5, 1)
/ txcolor = (black)
/ finishlabel = "Presiona la tecla Enter continuar"
/ nextkey = (28)
/ nextlabel = "Presiona la tecla Enter para continuar"
/ prevkey = (57)
/ prevlabel = "Presiona la barra espaciadora para volver atrás"
</instruct>

<page pre_video>
A cotinuación verás algunos estímulos visuales. Por favor presta atención a las imágenes que verás e intenta distraerte lo menos posible.^^

Cuando estés listo, presiona la tecla Enter.
</page>

<page instruccionesPOFA>
A continuación verás una serie de fotografías de diferentes personas.
Abajo de cada imágen encontrarás dos preguntas, las cuales debes responder usando las barras horizontales que se encuentran abajo de las mismas.^^

En la barra de la izquierda deberás indicar como crees que se está sintiendo cada persona según su expresión facial.
Usa el mouse para indicar tu respuesta, teniendo en cuenta que:^^

El EXTREMO IZQUIERDO significa ESTADO EMOCIONAL MUY NEGATIVO^^
El EXTREMO DERECHO significa ESTADO EMOCIONAL MUY POSITIVO^^

En la barra de la derecha deberás indicar que tan seguro estás de tu interpretación
de los estados emocionales de cada persona. Usa el mouse para indicar tu respuesta, teniendo en cuenta que:^^

El EXTREMO IZQUIERDO significa NADA SEGURO^^
El EXTREMO DERECHO significa MUY SEGURO^^

Después de que indiques tu respuesta en ambas barras, presiona el botón "Siguiente" para pasar a la siguiente fotografía.

Avanza tan rápido como puedas respondiendo con la primer impresión que te genere cada imágen. Si piensas demasiado tu respuesta se generarán resultados difíciles de interpretar.^^
</page>

*******************************************************************************************************************
*******************************************************************************************************************
DATA: this section contains data file information
*******************************************************************************************************************
*******************************************************************************************************************

********************
raw data
********************
<data>
/ file = "experimentoPiloto.iqdat"
/ columns = [build, date, time, subject, group, blockcode, blocknum, trialcode, trialnum,stimulusitem, latency, response]
/ separatefiles = true
</data>

****************************************** STIMULI ***********************************************************************

<surveypage positive>
/ ontrialbegin = [values.positiveitem = list.pos_items.nextindex]
/ questions=[1 = p1]
/ stimulusframes = [1 = POFApositive]
/ finishlabel = "Siguiente"
/ branch = [surveypage.positive_2]
</surveypage>

<surveypage positive_2>
/ questions=[1 = p2]
/ stimulusframes = [1 = POFApositive]
/ finishlabel = "Siguiente"
</surveypage>

<surveypage negative>
/ ontrialbegin = [values.negativeitem = list.neg_items.nextindex]
/ questions=[1=p1]
/ stimulusframes = [1 = POFAnegative]
/ finishlabel = "Siguiente"
/ branch = [surveypage.negative_2]
</surveypage>

<surveypage negative_2>
/ questions=[1=p2]
/ stimulusframes = [1 = POFAnegative]
/ finishlabel = "Siguiente"
</surveypage>

<surveypage neutral>
/ ontrialbegin = [values.neutralitem = list.neu_items.nextindex]
/ questions=[1=p1]
/ finishlabel = "Siguiente"
/ stimulusframes = [1 = POFAneutral]
/ branch = [surveypage.neutral_2]
</surveypage>

<surveypage neutral_2>
/ questions=[1=p2]
/ finishlabel = "Siguiente"
/ stimulusframes = [1 = POFAneutral]
</surveypage>

<picture POFApositive>
/items = POFApositives
/select = values.positiveitem
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

<picture POFAnegative>
/items = POFAnegatives
/select = values.negativeitem
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

<picture POFAneutral>
/items = POFAneutrals
/select = values.neutralitem
/size = (50%, 50%)
/position = (50%, 30%)
</picture>

*******************************************************************************************************************
*******************************************************************************************************************
LISTS
*******************************************************************************************************************
*******************************************************************************************************************
<list pos_items>
/ poolsize = 5
</list>

<list neg_items>
/ poolsize = 5
</list>

<list neu_items>
/ poolsize = 5
</list>

<list triallist>
/ items = (surveypage.positive, surveypage.neutral, surveypage.negative)
/ poolsize = 15
/ maxrunsize = 2
</list>
By Nesard - 2/10/2016

Thank you so much for your answer. This is working fine, but I'm having two more problems:

1. If user wants to select the value where the slider selector shows by default (in this case it is 2), he would have to move the selector either to 1 or 3 and then move it again back to 2. Otherwise, Inquisit will not recognize the selection as an answer, and will not allow the user to move to the next question. How can I fix this?
2. When user clics on the /finishlabel button with out selecting an answer before, the image disappears. The images should always be visible.

Thanks!
By Dave - 2/10/2016

Re. #1: The only thing you can do is set the <slider>'s /required attribute to false.
Re. #2: This is not possible when displaying <picture> elements via a <surveypage>'s /stimulusframes. You would have to work with <image> elements displayed via the /questions attribute instead.
By Nesard - 2/10/2016

Ok, thanks.