Millisecond Forums » Millisecond Forums » Inquisit 5 » Survey with random item order and disqualification question

Survey with random item order and disqualification question

AnnaStefaniak — Fri, 07 Jul 2017 09:41:07 GMT

Hi, I am very new to Inquisit and trying to program a survey. I am using some demographic questions and then several scales (i.e. lists of questions). I have programmed all my items - most use the "slider" function - but now have 2 major problems that I stumbled upon. I used to work with Qualtrics, where all this would take me half an hour to program, but now am forced to quickly learn Inquisit...

1) I have a demographic qualification question about race. The question has 7 options but I only want people who self identify as being Black or White to participate (hence want to disqualify those who choose other options and take them to a "thank you for your interest page". I also need those who select either Black or White as their identification to get the survey with wording reflecting their self-identification (I have items designed for each group).

2) I would like to present the items that make up the scales that I am using in a randomized order.

How do I do all this? I will be thankful if somebody could send me script(s) of similar studies, tips, and any advice really.

Thank you for your help.
Anna

RE: Survey with random item order and disqualification question

Dave — Fri, 07 Jul 2017 09:41:07 GMT

[quote]

[b]AnnaStefaniak - Friday, July 7, 2017[/b]

Thank you for this answer!

I am still a little confused about branching. Ill try to give more detail about what I want to do.

Here is my qualification question:
<dropdown Race>
/ caption = "Do you identify as:"
/ options = ("American Indian or Alaska Native", "Asian", "Black or African American", "Hispanic, Latina/Latino or Spanish origin", "Native Hawaiian or Other Pacific Islander", "White", "Some other race or origin")
/ fontstyle = ("Calibri", 13pt, true, false, false, false, 5, 0)
</dropdown>

I'd like the participants who select "Black or African American" to then receive one block of questions and the participants who choose "White" to receive a different block. Furthermore I need the participants who select any other option to be taken to a disqualification page. After the two blocks that will be different for people who select either "Black" or "White" - the rest of the survey is identical.

How would the "branch" option work here? Tried specifying it for all the options from the qualification questions, but unfortunately it didn't work.

Thank you for your help!

[/quote]

> How would the "branch" option work here? Tried specifying it for all the options from the qualification questions, but unfortunately it didn't work.

You should use the /skip here instead of /branch -- it will be easier.

<dropdown Race>
/ caption = "Do you identify as:"
/ options = ("American Indian or Alaska Native", "Asian", "Black or African American", "Hispanic, Latina/Latino or Spanish origin", "Native Hawaiian or Other Pacific Islander", "White", "Some other race or origin")
/ fontstyle = ("Calibri", 13pt, true, false, false, false, 5, 0)
</dropdown>

<expt>
/ blocks = [1=raceblock; 2=sequence(blackblock, whiteblock); 3=remainingblock; 4=disqualificationblock]
</expt>

<block raceblock>
/ trials = [1=racepage]
</block>

//your pages w/ questions for black participants go here
//skip if response was NOT black
<block blackblock>
/ skip = [dropdown.race.response != "Black or African American"]
/ trials = [1=blackpage]
</block>

//your pages w/ questions for white participants go here
//skip if response was NOT white
<block whiteblock>
/ skip = [dropdown.race.response != "White"]
/ trials = [1=whitepage]
</block>

//remaining questions identical for black and white participants go here
//skip for ineligible participants
<block remainingblock>
/ skip = [dropdown.race.response != "Black or African American" && dropdown.race.response != "White"]
/ trials = [1=remainingpage]
</block>

//disqualification message for all others
//skip for eligible participants (black or white)
<block disqualificationblock>
/ skip = [dropdown.race.response == "Black or African American" || dropdown.race.response == "White"]
/ trials = [1=disqualificationpage]
</block>

<surveypage racepage>
/ questions = [1=race]
</surveypage>

<surveypage blackpage>
/ caption = "for black participants only"
</surveypage>

<surveypage whitepage>
/ caption = "for white participants only"
</surveypage>

<surveypage remainingpage>
/ caption = "for all eligible participants (black and white)"
</surveypage>

<surveypage disqualificationpage>
/ caption = "you are not eligible to participate (neither black nor white)"
</surveypage>

RE: Survey with random item order and disqualification question

AnnaStefaniak — Fri, 07 Jul 2017 02:13:48 GMT

RE: Survey with random item order and disqualification question

Dave — Wed, 05 Jul 2017 10:08:12 GMT

[quote]

[b]AnnaStefaniak - Wednesday, July 5, 2017[/b]

[/quote]

You can achieve #1 with /branch and/or /skip logic on your <surveypage>s. Basically, what you do is /skip the pages a given participant is not supposed to receive. See e.g.
https://www.millisecond.com/forums/Topic5460.aspx#bm5461

#2 depends on how you've arranged things. You can randomize the order of <surveypage>s via the <survey>'s /pages attribute:

<survey mysurvey>
/ pages = [1-4=noreplace(page_a, page_b, page_c, page_d)
...
</survey>

You can randomize the order of questions on a given <surveypage> via its /questions attribute:

<surveypage mypage>
/ questions = [1-3=noreplace(q1, q2, q3)
...
</surveypage>