Millisecond Forums » Millisecond Forums » Inquisit 4 » Wason rule discovery test

Wason rule discovery test

KoenD — Tue, 29 Nov 2016 17:52:40 GMT

Hi forum users,

I hope you can help me programming the following study: I want to program the classic Wason rule discovery test to assess confirmation bias (Wason, 1960; for an example, see http://www.nytimes.com/interactive/2015/07/03/upshot/a-quick-puzzle-to-test-your-problem-solving.html). I’m not sure how to do this and whether it is even possible in Inquisit. All the help is appreciated!

In the original study participants were presented with a series of three numbers (viz., 2,4,6) and told that the series of numbers confirm to a certain rule. Participants were instructed to discover this rule by writing down sets of three numbers.
After writing down each set, participants were informed whether the series of numbers that was written down confirmed the rule or not. By testing their hypotheses this way, participants could infer the rule behind the series of numbers.

Because the rule is quite simple (three numbers in increasing order of magnitude) I think/hope programming this in inquisit is not very complicated, but I do not know which option/function to use.
Again, all the help is appreciated.

Best, Koen

RE: Wason rule discovery test

KoenD — Tue, 29 Nov 2016 17:52:40 GMT

[quote]

[b]Dave - Tuesday, November 29, 2016[/b]

[quote]

[b]KoenD - Tuesday, November 29, 2016[/b]

[/quote]

It seems to me that all you need is a <surveypage> with three <textbox> elements and a little math to evaluate whether the three entered numbers conform to the rule. In a nutshell (focusing on functionality, not making it look pretty):

<block wasonblock>
/ trials = [1=enter_sequence]
</block>

<surveypage enter_sequence>
/ caption = "We’ve chosen a rule that some sequences of three numbers obey — and some do not.
Your job is to guess what the rule is.
We’ll start by telling you that the sequence 2, 4, 8 obeys the rule.

2 4 8 obeys the rule

Enter a number sequence in the boxes below, and we’ll tell you whether it satisfies the rule or not.
You can test as many sequences as you want."
/ questions = [1=n1; 2=n2; 3=n3]
/ showpagenumbers = false
/ showquestionnumbers = false
/ finishlabel = "CHECK"
/ navigationbuttonsize = (20%, 5%)
/ nextbuttonposition = (40%, 60%)
/ branch = [if (textbox.n1.response < textbox.n2.response && textbox.n2.response < textbox.n3.response) surveypage.correctpage
    else surveypage.errorpage]
</surveypage>

<textbox n1>
/ textboxsize = (20%, 5%)
/ mask = integer
/ position = (15%, 45%)
</textbox>

<textbox n2>
/ textboxsize = (20%, 5%)
/ mask = integer
/ position = (40%, 45%)
</textbox>

<textbox n3>
/ textboxsize = (20%, 5%)
/ mask = integer
/ position = (65%, 45%)
</textbox>

<surveypage correctpage>
/ caption = "Correct!
The sequence
<%textbox.n1.response%> <%textbox.n2.response%> <%textbox.n3.response%>
obeys the rule."
/ questions = [1=solve]
/ showpagenumbers = false
/ showquestionnumbers = false
/ finishlabel = "NEXT"
/ navigationbuttonsize = (20%, 5%)
/ nextbuttonposition = (40%, 60%)
/ branch = [if (radiobuttons.solve.response == "1") surveypage.enter_rule
    else surveypage.enter_sequence]
</surveypage>

<surveypage errorpage>
/ caption = "Wrong!
The sequence
<%textbox.n1.response%> <%textbox.n2.response%> <%textbox.n3.response%>
does NOT obey the rule."
/ questions = [1=solve]
/ showpagenumbers = false
/ showquestionnumbers = false
/ finishlabel = "NEXT"
/ navigationbuttonsize = (20%, 5%)
/ nextbuttonposition = (40%, 60%)
/ branch = [if (radiobuttons.solve.response == "1") surveypage.enter_rule
    else surveypage.enter_sequence]
</surveypage>

<radiobuttons solve>
/ options = ("Check another sequence.", "Stop. I know the rule.")
/ optionvalues = ("0", "1")
/ defaultresponse = ("0")
</radiobuttons>

<surveypage enter_rule>
/ caption = "Describe the rule:"
/ questions = [1=rule_description]
/ showpagenumbers = false
/ showquestionnumbers = false
/ finishlabel = "FINISH"
/ navigationbuttonsize = (20%, 5%)
/ nextbuttonposition = (40%, 60%)
</surveypage>

<textbox rule_description>
/ textboxsize = (50%, 30%)
/ multiline = true
</textbox>

[/quote]

Hi Dave,
This is exactly what I need!!
Thank you very much for the script.
Best, Koen

RE: Wason rule discovery test

Dave — Tue, 29 Nov 2016 09:54:16 GMT

[quote]

[b]KoenD - Tuesday, November 29, 2016[/b]

[/quote]