Millisecond Forums

A <values> entry is what you may know as a global variable in other programming languages. It does not update itself automatically. Thus

<values>
/ reactiontime1 = if (trial.trial1.response == 57 && block.block1.latency >= 3000) (block.block1.latency - 3000)  else -8
</values>

will be evaluated *exactly once* as soon as you run the script. At this point the result of that evaluation can only ever be -8. The if-condition will never evaluate to true.

If you want something akin to user defined functions that's evaluated automatically, you'll want to use <expressions>.

> Also, it seems like ever since I started trying these values, the data report of other variables has been affected. It seems it will
> only record a trial.trial1.response as 57 if I hit spacebar before the correct stimulus appears. If I wait to react to the stimulus, it
> outputs the response as 0

Whatever you do with that <values> element, it should not and -- according to my tests -- does not affect those things. The way you've set up the <trial>, it will allow for a response at any time during the video -- be it before or after 3 seconds have elapsed. It will only record a 0 as a response if no valid response has been submitted prior to the trial timing out after 6 seconds. To illustrate this, find attached a data file generated by your script. The response is 57 and its latency is 4594 ms, i.e. well after 3 seconds.

If you are experiencing something else on your system, please first ensure that your Inquisit installation is up to date. If -- after an eventual update -- the issue persists, please provide a data file illustrating it.

> There is no possible way to get Inquisit 4 to record two or more valid responses in one trial, right?

There is a way. It requires the use of /isvalidresponse logic.


<values>
/ rt_premature = ""
</values>

<data>
/ columns = [date time subject blocknum blockcode trialnum trialcode stimulusitem response latency values.rt_premature]
/ separatefiles = true
</data>
 
<video Video1>
/ items = ("Video1.wmv")
</video>

<trial Trial1>
/ ontrialbegin = [values.rt_premature=""; ]
/ beginresponsetime = 0
/ inputdevice = keyboard
/ validresponse = (57)
/ isvalidresponse = [if(trial.trial1.elapsedtime<3000 && trial.trial1.response == 57) {values.rt_premature=trial.trial1.latency; false;} else if
    (trial.trial1.elapsedtime>=3000 && trial.trial1.response == 57) {true}]
/ responseinterrupt = trial
/ timeout = 6000
/ stimulusframes = [1=Video1]
</trial>

<block Block1>
/ trials = [1=Trial1]
</block>

<expt Expt1>
/ blocks = [1=Block1]
</expt>

Via the /isvalidresponse attribute above, a premature response (prior to 3000ms) will be evaluated as invalid (false), so the trial will continue accepting responses. However, the latency of that 1st, premature response is stored in a variable (<values> entry) and written to the data file.

Dave,

Thanks for the advice! It works great except for one very odd problem. If I repeatedly mash the spacebar during the whole trial, I can still get latency values before the appearance of the stimulus. For instance, it would accept a latency value of 11102 even if the logic refused any values lower than 12220. I believe I was able to solve the issue, and I think it has something to do with why my data output was also acting wonky.

Trying out the experiment on my old home laptop, the length of the videos is almost doubled from lag. It should have occurred to me that Inquisit was tsill running a consistent timer despite my computer's slow video. Thus, whenever I hit spacebar in reaction to the stimulus, it was long past the timeout period, resulting in a response of "0." That may have been the case yesterday as well, but that was on a fairly good lab computer. I will have to test that one.Additionally, the computer's slowness probably affected the "trial.trial1.elapsedtime" and made it out of sync with the latency. When I changed the isvalidreponse logic to be dependent on latency, I didn't get valid responses from before the stimulus appearance time.

Thanks for your help!

I can confirm that video performance will depend a lot on system characteristics (processor speed, RAM, codec performance, driver performance, video resolution) and performance can vary substantially from system to system depending on the various moving parts involved. It very much sounds like performance bottlenecks were the most significant issue here.

One thing that I am curious about, though it is not too relevant to the current experiment, is how one would set up Inquisit to record all responses given by the participant, until they responded post-correct stimulus. It seems that the script that you provided overwrites the latency each time the participant responds until the appearance of the correct stimulus. I think I can imagine how one could set up the possibility for a set number of possible premature responses being recorded with rt_premtaure1, rt_premature2, etc. and using conditional statements that test if the previous rt_premature != -8. Is there a shortcut for that or way to make the possible premature responses nearly unlimited.

As I said, this experiment is mainly interested in if they respond early at all, but recording the variables as described above may be interesting.

As you suggested, you either need to set up N variables (as many as reasonably needed; values.rt_premature1, values.rt_premature2, etc.) and populate them in order. Alternatively, you could concatenate the various premature rts and store the resulting string of rts in a single variable.

/ isvalidresponse = [if(trial.trial1.elapsedtime<3000 && trial.trial1.response == 57) {values.rt_premature=concat(concat(values.rt_premature, ","), trial.trial1.latency); false;} else if
    (trial.trial1.elapsedtime>=3000 && trial.trial1.response == 57) {true}]