Inserting White Blanks When The Participant Gets the Trial Incorrect

Taylor — Mon, 11 Mar 2019 05:09:36 GMT

I am currently coding the inquisit for a stereotyping project and I have run into some trouble regarding the blanks. The method for how the blanks should work is:

If the response was correct, a blank screen appeared for 8000 ms before the presentation of the next trial. If the response was incorrect, a blank screen appeared for 8000 ms, followed by a red “X” in the center of the screen for 8000 ms, and a blank screen for 8000 ms before the next trial began.

I don't know how to specify the blank screens appearing for the incorrect responses. Right now I have it coded where a blank screen appears for 8000 ms after each trial (coded as individual trials in blocks, shown below) but I can't figure out how to have the blanks appear for 8000 ms then show an X then appear for 8000 ms if the participant answered incorrectly. Hopefully, this makes sense. I inserted the code used for the blanks below for reference of what I have so far.

<trial Whitetrial>
/ stimulusframes = [1 = White]
/ trialduration = 1000
/ correctresponse = (noresponse)
</trial>

<block ReductionBlock1>
/ bgstim = (attributeAleft, attributeBright)
/ trials = [1=instructions; 2, 4, 6, 8, 10, 12, 14, 16, 18, 20, 22, 24,26,28,30,32,34,36,38,40,42,44,46,48,50,52,54,56,58,60,62,64,66,68,70,72,74,76,78,80,82 = Whitetrial;
3, 5, 7, 9, 11, 13, 15, 17, 19, 21,23,25,27,29,31,33,35,37,39,41,43,45,47,49,51,53,55,57,59,61,63,65,67,69,71,73,75,77,79,81 = random(targetAleft,targetBright)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

RE: Inserting White Blanks When The Participant Gets the Trial Incorrect

Dave — Mon, 11 Mar 2019 05:09:36 GMT

[quote]

[b]Taylor - Saturday, March 9, 2019[/b]

[/quote]

You should set up two separate <trial> elements -- one 8000ms white screen trial, one (8000ms white screen + 8000ms red X + 8000ms white screen) trial -- then /branch to the appropriate trial based on the response, i.e. do not run those trials via the <block>'s /trials. Example:

<block exampleblock>
/ trials = [1-4 = noreplace(a,b)]
</block>

<trial a>
/ stimulusframes = [1=astim]
/ validresponse = ("a", "b")
/ correctresponse = ("a")
/ branch = [
if (trial.a.error) trial.redx else trial.whitescreen;
]
</trial>

<trial b>
/ stimulusframes = [1=bstim]
/ validresponse = ("a", "b")
/ correctresponse = ("b")
/ branch = [
if (trial.b.error) trial.redx else trial.whitescreen;
]
</trial>

<text astim>
/ items = ("Press A or B. A is correct.")
</text>

<text bstim>
/ items = ("Press A or B. B is correct.")
</text>

<trial whitescreen>
/ stimulusframes = [1=clearscreen]
/ trialduration = 1000
/ validresponse = (0)
</trial>

<trial redx>
/ stimulustimes = [0=clearscreen; 1000=x; 2000=clearscreen]
/ trialduration = 3000
/ validresponse = (0)
</trial>

<text x>
/ items = ("X")
/ txcolor = red
</text>

Millisecond Forums » Millisecond Forums » Inquisit 5 » Inserting White Blanks When The Participant Gets the Trial Incorrect

Inserting White Blanks When The Participant Gets the Trial Incorrect

RE: Inserting White Blanks When The Participant Gets the Trial Incorrect