Millisecond Forums » Millisecond Forums » Inquisit 5 » randomising trials/ how to create multiple choice options

randomising trials/ how to create multiple choice options

KS — Mon, 11 Apr 2016 08:52:13 GMT

Hello Inquisiters,
I am trying to create a set of 10 trials in which the participant will hear sounds (which will be a word) and they will then be able to choose the word they heard from 3 words presented on the screen.

So for example, the word they will hear is 'cat' and then they can pick from 'cat' 'mat' 'flat'- and then they will receive feedback on whether their answer was correct or not.

I would like the 10 trials to be presented in a random order.
I would also like the multiple choice options to be presented in a random order.

There is probably a simple way to do this, but I really CAN NOT figure it out.
I would appreciate any advice at all!
Thank you!

RE: randomising trials/ how to create multiple choice options

Dave — Mon, 11 Apr 2016 08:52:13 GMT

> / vposition = list.randomvpos.nextvalue

The element's *vertical* ("v") position is drawn from the indicated list. There are three objects on screen and three different vertical positions in the list. I.e., the three objects vertical positions will vary randomly from trial to trial.

> / select = sound.word.currentindex

Serves to select the items *corresponding* to the displayed sound item for the correct option and distractor elements.

See the "How to present stimulus pairs" topic in the documentation for further details on that.

RE: randomising trials/ how to create multiple choice options

KS — Mon, 11 Apr 2016 07:59:51 GMT

Thank you Dave!
That works brilliantly!
I'm trying to get my head around Inquisit so that I am able to use it and understand it if I need to use this kind of syntax again.
Would you mind explaining these parts to me...

/ vposition = list.randomvpos.nextvalue

/ select = sound.word.currentindex

Thank you for your time! SO helpful!

K.

RE: randomising trials/ how to create multiple choice options

Dave — Mon, 11 Apr 2016 05:56:41 GMT

You do something like this:

<block myblock>
/ trials = [1-2 = word]
</block>

<trial word>
/ stimulusframes = [1=word]
/ validresponse = (0)
/ trialduration = 10
/ branch = [trial.response]
</trial>

<sound word>
/ items = ("cat.wav", "dog.wav")
/ playthrough = true
</sound>

<trial response>
/ stimulusframes = [1=correctoption, distractor1, distractor2]
/ inputdevice = mouse
/ validresponse = (correctoption, distractor1, distractor2)
/ correctresponse = (correctoption)
</trial>

<text correctoption>
/ items = ("cat", "dog")
/ select = sound.word.currentindex
/ hposition = 50%
/ vposition = list.randomvpos.nextvalue
</text>

<text distractor1>
/ items = ("mat", "bog")
/ select = sound.word.currentindex
/ hposition = 50%
/ vposition = list.randomvpos.nextvalue
</text>

<text distractor2>
/ items = ("flat", "fog")
/ select = sound.word.currentindex
/ hposition = 50%
/ vposition = list.randomvpos.nextvalue
</text>

<list randomvpos>
/ items = (40%, 50%, 60%)
/ selectionrate = always
</list>