Millisecond Forums » Millisecond Forums » Inquisit 4 » Random selection of words for encoding list

Random selection of words for encoding list

xxPsyWWUxx — Tue, 13 Jun 2017 08:47:57 GMT

Hello there,
In my experiment a word list for encoding is presented to my subjects. In the following, they will be confronted with a recognition task-list (each word is presented by itself), consisting of "old" words (which have been in the list presented before) and "new" words (which the participants have not seen before"). The participants will have to press the space key to decide whether the word is "old" or "new".
Here it is important that not only the "old" words are extracted from a pool, but also the "new" words. The best solution would be that they come from the same pool, meaning that a word that is "old" for Person A, might be random "new" for Person "A".

Thanks for your help, much appreciated!

RE: Random selection of words for encoding list

Dave — Tue, 13 Jun 2017 08:47:57 GMT

[quote]

[b]xxPsyWWUxx - Tuesday, June 13, 2017[/b]

[quote]

[b]Dave - Monday, June 12, 2017[/b]

[quote]

[b]xxPsyWWUxx - Sunday, June 11, 2017[/b]

[/quote]

Designs like this have been discussed here a number of times. See e.g, https://www.millisecond.com/forums/Topic17069.aspx

[/quote]

Dear Dave, I am sorry but these discussion do not really help me in the moment.
The special thing here is that, in the encoding task every subject sees different words. How can I ensure now that in the recognition task the recently presented words appear and also new words? Furthermore I have to make sure, that words which a correctly judged as new or old are also recognised as correct from Inquisit.

<item AlleWÃ¶rter>
/ 1 = "Heimat"
/ 2 = "Humor"
/ 3 = "Reise"
/ 4 = "Sonne"
/ 5 = "Urlaub"
/ 6 = "Treue"
/ 7 = "Party"
/ 8 = "Advent"
/ 9 = "Bedarf"
/ 10 = "LÃ¤nge"
/ 11 = "Kader"
/ 12 = "Marke"
/ 13 = "Strecke"
/ 14 = "Runde"
/ 15 = "Handel"
/ 16 = "Finger"
/ 17 = "MÃ¶rder"
/ 18 = "Leiche"
/ 19 = "Waffe"
/ 20 = "Armut"
/ 21 = "Panik"
/ 22 = "Falle"
/ 23 = "Verlust"
/ 24 = "Unfall"
</item>

<text BekannteWords>
/fontstyle = ("Arial", 5%, true, false, false, false, 5, 0)
/items = AlleWÃ¶rter
/position=(50%,50%)
</text>

<text NeueWords>
/fontstyle = ("Arial", 5%, true, false, false, false, 5, 0)
/items = AlleWÃ¶rter
/position=(50%,50%)
</text>

one version with BekannteWord: correct response = f, neue word: correct response = j; second version the other way around

<trial BekannteWordsVersion1>
/ stimulusframes = [1-24 = noreplace(BekannteWords)]
/inputdevice = keyboard
/ validresponse = ("F", "J")
/ correctresponse = ("F")
</trial>

<trial NeueWordsVersion1>
/ stimulusframes = [1-24 = noreplace(NeueWords)]
/inputdevice = keyboard
/ validresponse = ("F", "J")
/ correctresponse = ("J")
</trial>

<trial BekannteWordsVersion2>
/ stimulusframes = [1-24 = noreplace(BekannteWords)]
/inputdevice = keyboard
/ validresponse = ("F", "J")
/ correctresponse = ("J")
</trial>

<trial NeueWordsVersion2>
/ stimulusframes = [1-24 = noreplace(NeueWords)]
/inputdevice = keyboard
/ validresponse = ("F", "J")
/ correctresponse = ("F")
</trial>

double check whether amount of trails is correct!

<block AbrufWordsInstructVersion1>
/trials = [1=InstruktionAbrufVersion1]
</block>

<block AbrufWordsVersion1>
/bgstim = (ButtonBekanntVersion1, ButtonNeuVersion1)
/trials = [1-15 = noreplace(BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1, BekannteWordsVersion1,
NeueWordsVersion1, NeueWordsVersion1, NeueWordsVersion1, NeueWordsVersion1, NeueWordsVersion1, NeueWordsVersion1)]
</block>

double check whether amount of trails is correct!

<block AbrufWordsInstructVersion2>
/trials = [1 = InstruktionAbrufVersion2]
</block>

<block AbrufWordsVersion2>
/bgstim = (ButtonBekanntVersion2, ButtonNeuVersion2)
/trials = [1-15 = noreplace(BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2, BekannteWordsVersion2,
NeueWordsVersion2, NeueWordsVersion2, NeueWordsVersion2, NeueWordsVersion2, NeueWordsVersion2, NeueWordsVersion2)]

Thank you so much for your help, I am desperately looking for any advice.

[/quote]

The way you do this is to randomly select a subset of words to be presented / learned (those will be your "old" words) at the start of the experiment (/onexptbegin), and take the rest and designate them as your "new" words -- just like the example linked shows.

Here's a basic example:

<item allwords>
/ 1 = "Heimat"
/ 2 = "Humor"
/ 3 = "Reise"
/ 4 = "Sonne"
/ 5 = "Urlaub"
/ 6 = "Treue"
/ 7 = "Party"
/ 8 = "Advent"
/ 9 = "Bedarf"
/ 10 = "Länge"
/ 11 = "Kader"
/ 12 = "Marke"
/ 13 = "Strecke"
/ 14 = "Runde"
/ 15 = "Handel"
/ 16 = "Finger"
/ 17 = "Mörder"
/ 18 = "Leiche"
/ 19 = "Waffe"
/ 20 = "Armut"
/ 21 = "Panik"
/ 22 = "Falle"
/ 23 = "Verlust"
/ 24 = "Unfall"
</item>

<list allitemnumbers>
/ poolsize = 24
/ selectionrate = always
</list>

<list olditemnumbers>
/ selectionrate = always
</list>

<list newitemnumbers>
/ selectionrate = always
</list>

// select 9 random item numbers out of all 24 item numbers
// and store them in list.olditemnumbers
// select 6 random item numbers out of the 24
// and store them in list.newitemnumbers
<expt>
/ onexptbegin = [
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.olditemnumbers.appenditem(list.allitemnumbers.nextindex);

    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
    list.newitemnumbers.appenditem(list.allitemnumbers.nextindex);
]
/ blocks = [1=learningblock; 2=old_new_block]
</expt>

// learning / presentation phase
<block learningblock>
/ trials = [1=learningtrial]
</block>

<trial learningtrial>
/ stimulusframes = [1=word1,word2,word3,word4,word5,word6,word7,word8,word9,prompt]
/ validresponse = (57)
</trial>

<text word1>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 15%)
</text>

<text word2>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 20%)
</text>

<text word3>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 25%)
</text>

<text word4>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 30%)
</text>

<text word5>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 35%)
</text>

<text word6>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 40%)
</text>

<text word7>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 45%)
</text>

<text word8>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 50%)
</text>

<text word9>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
/ position = (50%, 55%)
</text>

<text prompt>
/ items = ("Remember these words:")
/ position = (50%, 5%)
</text>

// recall / old-new jusdgment phase
<block old_new_block>
/ trials = [1-15 = noreplace(oldtrial, oldtrial, oldtrial, newtrial, newtrial)]
</block>

<trial oldtrial>
/ stimulusframes = [1=oldword, oldnewprompt]
/ validresponse = ("o", "n")
/ correctresponse = ("o")
</trial>

<trial newtrial>
/ stimulusframes = [1=newword, oldnewprompt]
/ validresponse = ("o", "n")
/ correctresponse = ("n")
</trial>

<text oldword>
/ items = allwords
/ select = list.olditemnumbers.nextvalue
</text>

<text newword>
/ items = allwords
/ select = list.newitemnumbers.nextvalue
</text>

<text oldnewprompt>
/ items = ("Press 'O' for 'old', press 'N' for 'new'")
/ position = (50%, 5%)
</text>

RE: Random selection of words for encoding list

xxPsyWWUxx — Tue, 13 Jun 2017 01:22:56 GMT

[quote]

[b]Dave - Monday, June 12, 2017[/b]

[quote]

[b]xxPsyWWUxx - Sunday, June 11, 2017[/b]

[/quote]

Designs like this have been discussed here a number of times. See e.g, https://www.millisecond.com/forums/Topic17069.aspx

[/quote]

RE: Random selection of words for encoding list

Dave — Mon, 12 Jun 2017 09:27:45 GMT

[quote]

[b]xxPsyWWUxx - Sunday, June 11, 2017[/b]

[/quote]

Designs like this have been discussed here a number of times. See e.g, https://www.millisecond.com/forums/Topic17069.aspx