Likert scale background colour

angela279 — Wed, 03 Jun 2026 12:18:18 GMT

Is there any way to change the background colour behind the likert scale to match the default background instead of it staying white? This is important for context for my experiment. I've tried various default settings to no avail. TIA

RE: Likert scale background colour

Dave — Wed, 03 Jun 2026 12:18:18 GMT

+x[quote]

[b]angela279 - 6/3/2026[/b]
Is there any way to change the background colour behind the likert scale to match the default background instead of it staying white? This is important for context for my experiment. I've tried various default settings to no avail. TIA
[/quote]

With the <likert> element? No.

Your best option is to buld a custom likert <trial> using regular <text>, <button>, <shape>, etc. elements.

[code]<defaults>
/ screencolor = aqua
</defaults>

<values>
/ likertValue = null
</values>

<expt myExpt>
/ blocks = [1=myBlock]
</expt>

<block myBlock>
/ trials = [1-5=likertTrial]
</block>

<trial likertTrial>
/ onTrialEnd = [
values.likertValue = substring(trial.likertTrial.responseText, 1, 1);
]

/ stimulusframes = [1=clearscreen, question, line, o1, o2, o3, o4]
/ inputdevice = mouse
/ validresponse = (o1,o2,o3,o4)
</trial>

<button o1>
/ caption = "1"
/ size = (4%, 4%)
/ fontstyle = ("Arial", 3%)
/ position = (20%, 60%)
</button>

<button o2>
/ caption = "2"
/ size = (4%, 4%)
/ fontstyle = ("Arial", 3%)
/ position = (40%, 60%)
</button>

<button o3>
/ caption = "3"
/ size = (4%, 4%)
/ fontstyle = ("Arial", 3%)
/ position = (60%, 60%)
</button>

<button o4>
/ caption = "4"
/ size = (4%, 4%)
/ fontstyle = ("Arial", 3%)
/ position = (80%, 60%)
</button>

<shape line>
/ shape = rectangle
/ size = (60%, 1%)
/ position = (50%, 60%)
</shape>

<text question>
/ items = questionItems
/ select = sequence
/ txbgcolor = transparent
</text>

<item questionItems>
/ 1 = "Q1"
/ 2 = "Q2"
/ 3 = "Q3"
/ 4 = "Q4"
/ 5 = "Q5"
</item>

<data>
/ columns = (date, time, subject, group, session, blocknum, blockcode, trialnum, trialcode, stimulusitem, stimulusnumber, stimulusitem, stimulusnumber,
responseText, correct, latency, values.likertValue)
/ separatefiles = true
</data>
[/code]

Millisecond Forums » Millisecond Forums » Inquisit 6 » Likert scale background colour

Likert scale background colour

RE: Likert scale background colour