+xHi,
I am creating a 2-option forced choice picture task where participants must choose one of the two images. I can make the task but I was wondering if there was a way to initially present the images as smaller thumbnails potentially greyed out and then upon the choice the chosen image becomes enlarged and coloured?
Thanks
Jack
Your trial should display the greyed-out thumbnails as clickable options, then upon selection of one of the images, display the corresponding large, colored version per the trial's /responsemessage.
<block myblock>
/ trials = [1-2 = example]
</block>
<trial example>
/ stimulusframes = [1=clearscreen, a_thumb, b_thumb]
/ inputdevice = mouse
/ validresponse = (a_thumb, b_thumb)
/ responsemessage = (a_thumb, a_large, 1000)
/ responsemessage = (b_thumb, b_large, 1000)
</trial>
<picture a_thumb>
/ items = a_thumbitems
/ size = (20%, 20%)
/ position = (30%, 50%)
/ erase = false
</picture>
<picture b_thumb>
/ items = b_thumbitems
/ size = (20%, 20%)
/ position = (70%, 50%)
/ erase = false
</picture>
<picture a_large>
/ items = a_largeitems
/ size = (40%, 40%)
/ position = (30%, 50%)
/ select = picture.a_thumb.currentindex
/ erase = false
</picture>
<picture b_large>
/ items = b_largeitems
/ size = (40%, 40%)
/ position = (70%, 50%)
/ select = picture.b_thumb.currentindex
/ erase = false
</picture>
<item a_thumbitems>
/ 1 = "a1_thumb.jpg"
/ 2 = "a2_thumb.jpg"
</item>
<item b_thumbitems>
/ 1 = "b1_thumb.jpg"
/ 2 = "b2_thumb.jpg"
</item>
<item a_largeitems>
/ 1 = "a1_large.jpg"
/ 2 = "a2_large.jpg"
</item>
<item b_largeitems>
/ 1 = "b1_large.jpg"
/ 2 = "b2_large.jpg"
</item>