By Anthony - 1/24/2017
I am trying to design an task in which participants of MTurk view videos and continuously rate them for perceived affect (negative to positive). The problems I am having currently are:
1) getting the data to output with second by second ratings (what rating they gave at a given second of the video). I need this for comparison to the videos collected in-lab. Right now I can get output on reaction time, but I figure there is a better way.
2) changing the likert scale option in Inquisit so it does not need input from a mouseclick or a press of the enter key. I recognize that this might not be possible. In the initial ratings of the videos, participants moved the Likert's slider with the arrow keys and the rating was automatically picked up and assigned to the nearest second for the output, so it would be best if I could go around the need for a press or click.
3) also, can the Likert scale in Inquisit be a slider at all, or is it only radio buttons?
Thanks in advance for any help.
|
By Dave - 1/24/2017
+xI am trying to design an task in which participants of MTurk view videos and continuously rate them for perceived affect (negative to positive). The problems I am having currently are: 1) getting the data to output with second by second ratings (what rating they gave at a given second of the video). I need this for comparison to the videos collected in-lab. Right now I can get output on reaction time, but I figure there is a better way. 2) changing the likert scale option in Inquisit so it does not need input from a mouseclick or a press of the enter key. I recognize that this might not be possible. In the initial ratings of the videos, participants moved the Likert's slider with the arrow keys and the rating was automatically picked up and assigned to the nearest second for the output, so it would be best if I could go around the need for a press or click. 3) also, can the Likert scale in Inquisit be a slider at all, or is it only radio buttons? Thanks in advance for any help.
You can build something like this using standard <trial> elements:
<values>
/ timeofrating = 0
/ distance = 15%
/ questionnumber = 0
</values>
<expressions>
/ ratingvalue = 1+(text.indicator.hposition-text.r1.hposition)/values.distance
</expressions>
<video myvideo>
/ items = ("video.mp4")
/ size = (40%, 40%)
</video>
<block videoblock>
/ bgstim = (myvideo)
/ trials = [1=ratingtrial]
/ timeout = 20000
</block>
<trial ratingtrial>
/ ontrialend = [if(trial.ratingtrial.response==203 && text.indicator.hposition>text.r1.hposition)
text.indicator.hposition=text.indicator.hposition-values.distance]
/ ontrialend = [if(trial.ratingtrial.response==205 && text.indicator.hposition<text.r5.hposition)
text.indicator.hposition=text.indicator.hposition+values.distance]
/ ontrialend = [values.timeofrating = block.videoblock.elapsedtime]
/ stimulusframes = [1=r1,r2,r3,r4,r5,indicator,currentrating]
/ validresponse = (203, 205)
/ branch = [trial.ratingtrial]
</trial>
<text currentrating>
/ items = ("Current rating :<%expressions.ratingvalue%>")
/ position = (50%, 5%)
/ erase = false
</text>
<text indicator>
/ items = ("^")
/ position = (50%, 85%)
</text>
<text r1>
/ items = ("1")
/ position = (20%, 80%)
/ erase = false
</text>
<text r2>
/ items = ("2")
/ position = (35%, 80%)
/ erase = false
</text>
<text r3>
/ items = ("3")
/ position = (50%, 80%)
/ erase = false
</text>
<text r4>
/ items = ("4")
/ position = (65%, 80%)
/ erase = false
</text>
<text r5>
/ items = ("5")
/ position = (80%, 80%)
/ erase = false
</text>
<data>
/ columns = (date time subject group blocknum blockcode trialnum trialcode response latency expressions.ratingvalue values.timeofrating)
/ separatefiles = true
</data>
|
|