Millisecond Forums » Millisecond Forums » Inquisit 5 » radiobuttons: images and columns; global timer

radiobuttons: images and columns; global timer

psychostudy — Tue, 09 Jan 2018 16:21:50 GMT

Hello,
I've got a few questions reading the construction of a matrices test, which I want to have as part of my experiment:
Basically I want to present the pattern and the participants have to choose between the missing elements (implemented as pictures), one exercise per page. Since they may skip forward if they can't solve one and come back to it later, I opted for implementing it with radiobuttons, since it's easy to go forward/backwards and the participants can see easily which one they already solved.

So here are my questions:
1.) Is it possible to tie images directly to the radiobuttons (i.e. to implement them as /options)?
2.) Is it possible to have multiple columns with one single radiobutton element, or do you have to make a separate one for each column?
3.) I'd like to put a time limit on the task, which should be visible on every page, and end the block (as it is just a part of an experiment) regardless on which page they are. Is something like that possible?

thanks for your answers in advance.

RE: radiobuttons: images and columns; global timer

Dave — Tue, 09 Jan 2018 16:21:50 GMT

[quote]

[b]psychostudy - Tuesday, January 9, 2018[/b]

thank you, that works fine, though no matter how big I make the textbox, I can only write in it on the first line. Did I miss something?

[/quote]

If you want the textbox to allow for multi-line entry, set its /multiline attribute to 'true', i.e.

<radiobuttons myrb>
/ options = ("A","B","C")
/ other = otherbox
</radiobuttons>

<textbox otherbox>
/ caption = "Other:"
/ textboxsize = (30%,10%)
/ multiline = true
</textbox>

<surveypage mypage>
/ questions = [1=myrb]
</surveypage>

Hope this helps!

RE: radiobuttons: images and columns; global timer

psychostudy — Tue, 09 Jan 2018 15:21:36 GMT

thank you, that works fine, though no matter how big I make the textbox, I can only write in it on the first line. Did I miss something?

RE: radiobuttons: images and columns; global timer

Dave — Tue, 09 Jan 2018 08:48:30 GMT

[quote]

[b]psychostudy - Tuesday, January 9, 2018[/b]

Thank you very much!

Another question regarding Radiobuttons though, if I use the /other option, is there a way to customize the size of the textbox appearing?

[/quote]

Yes, you can do this by defining a separate <textbox> element and specifying that in the <radiobuttons> /other attribute:

<radiobuttons myrb>
/ options = ("A","B","C")
/ other = otherbox
</radiobuttons>

<textbox otherbox>
/ caption = "Other:"
/ textboxsize = (30%,10%)
</textbox>

<surveypage mypage>
/ questions = [1=myrb]
</surveypage>

RE: radiobuttons: images and columns; global timer

psychostudy — Tue, 09 Jan 2018 06:34:42 GMT

Thank you very much!

Another question regarding Radiobuttons though, if I use the /other option, is there a way to customize the size of the textbox appearing?

RE: radiobuttons: images and columns; global timer

Dave — Tue, 02 Jan 2018 09:32:05 GMT

[quote]

[b]psychostudy - Monday, January 1, 2018[/b]

Have to "revive" yet another old thread, but the questions are related to previous things:

1) earlier I asked you follwing question and you wrote this:
> that you can make a short message appear in the sense of "you ticked too many boxes"?

Yes. From the page with your checkboxes /branch to another page that displays the "too many boxes" message if too many boxes have been ticked. From there, /branch back to the original page.
----------------
My question is, if I have multiple survey pages, can I have a sort of global "error" page, which is linked to all of them and then automatically branches back to whatever current survey page the participant was on before, or do I have to setup a different "error" page for each?

Kinda related to this, is it possible to have a sort of error message pop up/ branching to an error page when using radiobuttons? In the case if the participant chooses a wrong answer and wants to proceed.

and my last question for now, for the instructions, I want certain words inside of a paragraph to be in different colors. Is there an easy way to go about it or do I have to make a separate <text> element for the colored words and try positioning them in the paragraph?

[/quote]

> My question is, if I have multiple survey pages, can I have a sort of global "error" page, which is linked to all of them and then automatically branches back to whatever current survey page the participant was on before, or do I have to setup a different "error" page for each?

Maybe. Ultimately, this depends on how you've set up the script. If you store whatever the previous surveypage was in a <values> entry, you can /branch back to the respective page via a <list>, for example:

<values>
/ pg = 1
</values>

<block myblock>
/ trials = [1-3 = noreplace(a,b,c)]
</block>

<surveypage a>
/ caption = "Page A"
/ ontrialbegin = [
    values.pg = 1;
]
/ questions = [1=qa]
/ branch = [
    if (radiobuttons.qa.response=="error") surveypage.errorpage
]
</surveypage>

<surveypage b>
/ caption = "Page B"
/ ontrialbegin = [
    values.pg = 2;
]
/ questions = [1=qb]
/ branch = [
    if (radiobuttons.qb.response=="error") surveypage.errorpage
]
</surveypage>

<surveypage c>
/ caption = "Page C"
/ ontrialbegin = [
    values.pg = 3;
]
/ questions = [1=qc]
/ branch = [
    if (radiobuttons.qc.response=="error") surveypage.errorpage
]
</surveypage>

<surveypage errorpage>
/ caption = "this is the global error page. we'll branch back to the previous surveypage"
/ branch = [
    list.pagelist.nextvalue
]
</surveypage>

<radiobuttons qa>
/ options = ("proceed normally", "go to error page")
/ optionvalues = ("normal", "error")
</radiobuttons>

<radiobuttons qb>
/ options = ("proceed normally", "go to error page")
/ optionvalues = ("normal", "error")
</radiobuttons>

<radiobuttons qc>
/ options = ("proceed normally", "go to error page")
/ optionvalues = ("normal", "error")
</radiobuttons>

<list pagelist>
/ items = (surveypage.a, surveypage.b, surveypage.c)
/ select = values.pg
</list>

> Kinda related to this, is it possible to have a sort of error message pop up/ branching to an error page when using radiobuttons? In the case if the participant chooses a wrong answer and wants to proceed.

The above example code should cover that.

> and my last question for now, for the instructions, I want certain words inside of a paragraph to be in different colors. Is there an easy way to go about it or do I have to make a separate <text> element for the colored words and try positioning them in the paragraph?

Several options apart from separate <text> elements:

(1) Use HTML. Format the HTML as desired (i.e. different fonts, color, etc. for certain words as needed) and display the resulting HTML file as a <htmlpage> instruction page or in a regular <trial> as <html> stimulus.

(2) Prepare your instructions in the word processor of your choice with all the desired formatting (different colors, etc.), take a screenshot, and then simply have Inquisit display the resulting image file as a <picture> stimulus in a regular <trial>.

RE: radiobuttons: images and columns; global timer

psychostudy — Mon, 01 Jan 2018 17:03:43 GMT

RE: radiobuttons: images and columns; global timer

Dave — Mon, 13 Nov 2017 16:58:54 GMT

[quote]

[b]psychostudy - Monday, November 13, 2017[/b]

that was very helpful, thanks again!
just a small add-on: I actually wanted to ask for a whole survey and not only a surveypage, but I tried it out (in a block, since there will be branching to <trials> as well) and seems to work out just fine. So my question is, if I declare something like this

<block example>
/ pages =[1-4 = noreplace (w,x,y,z)]
</block>
where w,x,y,z are surveypages, am I right in the assumption that each page will only be shown once, and not that it skips a page or shows a page twice?

[/quote]

It should read

<block example>
/ trials = [1-4 = noreplace (w,x,y,z)]
</block>

(the <block> element has no /pages attribute, only the <survey> element does), but otherwise you are correct.

<block example>
/ trials = [1-4 = noreplace (w,x,y,z)]
</block>

will give you one instance of <surveypage w>, one instance of <surveypage x>, one instance of <surveypage y>, and one instance of <surveypage z> in random order.

RE: radiobuttons: images and columns; global timer

psychostudy — Mon, 13 Nov 2017 16:15:03 GMT

RE: radiobuttons: images and columns; global timer

Dave — Mon, 13 Nov 2017 15:34:05 GMT

[quote]

[b]psychostudy - Monday, November 13, 2017[/b]

Ok thanks, that helped out!
For 3) I meant the position of the answers (/options) of a single /radiobutton element, for example if you could space them out a bit.
for 4) yeah I must've mixed them up.

Also sorry, but got yet another question: Is it possible to randomize the question order of a surveypage?

[/quote]

> For 3) I meant the position of the answers (/options) of a single /radiobutton element, for example if you could space them out a bit.

Thanks for the clarification. Several options:

You can use

/ orientation = horizontalequal

<radiobuttons example>
/ options = ("cat", "dog", "elephant")
/ orientation = horizontalequal
</radiobuttons>

<surveypage mypage>
/ questions = [1=example]
</surveypage>

or you can pad options with spaces or tabs:

<radiobuttons example>
/ options = ("cat~t", "dog~t", "elephant")
/ orientation = horizontal
</radiobuttons>

<surveypage mypage>
/ questions = [1=example]
</surveypage>

> Is it possible to randomize the question order of a surveypage?

Yes. Like so:

<surveypage mypage>
/ questions = [1-3 = noreplace(a,b,c)]
</surveypage>

<radiobuttons a>
/ options = ("A1", "A2")
/ orientation = horizontalequal
</radiobuttons>

<radiobuttons b>
/ options = ("B1", "B2")
/ orientation = horizontalequal
</radiobuttons>

<radiobuttons c>
/ options = ("C1", "C2")
/ orientation = horizontalequal
</radiobuttons>

RE: radiobuttons: images and columns; global timer

psychostudy — Mon, 13 Nov 2017 14:32:07 GMT

RE: radiobuttons: images and columns; global timer

Dave — Mon, 13 Nov 2017 08:53:33 GMT

[quote]

[b]psychostudy - Monday, November 13, 2017[/b]

Thank you, that did indeed help!
I got some further questions though:
1) Is it possible to implement a button on each page of a block, which, when pressed, quits the block, so participants could end the test (if they finished before time runs out) regardless on which page they are?
2) I implemented the answer limitation similar to your posted example,as I worked for this task with check boxes as well (-->counting the numbers of ticked boxes,if it's too high, you can't proceed). Now is there a possibility that, when someone tries to move to the next page with too many check boxes ticked, that you can make a short message appear in the sense of "you ticked too many boxes"?

3)again for the radiobuttons: Is there a possibility to decide the position of the answers of a single item beyond the /orientation command?

also some questions for the /include command:
4) if two or more experiments have elements with the same name, it gets an error. I recall seeing a tutorial, where you can handle this collision directly in the the file where you include the other experiments instead of renaming every single element in one of the experiments, but I can't find it anymore. Anyone might know what I'm talking about and have a link?
5) I want to include another experiment, which is located in a different folder. By choosing its path, it can include the experiment with no problems, however, if this experiment contains pictures (which are also located in that folder), I get an error message, saying it can't find the pictures. Is there a way around this or do I just have to include the pictures in the same folder where I have the File that runs the /include command?

thanks again in advance for answers

[/quote]

> 1) Is it possible to implement a button on each page of a block, which, when pressed, quits the block, so participants could end the test
> (if they finished before time runs out) > regardless on which page they are?

You'd have to include a <radiobuttons> question or the like on the respective <surveypage>s (or define some additional response in any <trial>s) that -- if answered in some fashion -- terminates the rest of the <block> via a /stop command.

<surveypage pg1>
/ caption = "Page 1 of 3"
/ questions = [1=a; 2=quitq]
</surveypage>

<surveypage pg2>
/ caption = "Page 2 of 3"
/ questions = [1=b; 2=quitq]
</surveypage>

<surveypage pg3>
/ caption = "Page 3 of 2"
/ questions = [1=c; 2=quitq]
</surveypage>

<radiobuttons quitq>
/ caption = ("Would you like to quit?"
/ options = ("Yes", "No")
/ defaultresponse = "No"
</radiobuttons>

<dropdown a>
/ options = ("A1", "A2")
</dropdown>
<dropdown b>
/ options = ("B1", "B2")
</dropdown>
<dropdown c>
/ options = ("C1", "C2")
</dropdown>

<block myblock>
/ stop = [radiobuttons.quitq.response == "Yes"]
/ trials = [1=pg1; 2=pg2; 3=pg3]
</block>

> 2) I implemented the answer limitation similar to your posted example,as I worked for this task with check boxes as well (-->counting the numbers of ticked boxes,
> if it's too high, you can't proceed). Now is there a possibility that, when someone tries to move to the next page with too many check boxes ticked,
> that you can make a short message appear in the sense of "you ticked too many boxes"?

Yes. From the page with your checkboxes /branch to another page that displays the "too many boxes" message if too many boxes have been ticked. From there, /branch back to the original page.

> 3)again for the radiobuttons: Is there a possibility to decide the position of the answers of a single item beyond the /orientation command?

I'm not quite sure what you mean here, but you can define the position of any given <radiobuttons> element via its /position attribute.

> 4) if two or more experiments have elements with the same name, it gets an error. I recall seeing a tutorial, where you can handle
> this collision directly in the the file where you include the other experiments instead of renaming every single element
> in one of the experiments, but I can't find it anymore. Anyone might know what I'm talking about and have a link?

I believe you are mistaken here. This is not possible with <include> -- all <include> does is effectively paste the contents of an external file into the main file; i.e. it is the same as having everything in a single file. As such, there may not be any name collisions, regardless of whether you use <include> or not.

If you have several self-contained experiments, however, you may execute those in the desired order one after another via <batch>, which is entirely different from <include>.

> 5) I want to include another experiment, which is located in a different folder. By choosing its path, it can include the experiment with no problems,
> however, if this experiment contains pictures (which are also located in that folder), I get an error message, saying it can't find the pictures.
> Is there a way around this or do I just have to include the pictures in the same folder where I have the File that runs the /include command?

You can specify the path to the image files in the respective script's <item> elements.

RE: radiobuttons: images and columns; global timer

psychostudy — Mon, 13 Nov 2017 04:51:54 GMT

RE: radiobuttons: images and columns; global timer

Dave — Mon, 30 Oct 2017 10:41:11 GMT

[quote]

[b]psychostudy - Saturday, October 28, 2017[/b]

[/quote]

> 1.) Is it possible to tie images directly to the radiobuttons (i.e. to implement them as /options)?

No, it's not possible to define images _directly_ as /options. You would have to build something like this: http://library.millisecond.com/v3/selectitems/selectitems.zip

> 2.) Is it possible to have multiple columns with one single radiobutton element, or do you have to make a separate one for each column?

Due to #1 above, you will probably have to define separate <radiobuttons> elements.

> 3.) I'd like to put a time limit on the task, which should be visible on every page, and end the block (as it is just a part of an experiment) regardless on which page they are. Is
> something like that possible?

You can define a /timeout at the <block> or <survey> level. You can potentially set up a <clock> stimulus counting down the time remaining and display that stimulus via /stimulusframes or the <block>'s /bgstim.

Hope this helps.