RE: Problem with selecting stimulus pairs using counters

Dave — Mon, 04 Mar 2013 03:19:59 GMT

[quote]Does this have to do with the use of counters in my script?[/quote]

Yes.

RE: Problem with selecting stimulus pairs using counters

blop — Sun, 03 Mar 2013 19:30:51 GMT

Thanks, that works a treat!

I don't understand the difference between current(stimcounter) and stimcounter though. I would have thought that unless the text for each word in the pair was somehow matched, different stimuli would have been selected. Also the documentation for creating stimulus pairs uses current to specify selection of the matching stimulus item:

<text firstname>
/ items = ("BILL", "LINDON")
/ select = noreplace
</text>

<text lastname>
/ items = ("CLINTON", "JOHNSON")
/ select = current(firstname)

</text>

However I get the same problem when I use /select=current(target) to select the neutral text i.e. word pairs are no longer consistently matched. Does this have to do with the use of counters in my script?

RE: Problem with selecting stimulus pairs using counters

Dave — Sun, 03 Mar 2013 03:42:18 GMT

Change

<text neutral>
/items = neutral
/select = current(stimcounter)
/vposition = neutralvpos
</text>

<text neutral>
/items = neutral
/select = stimcounter
/vposition = neutralvpos
</text>

Problem with selecting stimulus pairs using counters

blop — Sat, 02 Mar 2013 18:57:00 GMT

Hello,

I'm trying to create a dot probe task in which each stimulus pair is presented once in each of four trial types (based on top-bottom or bottom-top configuration of each word pair, and the location of the probe).

I thought the script was working fine, but have discovered that the stimulus pairs are not always presented in the correct pairs (e.g. 3/16 pairs are not matched in a basic version with only four stimulus pairs).

The script is below:

*******************************************************************
ITEMS
*******************************************************************
<item target>
/1 = "one"
/2 = "two"
/3 = "three"
/4 = "four"
</item>

<item neutral>
/ 1 = "ONE"
/ 2 = "TWO"
/ 3 = "THREE"
/ 4 = "FOUR"
</item>

<item probe>
/1 = "p"
/2 = "q"
</item>

*******************************************************************
TEXT AND COUNTERS
*******************************************************************
<text probe>
/ items = probe
/ select = replace
/ color = white
/ vposition = probevpos
</text>

<text target>
/items = target
/select = stimcounter
/vposition = threatvpos
</text>

<text neutral>
/items = neutral
/select = current(stimcounter)
/vposition = neutralvpos
</text>

<counter stimcounter>
/ items =
(1,1,1,1,
2,2,2,2,
3,3,3,3,
4,4,4,4)
/ select = noreplacenorepeat
</counter>

<counter threatvpos>
/ items =
(47%,53%,47%,53%,
47%,53%,47%,53%,
47%,53%,47%,53%,
47%,53%,47%,53%)
/ select = current(stimcounter)
</counter>

<counter neutralvpos>
/items =
(53%, 47%, 53%, 47%
53%, 47%, 53%, 47%
53%, 47%, 53%, 47%
53%, 47%, 53%, 47%)
/select = current(stimcounter)
</counter>

<counter probevpos>
/items =
(47%, 47%, 53%, 53%,
47%, 47%, 53%, 53%,
47%, 47%, 53%, 53%,
47%, 47%, 53%, 53%)
/select = current(stimcounter)
</counter>

<counter correctresponse>
/ items = (25, 16)
/ select = current(probe)
</counter>
*******************************************************************
OTHER STIMULI AND DEFAULTS
*******************************************************************
<text fixation>
/items = (" + ")
/ fontstyle = ("Times", 24pt)
</text>

<shape erase>
/ color = (150,150,150)
/ size = (100%, 100%)
</shape>

<defaults>
/ txbgcolor = transparent
/ screencolor = (150,150,150)
/ txcolor = white
/ fontstyle = ("Arial Rounded MT", 14pt)
</defaults>
*******************************************************************
TRIALS AND BLOCKS
*******************************************************************
<trial maintrial>
/stimulustimes = [0 = fixation; 500 = erase, target, neutral; 1000 = erase, probe]
/inputdevice = keyboard
/validresponse = ("p","q")
/iscorrectresponse = [trial.maintrial.response==counter.correctresponse.selectedvalue]
/responsetime = 1000
/timeout = 2500
</trial>
<block main>
/trials = [1-16 = maintrial]
</block>

Many thanks!

Millisecond Forums » Millisecond Forums » Inquisit 3 » Problem with selecting stimulus pairs using counters

RE: Problem with selecting stimulus pairs using counters

RE: Problem with selecting stimulus pairs using counters

RE: Problem with selecting stimulus pairs using counters

Problem with selecting stimulus pairs using counters