Dear all,

Hope you're all well :). And I also hope you can help me with some perhaps unconventional questions regarding Inquisit! Perhaps you know some workarounds that would help me, if Inquisit isn't able to do what I would like?

Well here they are:

1. First of all, is it possible to adjust volume levels using inquisit? My students are in need of a setup in which participants are able to select prefered volume levels in the program.

2. My second question regards pausing - or stop/resuming - the presentation of stimuli. I need to develop a paradigm in which participants can select two buttons, a left button press which would play a video file for 25 seconds, and then stop. A right button press would play 5 seconds of the video and then stop. Well this is doable, but I need following trials to resume the video file where the last trial ended it! Any thoughts on this?

3. Last, is it possible to make the computer monitor shut down using Inquisit, and start up again when I indicate it to do so? This is for another experiment, and we are considering the use of a screensize black picture. But shutting down the monitor would be preferred!

Thanks for the help,

Tom

The <sound> element has a /volume attribute which should be able to handle variables, e.g.

<sound mysound>
/ items = ("mysound.wav")
/ volume = values.myvolume
</sound>

See the documentation for details. You can't make sounds louder, so set the systems volume high. But you could allow subjects to make sounds less loud.

Split your video in 25s and 5s segments respectively and select them sequentially. There's no way to make Inquisit resume a video from a previous position.

Nope, no way to control the monitor state from within Inquisit. Black picture or shape is your best option.

~Dave

Thanks for the answers!

Splitting the answers isn't really an option because if you have a dichotomous choice with 20 opportunities to select either response, there are 2^20 = 1048576 possible orders.

That would be quite a long script.. Hmm any other thoughts on this?

Thx!

Well, it's not like you'd have to hardcode any of these orders, so that figure is totally irrelevant. After all, the sequence is determined by the subject's choices. All you need is something along these lines:

<values>
/ longvid = 0
/ shortvid = 0
</values>

<block myblock>
/ trials = [1=choice]
</block>

<trial choice>
/ stimulusframes = [1=selectlong, selectshort]
/ inputdevice = mouse
/ validresponse = (selectlong, selectshort)
/ branch = [if(trial.choice.response=="selectlong")trial.playlong else trial.playshort]
</trial>

<text selectlong>
/ items = ("Play long video")
/ position = (40%, 50%)
</text>

<text selectshort>
/ items = ("Play short video")
/ position = (60%, 50%)
</text>

<trial playlong>
/ ontrialbegin = [values.longvid=values.longvid+1]
/ stimulusframes = [1=longvideo]
/ validresponse = (anyresponse)
/ branch = [trial.choice]
</trial>

<trial playshort>
/ ontrialbegin = [values.shortvid=values.shortvid+1]
/ stimulusframes = [1=shortvideo]
/ validresponse = (anyresponse)
/ branch = [trial.choice]
</trial>

<text longvideo>
/ items = longvideosegments
/ select = values.longvid
</text>

<text shortvideo>
/ items = shortvideosegments
/ select = values.shortvid
</text>

<item longvideosegments>
/ 1 = "long video segment 1"
/ 2 = "long video segment 2"
/ 3 = "long video segment 3"
</item>

<item shortvideosegments>
/ 1 = "short video segment 1"
/ 2 = "short video segment 2"
/ 3 = "short video segment 3"
</item>

Regards

~Dave

Still wrapping my brains around this one,

I like your solution. However, as it is possible for each last trial to have been the short video of 5 seconds, with 20 choice moments there are 20*5=100 possible starting points for the short vid trial, and 100 possible starting points for the long vid trial.

And i don't think Inquist could handle loading 200 video segments.

Best,

Tom!

And this is important, because...?

Given enough RAM, why not?