+xHello,
I’ve encountered two issues with the task I am programming. In this task, I want to first randomly assign the participant to one of two audio conditions before they complete a second part of the task that's the same for both conditions (A Flanker task).
I’ve modified the Flanker task to meet my desired specifications, though I’m having difficulty integrating the audio files into the script. I’ve also struggled to figure out how to randomize the participant to listen to one of the two audio files. Do you have any tips on how to integrate the audio files and randomize participants?
Thanks in advance for any help you give!
Generally, to (randomly) assign participants to different conditions, you want to make use of several <expt> elements in your script, one per condition. If you run separate scripts, you do the same using several <batch> elements, as in
// stuff to do and run for condition #1
<expt>
/ subjects = (1 of 2)
/ groupassignment = groupnumber
....
</expt>
// stuff to do and run for condition #2
<expt>
/ subjects = (2 of 2)
/ groupassignment = groupnumber
....
</expt>
or
// scripts to run for condition #1
<batch>
/ subjects = (1 of 2)
/ groupassignment = groupnumber
/ file = "condition1.iqx"
/ file = "flanker.iqx"
</batch>
// scripts to run for condition #2
<batch>
/ subjects = (2 of 2)
/ groupassignment = groupnumber
/ file = "condition2.iqx"
/ file = "flanker.iqx"
</batch>
respectively.
Now, for the audio part, you could simply do something like this
// scripts to run for condition #1
<values>
/ audioitem = 1
</values>
// uses the 1st audio item
<expt>
/ onexptbegin = [values.audioitem = 1]
/ subjects = (1 of 2)
/ groupassignment = groupnumber
/ blocks = [1=myblock]
</expt>
// uses the 2nd audio item
<expt>
/ onexptbegin = [values.audioitem = 2]
/ subjects = (2 of 2)
/ groupassignment = groupnumber
/ blocks = [1=myblock]
</expt>
<block myblock>
/ trials = [1=audiotrial]
</block>
<trial audiotrial>
/ stimulusframes = [1=myaudio]
/ validresponse = (57)
</trial>
<video myaudio>
/ items = audioitems
/ select = values.audioitem
</video>
<item audioitems>
/ 1 = "a.mp3"
/ 2 = "b.mp3"
</item>