Hi all!

Does anyone know of a way to enable double verification, so that participants are required to enter their ID# two times?
Thanks in advance!

-Mike

If you're talking about a web experiment, participant-entered ID *with* confirmation is one of the selectable standard options.

I'm using the desktop version of Inquisit 4. Would something like this have to be done/ could it be done, writing code?  

Yes, with Inquisit Lab, you'd have to resort to something like two <openended> elements to collect an ID instead. I.e.

<openended enterID>
/ stimulusframes = [1=enterprompt]
/ branch = [openended.confirmID]
</openended>

<text enterprompt>
/ items = ("Please enter your ID:")
/ position = (50%, 40%)
</text>

<openended confirmID>
/ stimulusframes = [1=confirmprompt]
/ branch = [if (openended.confirmID.response != openended.enterID.response) trial.nomatch]
</openended>

<text confirmprompt>
/ items = ("Please confirm your ID:")
/ position = (50%, 40%)
</text>

<trial nomatch>
/ stimulusframes = [1=nomatchprompt]
/ branch = [openended.enterid]
/ trialduration = 2000
/ validresponse = (0)
</trial>

<text nomatchprompt>
/ items = ("The IDs you entered did not match. Please try again.")
/ position = (50%, 40%)
</text>

<block IDblock>
/ trials = [1=enterID]
</block>

<expt>
/ blocks = [1=IDblock]
</expt>

Note that this will be separate and independent of the subject ID.

This works thanks! Just out of curiosity, is there a way to make sure that this matches up with the Subject ID?