By emotion001 - 2/20/2020
We are trying to work through a variant of the rooks problem.
In our case, we have a within-subjects design in that everyone sees all 6 scenarios in all 6 conditions. We have 6 different Scenarios (e.g., A, B, C, D, E, F) and 6 different Conditions (e.g., 1, 2, 3, 4, 5, 6). We are hoping to use Inquisit to randomly present six different scenarios that are tied to 6 different conditions. There are 36 possible combinations of Scenarios/Conditions. However, we want to set it such that if a participant sees a Scenario for a particular condition, that Scenario should not be used for another condition:
A1 B1 C1 D1 E1 F1
A2 B2 C2 D2 E2 F2
A3 B3 C3 D3 E3 F3
A4 B4 C4 D4 E4 F4
A5 B5 C5 D5 E5 F5
A6 B6 C6 D6 E6 F6
So say the first thing that someone sees is A1. The fact A1 is displayed means B1, C1, D1, E1, F1, as well as A2, A3, A4, A5, and A6 can't be shown in the following trials. Then in the next trial, say B2 is shown, then B3, B4, B5, B6, and C2, D2, E2, and F2 can't be shown in the following trails, as well as the previous ones that can't be shown.
Any help on specifying how this can be done would be greatly appreciated.
Thank you!!!
|
By Dave - 2/20/2020
+xWe are trying to work through a variant of the rooks problem. In our case, we have a within-subjects design in that everyone sees all 6 scenarios in all 6 conditions. We have 6 different Scenarios (e.g., A, B, C, D, E, F) and 6 different Conditions (e.g., 1, 2, 3, 4, 5, 6). We are hoping to use Inquisit to randomly present six different scenarios that are tied to 6 different conditions. There are 36 possible combinations of Scenarios/Conditions. However, we want to set it such that if a participant sees a Scenario for a particular condition, that Scenario should not be used for another condition: A1 B1 C1 D1 E1 F1 A2 B2 C2 D2 E2 F2 A3 B3 C3 D3 E3 F3 A4 B4 C4 D4 E4 F4 A5 B5 C5 D5 E5 F5 A6 B6 C6 D6 E6 F6 So say the first thing that someone sees is A1. The fact A1 is displayed means B1, C1, D1, E1, F1, as well as A2, A3, A4, A5, and A6 can't be shown in the following trials. Then in the next trial, say B2 is shown, then B3, B4, B5, B6, and C2, D2, E2, and F2 can't be shown in the following trails, as well as the previous ones that can't be shown. Any help on specifying how this can be done would be greatly appreciated. Thank you!!!
Set up six <trial> elements, one per scenario class A to F. Sample these six trials randomly at the block-level. Set up six <text> elements, again one per scenario class A to F, with six items each -- the scenario items belonging to the respective scenario class. Sample from these text elements using a single <list> element with numbers 1 to 6 as items. In a nutshell:
<block example>
/ trials = [1-6 = noreplace(a_trial, b_trial, c_trial, d_trial, e_trial, f_trial)]
</block>
<values>
/ scenarioitem = 1
</values>
<list scenarios>
/ items = (1,2,3,4,5,6)
</list>
<trial a_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=a_scenario]
/ validresponse = (57)
</trial>
<trial b_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=b_scenario]
/ validresponse = (57)
</trial>
<trial c_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=c_scenario]
/ validresponse = (57)
</trial>
<trial d_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=d_scenario]
/ validresponse = (57)
</trial>
<trial e_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=e_scenario]
/ validresponse = (57)
</trial>
<trial f_trial>
/ ontrialbegin = [
values.scenarioitem = list.scenarios.nextvalue;
]
/ stimulusframes = [1=f_scenario]
/ validresponse = (57)
</trial>
<text a_scenario>
/ items = a_scenarioitems
/ select = values.scenarioitem
</text>
<item a_scenarioitems>
/1 = "A1"
/2 = "A2"
/3 = "A3"
/4 = "A4"
/5 = "A5"
/6 = "A6"
</item>
<text b_scenario>
/ items = b_scenarioitems
/ select = values.scenarioitem
</text>
<item b_scenarioitems>
/1 = "B1"
/2 = "B2"
/3 = "B3"
/4 = "B4"
/5 = "B5"
/6 = "B6"
</item>
<text c_scenario>
/ items = c_scenarioitems
/ select = values.scenarioitem
</text>
<item c_scenarioitems>
/1 = "C1"
/2 = "C2"
/3 = "C3"
/4 = "C4"
/5 = "C5"
/6 = "C6"
</item>
<text d_scenario>
/ items = d_scenarioitems
/ select = values.scenarioitem
</text>
<item d_scenarioitems>
/1 = "D1"
/2 = "D2"
/3 = "D3"
/4 = "D4"
/5 = "D5"
/6 = "D6"
</item>
<text e_scenario>
/ items = e_scenarioitems
/ select = values.scenarioitem
</text>
<item e_scenarioitems>
/1 = "E1"
/2 = "E2"
/3 = "E3"
/4 = "E4"
/5 = "E5"
/6 = "E6"
</item>
<text f_scenario>
/ items = f_scenarioitems
/ select = values.scenarioitem
</text>
<item f_scenarioitems>
/1 = "F1"
/2 = "F2"
/3 = "F3"
/4 = "F4"
/5 = "F5"
/6 = "F6"
</item>
|
|