+xHi!
I am trying to achieve the following (and did not manage to find a solution yet...):
1) Participants have to list up to 6 'things' (bullet points) that they have to still accomplish this week.
2) Later in the experiment, I want to get back to this list and present each of those 'things' and ask a 'yes' 'no' question alongside it ("Do you think you will accomplish this this week").
Problem 1: how can I present all 'things' they listed in the beginning in a radiobutton format later on? If the radiobutton format is not appropriate, which format would work better?
Problem 2: how can I make sure that if one participant only listed 4 'things', that they only get to see those 4 'things' later on and no blanks, or some 'things' twice (I am asking because I tried making an itemlist out of the 'things' and then present them in a likert questionnaire format, but in case I only listed 4 'things', the list kept repeating with the first thing, until 6 questions in total were asked).
Many thanks in advance for your help!!
Best wishes
Daniela
Re. #1: Set up a <surveypage> with six <textbox> elements. Make responses to those <textbox>es optional (/required=false). If the response is non-empty, store it in an <item> element.
Re. #2: Display the <item>s collected in step 1 in a <text> element via a <likert> or the like. You can stop after X trials based on the <item> element's itemcount property, i.e. if there were only 4 things listed, stop after 4 trials.
<block a>
/ trials = [1=mypage]
</block>
<surveypage mypage>
/ questions = [1=q1; 2=q2; 3=q3; 4=q4; 5=q5; 6=q6]
/ ontrialend = [if(textbox.q1.response != "") item.responses.appenditem(textbox.q1.response)]
/ ontrialend = [if(textbox.q2.response != "") item.responses.appenditem(textbox.q2.response)]
/ ontrialend = [if(textbox.q3.response != "") item.responses.appenditem(textbox.q3.response)]
/ ontrialend = [if(textbox.q4.response != "") item.responses.appenditem(textbox.q4.response)]
/ ontrialend = [if(textbox.q5.response != "") item.responses.appenditem(textbox.q5.response)]
/ ontrialend = [if(textbox.q6.response != "") item.responses.appenditem(textbox.q6.response)]
</surveypage>
<textbox q1>
/ required = false
</textbox>
<textbox q2>
/ required = false
</textbox>
<textbox q3>
/ required = false
</textbox>
<textbox q4>
/ required = false
</textbox>
<textbox q5>
/ required = false
</textbox>
<textbox q6>
/ required = false
</textbox>
<item responses>
</item>
<text mytext>
/ items = responses
/ position = (50%, 40%)
</text>
<block b>
/ trials = [1=mylikert]
</block>
<likert mylikert>
/ stimulusframes = [1=mytext]
/ numpoints = 2
/ branch = [if (likert.mylikert.trialcount < item.responses.itemcount) likert.mylikert]
</likert>