Millisecond Forums » Millisecond Forums » Inquisit 4 » same order of randomization

same order of randomization

wieteke — Thu, 29 May 2014 08:14:15 GMT

Dear all,

I use a randomization counter to pick random (no replace) a picture for trial A, and with the picture element I select with the current function the same picture for trial B and C (and this 80 times). This works perfectly fine. However, after this block 'task' I want another block 'task2' in which I would like the same order of pictures that participants received in block "task". Is this possible (I tried different things but could not find the solution)? Thanks a lot!

/ trials = [1=A; 2=B; 3=C]

</block>

/ select = noreplace (1-80)

/ resetinterval = 0

</counter>

RE: same order of randomization

wieteke — Thu, 29 May 2014 08:14:15 GMT

Thank you very much! That helps a lot!

RE: same order of randomization

Dave — Thu, 29 May 2014 06:48:02 GMT

Yes, it's possible to do that. Two options:

#1: Randomize stuff *once* at the beginning of the experiment, store the result in a <list> or <counter>, then use sequential selection from that list / counter for the remainder of the experiment.

#2: Go for random order in the first portion, record the result (again in a list or counter) at runtime, then use sequential selection from said list counter in the 2nd part.

EDITED TO ADD: Example for #2 (#1 would work along similar lines):

<values>
/ itemnumber = 1
</values>

<expt>
/ blocks = [1=block1; 2=block2]
</expt>

<block block1>
/ trials = [1-4=block1_trial]
</block>

<block block2>
/ trials = [1-4=block2_trial]
</block>

<trial block1_trial>
/ ontrialbegin = [values.itemnumber=list.itemlist_block1.nextvalue; list.itemlist_block2.appenditem(values.itemnumber)]
/ stimulusframes = [1=mytext]
/ validresponse = (57)
</trial>

<trial block2_trial>
/ ontrialbegin = [values.itemnumber=list.itemlist_block2.nextvalue]
/ stimulusframes = [1=mytext]
/ validresponse = (57)
</trial>

<text mytext>
/ items = ("A", "B", "C", "D")
/ select = values.itemnumber
</text>

<list itemlist_block1>
/ items = (1,2,3,4)
/ selectionmode = random
</list>

<list itemlist_block2>
/ selectionmode = sequence
</list>