Hi all,

I'm currently devising a reading task during which I'd like to have probes pop up every now and then and ask participants what they're thinking about.

What is the best way to do this?

Ideally I'd like the probe pages to appear after a certain period of time (either 30, 40, 50, or 60 second intervals)  regardless of what is going on in the reading, and then after the probe it goes back to whichever page they were on before. The piece of text is a scientific journal article (currently in PDF - but I'm guessing I can just copy and paste it to create a set of pages with the same text), so none of the participants will have time to finish it, it will just end after the eighth probe.

I have the probe trial pages written already, and a preceding task with all the stimuli I need, this is the last piece of the puzzle!

Thanks in advance,

Jack

In essence, you'd do something like this (use the left and right arrow keys to navigate back and forth between the "pages" in the reading part):

<values>
/ npages = 20
/ pagenumber = 1
/ probeinterval = 10000
/ timeuntilprobe = values.probeinterval
/ nprobes = 8
/ probenumber = 0
</values>

<block myblock>
/ stop = [values.probenumber == values.nprobes]
/ trials = [1=readingtrial]
</block>

<trial readingtrial>
/ ontrialend = [if (trial.readingtrial.response==205 && values.pagenumber < values.npages) values.pagenumber +=1;
    if (trial.readingtrial.response==203 && values.pagenumber > 1) values.pagenumber -= 1;]
/ ontrialend = [values.timeuntilprobe -= trial.readingtrial.latency]
/ stimulusframes = [1=pagetext]
/ validresponse = (203, 205)
/ timeout = values.timeuntilprobe
/ branch = [if (trial.readingtrial.response == 0) openended.probetrial else trial.readingtrial]
</trial>

<openended probetrial>
/ ontrialend = [values.probenumber += 1;
    values.timeuntilprobe = values.probeinterval]
/ stimulusframes = [1=clearscreen, probeprompt]
/ branch = [trial.readingtrial]
</openended>

<text pagetext>
/ items = pageitems
/ erase = false
/ size = (90%, 90%)
/ select = values.pagenumber
</text>

<item pageitems>
/ 1 = "Page 01 Text..."
/ 2 = "Page 02 Text..."
/ 3 = "Page 03 Text..."
/ 4 = "Page 04 Text..."
/ 5 = "Page 05 Text..."
/ 6 = "Page 06 Text..."
/ 7 = "Page 07 Text..."
/ 8 = "Page 08 Text..."
/ 9 = "Page 09 Text..."
/ 10 = "Page 10 Text..."
/ 11 = "Page 11 Text..."
/ 12 = "Page 12 Text..."
/ 13 = "Page 13 Text..."
/ 14 = "Page 14 Text..."
/ 15 = "Page 15 Text..."
/ 16 = "Page 16 Text..."
/ 17 = "Page 17 Text..."
/ 18 = "Page 18 Text..."
/ 19 = "Page 19 Text..."
/ 20 = "Page 20 Text..."
</item>

<text probeprompt>
/ items = ("What are you thinking about right now?")
/ position = (50%, 10%)
</text>