By vz29 - 7/24/2016
hi,
i'd like to present a trial, and then immediately after the P indicates their response, present another prompt. My code below has a delay between the P response and the onset of the next trial. I'm not sure how to shorten it.
Here's the script:
<trial base_negUP>
/ validresponse = ("a", "5")
/ correctresponse = ("a")
/ stimulustimes = [0 = noreplace (base); 200 = noreplace (blank); 300 = noreplace (badtarget)]
/ branch = [trial.what_prompt]
</trial>
<trial what_prompt>
/ validresponse = ("a", "5")
/ correctresponse = ("")
/ stimulustimes = [0 = noreplace (what); 300 = noreplace (blank)]
/ trialduration = 700
</trial>
|
By Dave - 7/24/2016
<trial what_prompt>
/ validresponse = ("a", "5")
/ correctresponse = ("")
/ stimulustimes = [0 = noreplace (what); 300 = noreplace (blank)]
/ trialduration = 700
</trial>
/trialduration *fixes* the trial's duration to the specified value -- i.e., the above trial will *always* last 700ms, regardless of when you respond. If you respond prior to 700ms, there will be a delay for the remainder of the 700ms until the next trial starts.
If you want to define a *maximum* duration for the trial, use /timeout, not /trialduration.
<trial what_prompt>
/ validresponse = ("a", "5")
/ correctresponse = ("")
/ stimulustimes = [0 = noreplace (what); 300 = noreplace (blank)]
/ timeout= 700
</trial>
The trial will then terminate as soon as the subjects responds or -- no response occurs -- end after 700ms.
|
By vz29 - 7/25/2016
Thanks. After the presentation of trial base_negUP there is a slight delay. How can I get rid of this?
|
By Dave - 7/25/2016
The slight delay is probably due to one or several of the stimuli presented by <trial base_negUP> being erased. The delay will thus be on the order of 1 to 2 display frames. You can only get rid of it by setting all the stimulus element's /erase attributes to false as in
<shape blank>
...
/ erase = false
</shape>
etc.
If need be, have the follow up <trial> overwrite any stimuli by displaying the "blank" shape at the start.
<trial what_prompt>
/ validresponse = ("a", "5")
/ correctresponse = ("")
/ stimulustimes = [0 = blank, what; 300 = blank]
/ timeout= 700
</trial>
Also, <trial what_prompt> will only start accepting response after its final stimulus has been displayed ("blank" at 300ms). If you want the trial to start accepting responses earlier (starting with the presentation of "what"), you should specify
<trial what_prompt>
/ ontrialbegin = [trial.what_prompt.resetstimulusframes(); ]
/ validresponse = ("a", "5")
/ correctresponse = ("")
/ stimulustimes = [0 = blank, what; 300 = blank]
/ timeout= 700
/ beginresponsetime = 0
</trial>
For information regarding Inquisit's stimulus erasing behavior, see the "How to erase stimuli" topic in the documentation. For an overview of the various components involved in timing stimuli, trials and responses, I would recommend taking a look at the "How to Control Trial Duration and Inter-Trial Intervals" topic.
|
By vz29 - 7/26/2016
thanks, dave.
|
|