Millisecond Forums » Millisecond Forums » Inquisit 6 » ending practice trails early

ending practice trails early

peter — Fri, 07 Oct 2022 23:58:17 GMT

Hi, I have been asked to tweak my script so that the practice trials end if the participant responds to 8 out of the last 10 trials correctly.

This is probably super easy but I cant seem to figure it out.
Any help greatly appreciated.
Thanks
Peter

RE: ending practice trails early

peter — Fri, 07 Oct 2022 23:58:17 GMT

+x[quote]

[b]Dave - 10/7/2022[/b]
+x[quote]

[b]Dave - 10/7/2022[/b]
+x[quote]

[b]peter - 10/7/2022[/b]
Hi, I have been asked to tweak my script so that the practice trials end if the participant responds to 8 out of the last 10 trials correctly.

This is probably super easy but I cant seem to figure it out.
Any help greatly appreciated.
Thanks
Peter
[/quote]

If you want an answer, you need to provide your script. Nobody can tell you how to tweak it otherwise.
[/quote]

Here's a generic example:

[code]<list practice_acc>
/ items = (0,0,0,0,0,0,0,0,0,0)
</list>

<expressions>
/ ncorr_last_10 = {
    list.practice_acc.item(1) + list.practice_acc.item(2) + list.practice_acc.item(3) + list.practice_acc.item(4) + list.practice_acc.item(5) +
    list.practice_acc.item(6) + list.practice_acc.item(7) + list.practice_acc.item(8) + list.practice_acc.item(9) + list.practice_acc.item(10)
};
</expressions>

<expt>
/ blocks = [1=practiceblock]
</expt>

<block practiceblock>
/ stop = [
    expressions.ncorr_last_10 >= 8;
]
/ trials = [1-100 = practicetrial]
</block>

<trial practicetrial>
/ ontrialend = [
    list.practice_acc.insertitem(trial.practicetrial.correct, 1);
]
/ stimulusframes = [1=practicetext, info]
/ validresponse = ("a", "b")
/ correctresponse = ("a")
</trial>

<text practicetext>
/ items = ("Press 'A' or 'B'
(A = correct; B = wrong)")
/ size = (80%, 20%)
</text>

<text info>
/ items = ("<%expressions.ncorr_last_10%> out of the last 10 trials correct")
/ position = (50%, 10%)
</text>[/code]
[/quote]

That works perfectly, thanks as always for your excellent help!
Much appreciated
Peter

RE: ending practice trails early

Dave — Fri, 07 Oct 2022 14:35:07 GMT

+x[quote]

[b]Dave - 10/7/2022[/b]
+x[quote]

[b]peter - 10/7/2022[/b]
Hi, I have been asked to tweak my script so that the practice trials end if the participant responds to 8 out of the last 10 trials correctly.

This is probably super easy but I cant seem to figure it out.
Any help greatly appreciated.
Thanks
Peter
[/quote]

If you want an answer, you need to provide your script. Nobody can tell you how to tweak it otherwise.
[/quote]

Here's a generic example:

[code]<list practice_acc>
/ items = (0,0,0,0,0,0,0,0,0,0)
</list>

<expressions>
/ ncorr_last_10 = {
    list.practice_acc.item(1) + list.practice_acc.item(2) + list.practice_acc.item(3) + list.practice_acc.item(4) + list.practice_acc.item(5) +
    list.practice_acc.item(6) + list.practice_acc.item(7) + list.practice_acc.item(8) + list.practice_acc.item(9) + list.practice_acc.item(10)
};
</expressions>

<expt>
/ blocks = [1=practiceblock]
</expt>

<block practiceblock>
/ stop = [
    expressions.ncorr_last_10 >= 8;
]
/ trials = [1-100 = practicetrial]
</block>

<trial practicetrial>
/ ontrialend = [
    list.practice_acc.insertitem(trial.practicetrial.correct, 1);
]
/ stimulusframes = [1=practicetext, info]
/ validresponse = ("a", "b")
/ correctresponse = ("a")
</trial>

<text practicetext>
/ items = ("Press 'A' or 'B'
(A = correct; B = wrong)")
/ size = (80%, 20%)
</text>

<text info>
/ items = ("<%expressions.ncorr_last_10%> out of the last 10 trials correct")
/ position = (50%, 10%)
</text>[/code]

RE: ending practice trails early

Dave — Fri, 07 Oct 2022 14:06:11 GMT

+x[quote]

[b]peter - 10/7/2022[/b]
Hi, I have been asked to tweak my script so that the practice trials end if the participant responds to 8 out of the last 10 trials correctly.

This is probably super easy but I cant seem to figure it out.
Any help greatly appreciated.
Thanks
Peter
[/quote]

If you want an answer, you need to provide your script. Nobody can tell you how to tweak it otherwise.