Assigning participants to condition based on sexual orientation

TEVH — Fri, 25 Mar 2016 07:21:48 GMT

Hi there,

I'm relatively new to Inquisit and I'm trying to simulate a Tinder-like environment in which participants can indicate whether they like a person or not based on picture stimuli. To that end, I need to match the stimuli with participants' sexual orientation (i.e., a heterosexual female participant or a homosexual male participant should only be presented with pictures of men). I guess this means that I need to assign participants to one of two conditions (pictures of men versus pictures of women), which is why I've sorted pictures of men and women into separate <item> elements.
However, I would rather avoid asking participants directly/face-to-face in our lab what their sexual orientation is because of the sensitive nature of such a question, and so I can't use the '/groupassignment' attribute and enter a group number manually. Instead, I'd like to add a question at the start of the experiment that asks them about their sexual orientation, and then automatically redirect them to the right condition. And so, my question is the following:

Can I present participants with the stimuli that corresponds to their sexual preference (which is indicated by the answer to a question at the start of the experiment)? Perhaps something with the <include> element, using the '/precondition' attribute?

Thank you so much for your time!

P.S. - I currently have Inquisit 4, but I could upgrade to Inquisit 5 if necessary.

RE: Assigning participants to condition based on sexual orientation

Dave — Fri, 25 Mar 2016 07:21:48 GMT

Neither <include> nor /groupassignment are the way to go here.

Your options are to either

(1) set up separate <block>s for male vs. female and use /skip to only run the applicable ones, or

(2) Use <list> representing the different item numbers for male vs. female stimuli and sample from the appropriate list based on the indicated sexual orientation.

<values>
/ itemnumber = 1
</values>

<block myblock>
/ trials = [1=orientationpage; 2-5=mytrial]
</block>

<surveypage orientationpage>
/ questions = [1=iam; 2=lookingfor]
</surveypage>

<dropdown iam>
/ caption = "I am a"
/ options = ("man", "woman")
</dropdown>

<dropdown lookingfor>
/ caption = "looking for"
/ options = ("men", "women")
</dropdown>

<trial mytrial>
/ ontrialbegin = [if (dropdown.lookingfor.response == "men") values.itemnumber = list.maleitems.nextvalue else
values.itemnumber = list.femaleitems.nextvalue; ]
/ stimulusframes = [1=stimulus]
/ validresponse = (57)
</trial>

<list maleitems>
/ items = (1,2,3,4)
</list>

<list femaleitems>
/ items = (5,6,7,8)
</list>

<text stimulus>
/ items = myitems
/ select = values.itemnumber
</text>

<item myitems>
/ 1 = "Male_A.jpg"
/ 2 = "Male_B.jpg"
/ 3 = "Male_C.jpg"
/ 4 = "Male_D.jpg"

/ 5 = "Female_A.jpg"
/ 6 = "Female_B.jpg"
/ 7 = "Female_C.jpg"
/ 8 = "Female_D.jpg"
</item>

Millisecond Forums » Millisecond Forums » Inquisit 4 » Assigning participants to condition based on sexual orientation

Assigning participants to condition based on sexual orientation

RE: Assigning participants to condition based on sexual orientation