Millisecond Forums » Millisecond Forums » Inquisit 4 » HTML element not located

HTML element not located

CES — Fri, 05 Jun 2015 14:07:29 GMT

I'm trying to format text in a more flexible way using the html feature. I'm receiving an error that states: /stimulusframes: Could not locate element 'introhtml'.

The html file is saved in the same location as the Inquisit file, so it should be able to locate it. What could be a possible reason for the error?

Thanks,

/ items = ( "index.html")

position = ( 50%, 50%)

/ showborders = false

/ showscrollbars = false

/ valign = center

/ halign = center

/ position = (0, 0)

/ size = (100%, 100%)

</html>

/ stimulusframes = [1=introhtml]

/ validresponse = (" ")

</trial>

/trials = [1=introhtml]

</block>

RE: HTML element not located

Dave — Fri, 05 Jun 2015 14:07:29 GMT

No, Inquisit 3 has no <html> element. You would have to display e.g. a <picture> instead.

RE: HTML element not located

jbae — Fri, 05 Jun 2015 12:51:37 GMT

I apologize but I didn't realize that this thread was posted under Inquisit 4.
The above question is in reference to Inquisit 3. Would it be still possible in Inquisit 3 even though there is no <html> in Inquisit 3?

Thanks.

RE: HTML element not located

Dave — Fri, 05 Jun 2015 11:37:08 GMT

Here's a quick example to illustrate:

<expt>
/ preinstructions = (intropage)
/ postinstructions = (endpage)
/ blocks = [1=consentblock; 2=taskblock]
</expt>

<instruct>
/ finishlabel = ("NEXT>>")
/ windowsize = (90%, 80%)
</instruct>

<htmlpage intropage>
/ file = "intro.htm"
</htmlpage>

<htmlpage endpage>
/ file = "end.htm"
</htmlpage>

<block consentblock>
/ trials = [1=consenttrial]
</block>

<block taskblock>
/ skip = [trial.consenttrial.response=="decline"]
/ trials = [1-10=tasktrial]
</block>

<html consentpage>
/ items = ("consent.htm")
/ size = (90%, 80%)
</html>

<trial consenttrial>
/ stimulusframes = [1=consentpage, accept, decline]
/ inputdevice = mouse
/ validresponse = (accept, decline)
</trial>

<text accept>
/ items = ("ACCEPT")
/ position = (45%, 95%)
/ txbgcolor = grey
</text>

<text decline>
/ items = ("DECLINE")
/ position = (55%, 95%)
/ txbgcolor = grey
</text>

<trial tasktrial>
/ posttrialpause = 500
/ stimulusframes = [1=stimulus]
/ validresponse = (57)
</trial>

<text stimulus>
/ items = ("Press the spacebar as quickly as possible.")
</text>

RE: HTML element not located

Dave — Fri, 05 Jun 2015 11:20:42 GMT

You cannot do this with html *instruction* pages (i.e., <htmlpage>). You can do this using standard <trial> elements displaying a <html> stimulus. Your buttons then would be just standard <text> elements displayed by the <trial> and clickable via the mouse (/inputdevice = mouse; /valdidresponse = (button1, button2, button3); etc.).

The agree to participate vs. decline to participate logic then would be accomplished via /branch, /skip and/or /stop attributes.

RE: HTML element not located

jbae — Fri, 05 Jun 2015 10:42:01 GMT

Another quick question to the above thread:

Would there be any way that I could add an additional button on my htmlpage?
I'm trying to have two buttons (one for 'Agree' and one for 'Disagree') on my htmlpage but using the <instruct> element attributes is not letting me add any additional buttons.

My code is shown below:
<htmlpage intro>
/ file = "C:\InquisitExp\intro.htm"
</htmlpage>

<block consent>
/ preinstructions=(intro)
</block>

<instruct>
/ inputdevice = mouse
/ prevlabel = "DISAGREE"
/ finishlabel = "AGREE"
</instruct>

<expt>
</blocks = [1 = consent]
</expt>

Also, if it is possible to add an additional button on my htmlpage, how would I set each button to go to different pages? For example, clicking 'Agree' button will move onto the next page whereas clicking 'Disagree' will move onto the last page of my experiment?

Thank you for your help and your time.

RE: HTML element not located

Dave — Wed, 03 Jun 2015 07:33:02 GMT

The label for the 'next' button for the *last* page in a set of instruction pages must be set via the <instruct> element's /finishlabel attribute.

RE: HTML element not located

CES — Wed, 03 Jun 2015 07:17:10 GMT

The previous question is in reference to Inquisit 3.

RE: HTML element not located

CES — Wed, 03 Jun 2015 07:15:27 GMT

Just a quick follow up to the above thread:

I'm trying to change the 'Press Enter to Continue' text on my htmlpage, but using nextlabel via the <instruct> element is not changing the text on the label button.

Here is a brief overview of my code:

<htmlpage intro>
/ file="D:\ExpTest\test.htm"
</htmlpage>

<block myblock>
/ preinstructions=(intro)
</block>

<instruct>
/ inputdevice = mouse
/ nextlabel = "AGREE"
</instruct>

<expt >
/blocks = [1 = myblock]
</expt>

Any insight into if it's possible to change this label would be helpful. Thanks!

RE: HTML element not located

CES — Wed, 03 Jun 2015 07:15:27 GMT

RE: HTML element not located

Dave — Wed, 13 Aug 2014 01:55:59 GMT

#1: There is no <html> element in Inquisit 3, only a <htmlpage> element for HTML instruction pages.

#2: You can partly configure things via the <instruct> element (e.g. its /windowsize, /nextlabel etc. attributes). You cannot get rid of scrollbar, borders and buttons completely.

RE: HTML element not located

CES — Tue, 12 Aug 2014 19:00:16 GMT

Is it possible to remove the border, scroll bar, and Next button label from the pre instructions page when using the htmlpage element in Inquisit 3?

RE: HTML element not located

CES — Tue, 12 Aug 2014 18:46:23 GMT

I believe it is because I am using Inquisit 3 and the html element is different in Inquisit 3 than it is in Inquisit 4