Millisecond Forums » Millisecond Forums » Inquisit 5 » Help me create a delayed discounting task.

Help me create a delayed discounting task.

nairegor — Wed, 25 Sep 2019 07:11:09 GMT

greeting.

i am graduate student in korea
I'm studying delayed discounting and smartphone addiction.
I would like to measure the delay discount through inquisit.

but
Script creation is really hard. Help.
Although there are delayed discount tools on the inquisit homepage Not the tool I want

I want to build a tool based on the monetary choice questionnaire created by kirbty (1999).
The order of the delayed discount assignment I want to make is as follows.

intro -> 2 practice trials -> real intro -> real trials.-> Finish.

There are 27 trials.
Participants choose one of two proposals for each trial.

1. Would you prefer $54 today, or $55 in 117 days?
2. Would you prefer $55 today, or $75 in 61 days?
3. Would you prefer $19 today, or $25 in 53 days?
4. Would you prefer $31 today, or $85 in 7 days?
5. Would you prefer $14 today, or $25 in 19 days?
6. Would you prefer $47 today, or $50 in 160 days?
7. Would you prefer $15 today, or $35 in 13 days?
8. Would you prefer $25 today, or $60 in 14 days?
9. Would you prefer $78 today, or $80 in 162 days?
10. Would you prefer $40 today, or $55 in 62 days?
11. Would you prefer $11 today, or $30 in 7 days?
12. Would you prefer $67 today, or $75 in 119 days?
13. Would you prefer $34 today, or $35 in 186 days?
14. Would you prefer $27 today, or $50 in 21 days?
15. Would you prefer $69 today, or $85 in 91 days?
16. Would you prefer $49 today, or $60 in 89 days?
17. Would you prefer $80 today, or $85 in 157 days?
18. Would you prefer $24 today, or $35 in 29 days?
19. Would you prefer $33 today, or $80 in 14 days?
20. Would you prefer $28 today, or $30 in 179 days?
21. Would you prefer $34 today, or $50 in 30 days?
22. Would you prefer $25 today, or $30 in 80 days?
23. Would you prefer $41 today, or $75 in 20 days?
24. Would you prefer $54 today, or $60 in 111 days?
25. Would you prefer $54 today, or $80 in 30 days?
26. Would you prefer $22 today, or $25 in 136 days?
27. Would you prefer $20 today, or $55 in 7 days?

How to display each amount
1. As you select each amount, they appear simultaneously on the screen.
2. Each amount is displayed inside a box
3. Participants click on the preferred amount.

so.. so.. hard. plz help me.

sincerely, young joo.

RE: Help me create a delayed discounting task.

nairegor — Wed, 25 Sep 2019 07:11:09 GMT

thanks dave.. very thanks. I will write down your help in my thesis

RE: Help me create a delayed discounting task.

nairegor — Wed, 25 Sep 2019 07:09:34 GMT

In the same way, the exercise will be performed four times by selecting one from two options
Would you prefer A, B?
1. As you select each amount, they appear simultaneously on the screen.
2. Each amount is displayed inside a box
3. Participants click on the preferred amount.
4. A and B have nothing to do with the amount.
5. A and B ask questions by comparing them whit fruits and objects.
6. Practice trail is not record datasheet.

Practice intro(for page) -> Practice trail 4 time -> real intro(present script)

The reason for doing this is to learn the task through practice, and the reason for presenting it with fruits and objects is not to affect the actual trial.

I'm so sorry to keep asking questions.

RE: Help me create a delayed discounting task.

Dave — Wed, 25 Sep 2019 07:07:52 GMT

[quote]

[b]nairegor - 9/25/2019[/b]

With your help, I modified the script as follows:

What I want to add is below

Introduction to practice-> 1. Bananas and cars 2. Apples and notebooks, 3. Grapefruits compared to airplanes After the practice trials-> I want to connect to realintㄱo (the script we just worked on). Only twists ㅠ

<list immediate_amounts>
/ items = (54, 55, 19, 31, 14, 47, 15, 25, 78, 40, 11, 67, 34, 27, 69, 49, 80, 24, 33, 28, 34, 25, 41, 54, 54, 22, 20)
/ selectionmode = sequence
</list>

<list delayed_amounts>
/ items = (55, 75, 25, 85, 25, 50, 35, 60, 80, 55, 30, 75, 35, 50, 85, 60, 85, 35, 80, 30, 50, 30, 75, 60, 80, 25, 55)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<list delay_periods>
/ items = (117, 61, 53, 7, 19, 160, 13, 14, 162, 62, 7, 119, 186, 21, 91, 89, 157, 29, 14, 179, 30, 80, 20, 111, 30, 136, 7)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<values>
/ immediate_amount = 0
/ delayed_amount = 0
/ delay_period = 0
</values>

<trial choicetrial>
/ posttrialpause = 1000
/ ontrialbegin = [
values.immediate_amount = list.immediate_amounts.nextvalue;
values.delayed_amount = list.delayed_amounts.nextvalue;
values.delay_period = list.delay_periods.nextvalue;
]
/ stimulusframes = [1=immediate, delayed, pre, or, instructions]
/ validresponse = (immediate, delayed)
/ inputdevice = mouse
</trial>

<text pre>
/ items = ("둘 중 어느 것을 더 선호하십니까?")
/ fontstyle = ("맑은고딕", 5%, true, false, false, false, 5, 1)
/ size = (80%, 10%)
/ position = (50%, 40%)
</text>

<text or>
/ items = ("또는")
/ position = (50%, 50%)
</text>

<text immediate>
/ items = ("지금 당장 <%values.immediate_amount%> 만원을 받는 것")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (30%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<text delayed>
/ items = ("<%values.delay_period%>일 후에 <%values.delayed_amount%> 만원을 받는 것")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (70%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<text instructions>
/ items = ("선호 하는 것을 클릭하세요")
/ position = (50%, 65%)
/ txcolor = gray
/ size = (80%, 5%)
/ vjustify = center
</text>

<block choiceblock>
/ preinstructions = (realintro)
/ postinstructions = (realoutro)
/ trials = [1-27 = choicetrial]
</block>

<page realintro>
^Instructions for the real trials go here.
</page>

<page realoutro>
^끝났습니다^
</page>

<data>
/ separatefiles = true
/ columns = (build, computer.platform, date, time, subject, group, blockcode, blocknum, trialcode, trialnum,
values.immediate_amount, values.delayed_amount, values.delay_period, response, latency)
</data>

[/quote]

Add a block and trial, etc. for the practice part -- it works the same way as the test part. Run the practice block before the test block per an <expt> element's /blocks attribute. To prevent the recording of the practice trials, use the /recorddata attribute as already explained. You will find basics like this covered in the tutorials, so please work through those before moving on: https://www.millisecond.com/support/docs/v5/html/tutorials/tutorials.htm

<list immediate_amounts>
/ items = (54, 55, 19, 31, 14, 47, 15, 25, 78, 40, 11, 67, 34, 27, 69, 49, 80, 24, 33, 28, 34, 25, 41, 54, 54, 22, 20)
/ selectionmode = sequence
</list>

<list delayed_amounts>
/ items = (55, 75, 25, 85, 25, 50, 35, 60, 80, 55, 30, 75, 35, 50, 85, 60, 85, 35, 80, 30, 50, 30, 75, 60, 80, 25, 55)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<list delay_periods>
/ items = (117, 61, 53, 7, 19, 160, 13, 14, 162, 62, 7, 119, 186, 21, 91, 89, 157, 29, 14, 179, 30, 80, 20, 111, 30, 136, 7)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<values>
/ immediate_amount = 0
/ delayed_amount = 0
/ delay_period = 0

/ practice_option_left = ""
/ practice_option_right = ""
</values>

<trial choicetrial>
/ posttrialpause = 1000
/ ontrialbegin = [
values.immediate_amount = list.immediate_amounts.nextvalue;
values.delayed_amount = list.delayed_amounts.nextvalue;
values.delay_period = list.delay_periods.nextvalue;
]
/ stimulusframes = [1=immediate, delayed, pre, or, instructions]
/ validresponse = (immediate, delayed)
/ inputdevice = mouse
</trial>

<text pre>
/ items = ("둘 중 어느 것을 더 선호하십니까?")
/ fontstyle = ("맑은고딕", 5%, true, false, false, false, 5, 1)
/ size = (80%, 10%)
/ position = (50%, 40%)
</text>

<text or>
/ items = ("또는")
/ position = (50%, 50%)
</text>

<text immediate>
/ items = ("지금 당장 <%values.immediate_amount%> 만원을 받는 것")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (30%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<text delayed>
/ items = ("<%values.delay_period%>일 후에 <%values.delayed_amount%> 만원을 받는 것")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (70%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<text instructions>
/ items = ("선호 하는 것을 클릭하세요")
/ position = (50%, 65%)
/ txcolor = gray
/ size = (80%, 5%)
/ vjustify = center
</text>

<block choiceblock>
/ preinstructions = (realintro)
/ postinstructions = (realoutro)
/ trials = [1-27 = choicetrial]
</block>

<page realintro>
^Instructions for the real trials go here.
</page>

<page realoutro>
^끝났습니다^
</page>

<data>
/ separatefiles = true
/ columns = (build, computer.platform, date, time, subject, group, blockcode, blocknum, trialcode, trialnum,
values.immediate_amount, values.delayed_amount, values.delay_period, response, latency)
</data>

<block practicechoiceblock>
/ preinstructions = (practiceintro)
/ postinstructions = (practiceoutro)
/ trials = [1-3 = practicechoicetrial]
/ recorddata = false
</block>

<page practiceintro>
^Intro to practice
</page>

<page practiceoutro>
^End of practice
</page>

<trial practicechoicetrial>
/ posttrialpause = 1000
/ ontrialbegin = [
values.practice_option_left = list.practice_left.nextvalue;
values.practice_option_right = list.practice_right.nextvalue;
]
/ stimulusframes = [1=left, right, pre, or]
/ validresponse = (left, right)
/ inputdevice = mouse
</trial>

<text left>
/ items = ("<%values.practice_option_left%>")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (30%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<text right>
/ items = ("<%values.practice_option_right%>")
/ fontstyle = ("맑은고딕", 3%, true, false, false, false, 5, 1)
/ position = (70%, 50%)
/ txbgcolor = black
/ txcolor = white
/ size = (25%, 15%)
/ vjustify = center
</text>

<list practice_left>
/ items = ("Bananas", "Apples", "Grapefruits")
/ selectionmode = sequence
</list>

<list practice_right>
/ items = ("Cars", "Notebooks", "Airplanes")
/ selectionmode = list.practice_left.currentindex
</list>

<expt>
/ blocks = [1 = practicechoiceblock; 2 = choiceblock]
</expt>

RE: Help me create a delayed discounting task.

nairegor — Wed, 25 Sep 2019 06:35:28 GMT

RE: Help me create a delayed discounting task.

Dave — Wed, 25 Sep 2019 06:06:33 GMT

[quote]

[b]nairegor - 9/25/2019[/b]

Dave.
I really appreciate everything you’ve done. I couldn’t have done it without you.
Based on the script you have made it was converted into 27 trials, and translated into Korean.

and I want to make a practice run about four times, and I don't want the exercise to be included in the results. What can I do?

[/quote]

Set the practice <block>'s and/or <trial>'s /recorddata attribute to false if you don't want those recorded in the data file.

RE: Help me create a delayed discounting task.

nairegor — Wed, 25 Sep 2019 05:06:46 GMT

RE: Help me create a delayed discounting task.

Dave — Wed, 25 Sep 2019 04:39:37 GMT

[quote]

[b]nairegor - 9/25/2019[/b]

[/quote]

<list immediate_amounts>
/ items = (54, 55, 19, 31, 14)
/ selectionmode = sequence
</list>

<list delayed_amounts>
/ items = (55, 75, 25, 85, 25)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<list delay_periods>
/ items = (117, 61, 53, 7, 19)
/ selectionmode = list.immediate_amounts.currentindex
</list>

<values>
/ immediate_amount = 0
/ delayed_amount = 0
/ delay_period = 0
</values>

<trial choicetrial>
/ posttrialpause = 1000
/ ontrialbegin = [
values.immediate_amount = list.immediate_amounts.nextvalue;
values.delayed_amount = list.delayed_amounts.nextvalue;
values.delay_period = list.delay_periods.nextvalue;
]
/ stimulusframes = [1=immediate, delayed, pre, or]
/ validresponse = (immediate, delayed)
/ inputdevice = mouse
</trial>

<text pre>
/ items = ("Would you prefer")
/ position = (50%, 40%)
</text>

<text or>
/ items = ("or")
/ position = (50%, 50%)
</text>

<text immediate>
/ items = ("<%values.immediate_amount%>$ today")
/ position = (30%, 50%)
/ txbgcolor = grey
/ size = (20%, 10%)
/ vjustify = center
</text>

<text delayed>
/ items = ("<%values.delayed_amount%>$ in <%values.delay_period%> days?")
/ position = (70%, 50%)
/ txbgcolor = grey
/ size = (20%, 10%)
/ vjustify = center
</text>

<block choiceblock>
/ preinstructions = (realintro)
/ trials = [1-5 = choicetrial]
</block>

<page realintro>
^Instructions for the real trials go here.
</page>