By InquisitJK - 11/13/2020
Hi,
I am new to Inquisit and I would like to know if there is anyway the output file can produce information for lists that are not presented on the screen during the experiment but they are in a list form corresponding to the stimuli.
To illustrate and clarify let me provide you with the following:
- I will have stimuli of faces which will be presented in a sequence order on a trial.
- And I will want to know the: age, gender, race of the face participants are presented with. But this information is not displayed on the screen.
Stimuli:
Face1, Face2, Face3, Face4, Face5
Age:
Old, Young, Old, Old, Young
Gender:
Male, Female, Female, Male, Female
Race:
Caucasian, Hispanic, Caucasian, Black/African American, Asian
Best,
Jordy
|
By Dave - 11/13/2020
+xHi, I am new to Inquisit and I would like to know if there is anyway the output file can produce information for lists that are not presented on the screen during the experiment but they are in a list form corresponding to the stimuli. To illustrate and clarify let me provide you with the following: - I will have stimuli of faces which will be presented in a sequence order on a trial. - And I will want to know the: age, gender, race of the face participants are presented with. But this information is not displayed on the screen. Stimuli: Face1, Face2, Face3, Face4, Face5 Age: Old, Young, Old, Old, Young Gender: Male, Female, Female, Male, Female Race: Caucasian, Hispanic, Caucasian, Black/African American, Asian Best, Jordy
<block example>
/ trials = [1-5 = facetrial]
</block>
<trial facetrial>
/ ontrialend = [
values.age = list.age.nextvalue;
values.gender = list.gender.nextvalue;
values.race = list.race.nextvalue;
]
/ stimulusframes = [1=face]
/ validresponse = (57)
</trial>
<values>
/ age = ""
/ race = ""
/ gender = ""
</values>
<text face>
/ items = ("Face1", "Face2", "Face3", "Face4", "Face5")
/ select = sequence
</text>
<list age>
/ items = ("Old", "Young", "Old", "Old", "Young")
/ selectionmode = text.face.currentindex
</list>
<list gender>
/ items = ("Male", "Female", "Female", "Male", "Female")
/ selectionmode = text.face.currentindex
</list>
<list race>
/ items = ("Caucasian", "Hispanic", "Caucasian", "Black/African American", "Asian")
/ selectionmode = text.face.currentindex
</list>
<data>
/ columns = (date time subject group blocknum blockcode trialnum trialcode response latency correct
stimulusitem values.age values.gender values.race)
/ separatefiles = true
</data>
|
|