Millisecond Forums

Hi,

So in myblock2 I have used ‘postive2/negative2’ where I have reversed the positions of these elements (within subjects). So, each subjects is being shown positive items on (30%, 80%) and (70%,80%) in half of the trials.

But I am not able to get the data element properly. With this ‘data’ command, data is being recorded for all columns, even if it is not there (for e.g., for first/second trials, the columns of third/fourth trials should be blank but it is not blank. Similarly, when ‘positive/negative’ items are shown, the columns of ‘positive2/negative2’ should be blank, but they are not blank. Is this data command wrong?
Thanks

No, it's not wrong, that's the expected behavior. You're logging properties. Suppose the experiment starts with one instance of trial.first/trial.second. Then there'll be a row in the data file, that reflects the response properties of trial.first and trial.second, but the column for trial.third.response and trial.fourth.response will be blank since *no instances of trial.third and trial.fourth* have been run at this point, and there is nothing those properties could reflect.

Now suppose, there's an instance of trial.third/trial.fourth next. Then you'll have values for the trial.third.response and trial.fourth.response properties in that row, reflecting the responses given. BUT, of course, there'll also be values in the trial.first.response and trial.second.response columns -- an instance of trial.first and trial.second ran before that so those properties have values as they should. Those columns should in fact NOT be blank, they do and should reflect the value they *currently* have until that value changes.

Hi Dave,

Thanks.

Is there an easy way to sort out the rows to identify first/third trials? Something  like, ‘1 for text entry’ and ‘0 for no entry /repeat’; Something which can be easily filtered out later to identify first/third trials.

Thanks

You have that information already in the blockcode column. Whenever the blockcode indicates "myblock", you know that only first/second trials were run in that block, anything logged in the third/fourth trial columns is irrelevant for that block. Conversely, whenever the blockcode is "myblock2", you know that only third/fourth trials were administered during that block, and anything logged in th first/second trial columns is irrelevant for that block.

If you want to clean up your data further, you can use <values>. If, ultimately, you want to run some kind of mixed blocks, and can't use the blockcode column to identify trial type, do something like this:

<item negative>
/1 = "lung cancer"
/2 = "addiction"
/3 = "heart disease"
/4 = "clogged arteries"
/5 = "blindness"
/6 = "amputation"
/7 = "death"
/8 = "tongue cancer"
/9 = "throat cancer"
/10 = "gangrene"
</item>

<item positive>
/1 = "healthy"
/2 = "vibrant"
/3 = "free"
/4 = "happy"
/5 = "in control"
/6 = "long life"
/7 = "energetic"
/8 = "refreshed"
/9 = "good"
/10 = "rewarding"
</item>

<item smoking>
/1 = "smoking"
</item>

<item me>
/1 = "me"
</item>

<text positive>
/ items = positive
/ position = (30%, 80%)
/ txcolor = green
/ fontstyle = ("Arial", 5%)
/ dropsource = true
/ select = values.positem
</text>


<text negative>
/ items = negative
/ position = (70%, 80%)
/ txcolor = green
/ fontstyle = ("Arial", 5%)
/ dropsource = true
/ select = values.negitem
</text>

<list negitemnumbers>
/ poolsize = 10
</list>

<list positemnumbers>
/ poolsize = 10
</list>

<values>
/ trialtype = ""
/ negitem = 1
/ positem = 1
/ reset = false
</values>


<text me>
/ items = me
/ position = (30%, 30%)
/ txcolor = black
/ fontstyle = ("Arial", 5%)
/ erase = false
/ droptarget = true
/ dropposition = (30%, 30%)
</text>

<text smoking>
/ items = smoking
/ position = (70%, 30%)
/ txcolor = black
/ fontstyle = ("Arial", 5%)
/ erase = false
/ droptarget = true
/ dropposition = (70%, 30%)
</text>

<text reset>
/ items = ("RESET")
/ size = (5%, 3%)
/ vjustify = center
/ txbgcolor = grey
/ position = (50%, 90%)
</text>


<trial first>
/ ontrialbegin = [
if (!values.reset) {
values.positem = list.positemnumbers.nextindex;
values.negitem = list.negitemnumbers.nextindex;
};
]
/ ontrialbegin = [
text.positive.hposition = 30%;
text.positive.vposition = 80%;
text.negative.hposition = 70%;
text.negative.vposition = 80%;
text.positive.dropsource = true;
text.negative.dropsource = true;
text.me.droptarget = true;
text.smoking.droptarget = true;
values.trialtype = "first/second";
]
/ ontrialend = [
if (trial.first.response == "me")
text.me.droptarget = false;
]
/ ontrialend = [
if (trial.first.response == "smoking")
text.smoking.droptarget = false;
]
/ stimulusframes = [1 = positive, negative, me, smoking]
/ inputdevice = dragdrop
/ showmousecursor = true
/ validresponse = (me, smoking)
/ branch = [
trial.second
]
/ recorddata = false
</trial>

<trial second>
/ ontrialbegin = [
values.reset = false;
]
/ ontrialbegin = [
if (text.positive.vposition != 80%)
text.positive.dropsource = false;
]
/ ontrialbegin = [
if (text.negative.vposition != 80%)
text.negative.dropsource = false;
]
/ stimulusframes = [1 = positive, negative, me, smoking, reset]
/ inputdevice = dragdrop
/ showmousecursor = true
/ validresponse = (me, smoking, reset)
/ branch = [
if (trial.second.response == "reset"){
values.reset = true;
trial.first;
};
]
/ branch = [
if (trial.second.response != "reset"){
trial.record_round;
}
]
/ recorddata = false
</trial>

<trial record_round>
/ trialduration = 0
/ validresponse = (0)
/ recorddata = true
</trial>

<block myblock>
/trials = [1-10 = noreplace(first, third)]
</block>

<trial third>
/ ontrialbegin = [
if (!values.reset) {
values.positem = list.positemnumbers.nextindex;
values.negitem = list.negitemnumbers.nextindex;
};
]
/ ontrialbegin = [
text.positive2.hposition = 30%;
text.positive2.vposition = 80%;
text.negative2.hposition = 70%;
text.negative2.vposition = 80%;
text.positive2.dropsource = true;
text.negative2.dropsource = true;
text.me.droptarget = true;
text.smoking.droptarget = true;
values.trialtype = "third/fourth";
]
/ ontrialend = [
if (trial.third.response == "me")
text.me.droptarget = false;
]
/ ontrialend = [
if (trial.third.response == "smoking")
text.smoking.droptarget = false;
]
/ stimulusframes = [1 = positive2, negative2, me, smoking]
/ inputdevice = dragdrop
/ showmousecursor = true
/ validresponse = (me, smoking)
/ branch = [
trial.fourth
]
/ recorddata = false
</trial>

<trial fourth>
/ ontrialbegin = [
values.reset = false;
]
/ ontrialbegin = [
if (text.positive2.vposition != 80%)
text.positive2.dropsource = false;
]
/ ontrialbegin = [
if (text.negative2.vposition != 80%)
text.negative2.dropsource = false;
]
/ stimulusframes = [1 = positive2, negative2, me, smoking, reset]
/ inputdevice = dragdrop
/ showmousecursor = true
/ validresponse = (me, smoking, reset)
/ branch = [
if (trial.fourth.response == "reset"){
values.reset = true;
trial.third;
};
]
/ branch = [
if (trial.fourth.response != "reset"){
trial.record_round;
}
]
/ recorddata = false
</trial>

<item negative2>
/1 = "lung cancer"
/2 = "addiction"
/3 = "heart disease"
/4 = "clogged arteries"
/5 = "blindness"
/6 = "amputation"
/7 = "death"
/8 = "tongue cancer"
/9 = "throat cancer"
/10 = "gangrene"
</item>

<item positive2>
/1 = "healthy"
/2 = "vibrant"
/3 = "free"
/4 = "happy"
/5 = "in control"
/6 = "long life"
/7 = "energetic"
/8 = "refreshed"
/9 = "good"
/10 = "rewarding"
</item>

<text positive2>
/ items = positive2
/ position = (70%, 80%)
/ txcolor = green
/ fontstyle = ("Arial", 5%)
/ dropsource = true
/ select = values.positem
</text>


<text negative2>
/ items = negative2
/ position = (30%, 80%)
/ txcolor = green
/ fontstyle = ("Arial", 5%)
/ dropsource = true
/ select = values.negitem
</text>

<data>
/ columns = (date time subject group blocknum blockcode trialnum trialcode
values.trialtype
trial.first.response trial.first.latency
trial.second.response trial.second.latency
trial.third.response trial.third.latency
trial.fourth.response trial.fourth.latency
text.negative.currentitem text.negative.hposition text.negative.vposition
text.positive.currentitem text.positive.hposition text.positive.vposition
text.negative2.currentitem text.negative2.hposition text.negative2.vposition
text.positive2.currentitem text.positive2.hposition text.positive2.vposition )
/ separatefiles = true
</data>

Thanks for this Dave. Working superb.

I noticed that at the time of launch there is an option to show participants a random confirmation code by millisecond. How to capture that code in the data element. Is there a documentation about confirmation code in the Help section.

Thanks

The confirmation code is just the subject ID, it's logged in the data file already in the subject column.

Hi, Just noticed that even if someone aborts the expt, still he/she gets the confirmation code. Anyway to stop that.
Thanks.