Millisecond Forums » Millisecond Forums » Inquisit 4 » affective Simon task

affective Simon task

jens — Wed, 28 Sep 2016 01:38:11 GMT

Hello,
I am trying to program an affective Simon task. Participants judge either the color of the stimulus word (green/blue) or when presented in white is emotional value of the stimulus word (positive/negative). I have a list of 4 x 10 words (belonging to different categories: negtra, negemo, postra, posemo). In the experimental block, I need to present each word once in white, blue or green, which at the moment I do not achieve. Words are presented more often than one time in a specific color. The reason for this is obvious. At the moment, there is just random selection which does not work out. I assume that the solution is a (or more) list(s). But I do not manage to set up such list.

Suggestions are welcome.

Best regards Jens

RE: affective Simon task

jens — Wed, 28 Sep 2016 01:38:11 GMT

Hello,
ok, understood. Thanks a lot. The extension to four categories of words works. :-)
Best regards Jens

RE: affective Simon task

Dave — Tue, 27 Sep 2016 11:20:20 GMT

The internal representation of colors is ultimately a numerical value (not a label), hence values.wordcolor is numerical.

RE: affective Simon task

jens — Tue, 27 Sep 2016 07:41:29 GMT

Hello,

thanks a lot, that helps. I hope I can expand it to my four conditions, but that should work. Any suggestion why values.wordcolor gives me numbers instead of color labels, e.g. 4278255360, 4294901760 and 4294967295?

Best regards Jens

RE: affective Simon task

Dave — Tue, 27 Sep 2016 07:09:51 GMT

You need to pair your word items / item numbers with the desired display colors. For the sake of example, suppose you have 4 words and 3 display colors -- you want to display each word in each color exactly once, i.e., you have 4 x 3 = 12 combinations:

<block myblock>
/ screencolor = black
/ trials = [1-12 = mytrial]
</block>

<trial mytrial>
/ ontrialbegin = [values.worditemnumber = list.worditemnumbers.nextvalue; values.wordcolor = list.wordcolors.nextvalue;
    text.word.textcolor = values.wordcolor]
/ stimulusframes = [1=word]
/ validresponse = (57)
</trial>

<text word>
/ items = worditems
/ select = values.worditemnumber
/ txbgcolor = black
/ fontstyle = ("Arial", 5%)
</text>

<item worditems>
/ 1 = "Bird"
/ 2 = "Cat"
/ 3 = "Dog"
/ 4 = "Eel"
</item>

<list worditemnumbers>
/ items = (1,1,1,
    2,2,2,
    3,3,3,
    4,4,4)
</list>

<list wordcolors>
/ items = (blue, green, white,
    blue, green, white,
    blue, green, white,
    blue, green, white)
/ selectionmode = list.worditemnumbers.currentindex
</list>

<values>
/ worditemnumber = 1
/ wordcolor = black
</values>

<data>
/ columns = [date time subject group blocknum blockcode trialnum trialcode response latency correct stimulusitem values.worditemnumber values.wordcolor]
/ separatefiles = true
</data>