+x

 

Bee - 4/23/2020

In my experiment, I have 2 separate blocks which require unique background stimuli. However, the background stimuli from the first block is carrying over to the second block. I  know that there is a clear screen function, but I do not know how to use it/ where to put it. This is what I have

<Block Practice_num>
/bgstim = (button.1n, button.2n, button.3n, button.4n, button.6n, button.7n, button.8n, button.9n)
/trials = [1= sequence(1_R, 2_R, 3_R, 4_R, 6_R, 7_R, 8_R, 9_R, 1_L, 2_L, 3_L, 4_L, 6_L, 7_L, 8_L, 9_L) ]
/showmousecursor = true
/ onblockend = [("clearscreen")]
</Block>

Thank you in advance

+x

 

Dave - 4/24/2020

+x

 

Bee - 4/23/2020

In my experiment, I have 2 separate blocks which require unique background stimuli. However, the background stimuli from the first block is carrying over to the second block. I  know that there is a clear screen function, but I do not know how to use it/ where to put it. This is what I have

<Block Practice_num>
/bgstim = (button.1n, button.2n, button.3n, button.4n, button.6n, button.7n, button.8n, button.9n)
/trials = [1= sequence(1_R, 2_R, 3_R, 4_R, 6_R, 7_R, 8_R, 9_R, 1_L, 2_L, 3_L, 4_L, 6_L, 7_L, 8_L, 9_L) ]
/showmousecursor = true
/ onblockend = [("clearscreen")]
</Block>

Thank you in advance

clearscreen essentially behaves and must be used like a built-in stimulus, so you'll want to integrate it into your /bgstim attributes.

Compare

<expt>
/ blocks = [1-2 = noreplace(a,b)]
</expt>

<block a>
/ bgstim = (a1, a2)
/ trials = [1=mytrial]
</block>

<block b>
/ bgstim = (b1, b2)
/ trials = [1=mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=press]
/ validresponse = (57)
</trial>

<text press>
/ items = ("Press SPACE")
</text>

<button a1>
/ caption = "A Left"
/ position = (10%, 5%)
/ erase = false
/ size = (4%, 6%)
</button>

<button a2>
/ caption = "A Right"
/ position = (90%, 5%)
/ erase = false
/ size = (4%, 6%)
</button>

<button b1>
/ caption = "B Left"
/ position = (20%, 10%)
/ erase = false
/ size = (4%, 6%)
</button>

<button b2>
/ caption = "B Right"
/ position = (80%, 10%)
/ erase = false
/ size = (4%, 6%)
</button>



versus

<expt>
/ blocks = [1-2 = noreplace(a,b)]
</expt>

<block a>
/ bgstim = (clearscreen, a1, a2)
/ trials = [1=mytrial]
</block>

<block b>
/ bgstim = (clearscreen, b1, b2)
/ trials = [1=mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=press]
/ validresponse = (57)
</trial>

<text press>
/ items = ("Press SPACE")
</text>

<button a1>
/ caption = "A Left"
/ position = (10%, 5%)
/ erase = false
/ size = (4%, 6%)
</button>

<button a2>
/ caption = "A Right"
/ position = (90%, 5%)
/ erase = false
/ size = (4%, 6%)
</button>

<button b1>
/ caption = "B Left"
/ position = (20%, 10%)
/ erase = false
/ size = (4%, 6%)
</button>

<button b2>
/ caption = "B Right"
/ position = (80%, 10%)
/ erase = false
/ size = (4%, 6%)
</button>