Millisecond Forums

You should not set up separate <video> elements for each gif in the respective manipulation condition. Instead, set up a two <video> elements -- on per manipulation conditon, 1 and 2 -- and the six gifs ought to the the respective <video> element's /items. Then pair your stimulus elements as needed: https://www.millisecond.com/support/docs/v5/html/howto/howtopairs.htm

Thank you so much for your help. If works out fine now.  I am still wondering though how to program that for the 6 stimuli (products) 3 will be randomly displayed with a high nutritional label and 3 with a low nutritional label. Thanks so much for your help again!



<instruct>
/ txcolor = (0, 0, 0)
/ screencolor = (255, 255, 255)
/ nextkey = (" ")
/ prevkey = ("p")
/ nextlabel = "(Leertaste) Nächste Seite…"
/ prevlabel = "(p) Previous page…"
</instruct>

<page welcome>

Liebe Teilnehmerin, lieber Teilnehmer,^^^
herzlichen Dank für Ihre Bereitschaft, an unserer Studie teilzunehmen.^
^Die Studie wird vom Arbeitsbereich Angewandte Sozialpsychologie und Konsumentenverhaltensforschung der Universität Wien durchgeführt. und dient ausschließlich wissenschaftlichen Zwecken. Ihre Angaben werden vertraulich behandelt und anonymisiert ausgewertet, so dass keine Rückschlüsse auf Ihre Person möglich sind. Falls nach der Beendigung der Studie noch Fragen aufkommen, können Sie sich jederzeit unter a1204970@univie.ac.at melden.
^In der folgenden Studie werden wir Ihnen einige Produkte zeigen und möchten Sie bitten, diese zu betrachten und zu beurteien.
^Bei Fragen können Sie sich gerne an den Versuchsleiter wenden.
^^Wenn Sie damit einverstanden sind, klicken Sie auf "Weiter".
</page>

<page vorgehensweise>

Im Folgenden werden Ihnen verschiedene Produkte vorgestellt. Vor jedem Produkt wird ein kurzes circa 40 sekündiges Video gezeigt. Bitte fixieren sie vor und nach dem Video jeweils das angezeigte Fixationskreuz in der Mitte der Bildschirms.
^Bei Fragen melden Sie sich bitte jetzt beim Versuchsleiter
^^Wenn Sie bereit sind, dann klicken Sie auf "Weiter" und beginnen Sie mit der Studie.
</page>

<page end>

Vielen Dank für ihre Hilfe, bitte wenden Sie sich an den Versuchsleiter!
</page>

------ Stimuli------------


<item Productwithoutlabel>
/1 = "Bar ohne label.jpg"
/2 = "Marmelade ohne label.jpg"
/3 = "Müsli ohne label.jpg"
/4 = "Smoothie ohne label.jpg"
/5 = "Yoghurt ohne label.jpg"
/6 = "Dressing ohne label.jpg"
</item>

<item labelhigh>
/1 = "Bar high label transparent.png"
/2 = "Marmelade high label transparent.png"
/3 = "Müsli high label transparent.png"
/4 = "Smoothie high label transparent.png"
/5 = "Yoghurt high label transparent.png"
/6 = "Dressing high label transparent.png"
</item>

<item labellow>
/7 = "Bar low label transparent.png"
/8 = "Marmelade low label transparent.png"
/9 = "Müsli low label transparent.png"
/10 = "Smoothie low label transparent.png"
/11 = "Yoghurt low label transparent.png"
/12 = "Dressing low label transparent.png"
</item>

---------Manipulationen
<item manip1>
/1 = "Cereal Bar.gif"
/2 = "Marmelade.gif"
/3 = "Müsli.gif"
/4 = "Smoothie.gif"
/5 = "Yoghurt.gif"
/6 = "Dressing.gif"
</item>


<item manip2>
/1 = "Cereal Bar Kontrollgruppe.gif"
/2 = "Marmelade Kontrollgruppe.gif"
/3 = "Müsli Kontrollgruppe.gif"
/4 = "Smoothie Kontrollgruppe.gif"
/5 = "Yoghurt Kontrollgruppe.gif"
/6 = "Dressing Kontrollgruppe.gif"
</item>

---------------Produkte ohne label--------------------
<picture Productwithoutlabel1>
/ items = ("Bar ohne label.jpg","Marmelade ohne label.jpg","Müsli ohne label.jpg","Smoothie ohne label.jpg","Yoghurt ohne label.jpg","Dressing ohne label.jpg")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture Productwithoutlabel2>
/ items = ("Bar ohne label.jpg","Marmelade ohne label.jpg","Müsli ohne label.jpg","Smoothie ohne label.jpg","Yoghurt ohne label.jpg","Dressing ohne label.jpg")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>

--------------------------Labels high calorie---------------------------------
<picture highlabel1>
/ items = ("Bar high label transparent.png","Marmelade high label transparent.png","Müsli high label transparent.png","Smoothie high label transparent.png","Yoghurt high label transparent.png","Dressing high label transparent.png")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture highlabel2>
/ items = ("Bar high label transparent.png","Marmelade high label transparent.png","Müsli high label transparent.png","Smoothie high label transparent.png","Yoghurt high label transparent.png","Dressing high label transparent.png")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>

--------------------------labels low calorie-------------------------
<picture lowlabel1>
/ items = ("Bar low label transparent.png","Marmelade low label transparent.png","Müsli low label transparent.png","Smoothie low label transparent.png","Yoghurt low label transparent.png","Dressing low label transparent.png")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture lowlabel2>
/ items = ("Bar low label transparent.png","Marmelade low label transparent.png","Müsli low label transparent.png","Smoothie low label transparent.png","Yoghurt low label transparent.png","Dressing low label transparent.png")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>



--------- Manipulation---
<video manip1>
/ items = ("Cereal Bar.gif","Marmelade.gif","Müsli.gif","Smoothie.gif","Yoghurt.gif","Dressing.gif")
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
/ select = noreplace
</video>

<video manip2>
/ items = ("Cereal Bar Kontrollgruppe.gif","Marmelade Kontrollgruppe.gif","Müsli Kontrollgruppe.gif","Smoothie Kontrollgruppe.gif","Yoghurt Kontrollgruppe.gif","Dressing Kontrollgruppe.gif" )
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
</video>




-----Fixation Cross--------
<item fixation>
/1 = "Fixaton Cross.jpg"
</item>

<picture fixation>
/ items = ("Fixation Cross.jpg")
/ size = (100%, 100%)
</picture>

----Question open end-----
<text Manipulationcheck>
/ items = ("Bitte beschreiben Sie, was Sie innerhalb des zuvor gezeigten Videos gesehen haben.")
/ position = (50%, 30%)
</text>

<openended Manipulationcheck>
/ stimulusframes=[1=Manipulationcheck]
/ position = (50, 80)
/ linelength = 90
/ numlines = 15
/required = true
</openended>

-------------------Question Kaufintention---------------------------------

<radiobuttons Kaufintention>
/caption = "Wie wahrscheinlich wäre es, dass Sie das Produkt kaufen würden?"
/ options = (" 1 ~nsehr unwahrscheinlich", " 2 ", " 3 ", " 4 ", " 5 ", " 6 ", " 7 ~nsehr wahrscheinlich")
/ optionvalues = ("1", "2", "3", "4", "5", "6", "7")
/required = true
/orientation = horizontalequal
</radiobuttons>

<surveypage Kaufintention>
/ questions = [1 = Kaufintention]
</surveypage>

-----trial Exp------------------

<trial manip1>
/stimulustimes = [1=fixation;2000=manip1;55000=fixation;60000=Productwithoutlabel1,picture.highlabel1]
/trialduration = 85000
/pretrialpause = 500
</trial>


<trial manip2>
/stimulustimes = [1=fixation;2000=manip2;55000=fixation;60000=Productwithoutlabel2,picture.lowlabel2]
/trialduration = 85000
/pretrialpause = 500
</trial>

------------

<block exp>
/trials = [1-6=manip1,Kaufintention,Manipulationcheck]
/preinstructions = (vorgehensweise)
</block>

<block con>
/trials = [1-6=manip2,Kaufintention,Manipulationcheck]
/preinstructions = (vorgehensweise)
</block>

Set up two <trial> elements -- one with high label, one with low label -- sample 6 times from those in equal proportions. In a nutshell:

<surveypage Kaufintention>
/ questions = [1 = Kaufintention]
/ branch = [
openended.Manipulationcheck;
]
</surveypage>

-----trial Exp------------------

<trial manip1_hi>
/stimulustimes = [1=fixation;2000=manip1;55000=fixation;60000=Productwithoutlabel1,highlabel1]
/trialduration = 85000
/pretrialpause = 500
/ branch = [
surveypage.Kaufintention;
]
</trial>

<trial manip1_lo>
/stimulustimes = [1=fixation;2000=manip1;55000=fixation;60000=Productwithoutlabel1,lowlabel1]
/trialduration = 85000
/pretrialpause = 500
/ branch = [
surveypage.Kaufintention;
]
</trial>


<trial manip2_hi>
/stimulustimes = [1=fixation;2000=manip2;55000=fixation;60000=Productwithoutlabel2,highlabel2]
/trialduration = 85000
/pretrialpause = 500
/ branch = [
surveypage.Kaufintention;
]
</trial>

<trial manip2_lo>
/stimulustimes = [1=fixation;2000=manip2;55000=fixation;60000=Productwithoutlabel2,lowlabel2]
/trialduration = 85000
/pretrialpause = 500
/ branch = [
surveypage.Kaufintention;
]
</trial>

------------

<block exp>
/trials = [1-6=noreplace(manip1_hi,manip1_lo)]
/preinstructions = (vorgehensweise)
</block>

<block con>
/trials = [1-6=noreplace(manip2_hi,manip2_lo)]
/preinstructions = (vorgehensweise)
</block>

Thanks Dave, it finally works!

Hi again,
i have another qestion concearning the connection between  my experiment and the Data viewer for Eye Tracking experiments.
Because i am using the following trials to display my stimuli:

<trial bild1_hi>
/stimulustimes = [1=Productwithoutlabel1,highlabel1]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [surveypage.Kaufintention]
</trial>

<trial fixation1low>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.manip1_lo]
</trial>

<trial bild2_hi>
/stimulustimes = [1=Productwithoutlabel2,highlabel2]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>


<trial bild2_lo>
/stimulustimes = [1=Productwithoutlabel2,lowlabel2]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>


I am not able to see the exact product that was displayed during the experiment in the Data Viewer, but a black screen that displays the trial(but not the picture i used as a stimuli in that trial) with the gaze data(gaze data is visible). I would like to see the picture of the product with the gaze data in the data viewer so that i don't have to search for the right stimuli all the time (as the order of the stimuli/products is randomized)
I tried to use a trial for every product+ high label(6 trials for 6 products)  and everyproduct+low label(6trials for 6 products), but it is not evenly distributed if i try it like this. As 3 products with high labels and 3 products with low labels should be displayed, still all 6 products need to be displayed.
My attempt looked like this:
<block exp>
/trials = [1-6=noreplace(fixation1high,fixation1low),(fixation2high,fixation2low),(fixation3high,fixation3low),(fixation4high,fixation4low),(fixation5high,fixation5low),(fixation6high,fixation6low)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>

Thanks for you help again!




<eyetracker>
/ plugin = "srresearch"
/ calibrationmode = "HV13"
/ aoidurationthreshold = 2000
</eyetracker>

<instruct>
/ txcolor = (0, 0, 0)
/ screencolor = (255, 255, 255)
/ nextkey = (" ")
/ prevkey = ("p")
/ nextlabel = "Weiter(Leertaste)"
/ prevlabel = "Vorherige Seite(p)"
/lastlabel = "Weiter(Leertaste)"
</instruct>

<page welcome>
.....
</page>

<page vorgehensweise>
....
</page>

<page Zwischentext>
....
</page>


<page end>
.....
</page>

------ Stimuli------------
<item tesprodukt>
/1 = "testbild.jpg"
</item>

<item testvid1>
/1 = "TestVideoExp.gif"
</item>



<item Productwithoutlabel>
/1 = "Bar ohne label.jpg"
/2 = "Marmelade ohne label.jpg"
/3 = "Müsli ohne label.jpg"
/4 = "Smoothie ohne label.jpg"
/5 = "Yoghurt ohne label.jpg"
/6 = "Dressing ohne label.jpg"
</item>

<item labelhigh>
/1 = "Bar high label transparent.png"
/2 = "Marmelade high label transparent.png"
/3 = "Müsli high label transparent.png"
/4 = "Smoothie high label transparent.png"
/5 = "Yoghurt high label transparent.png"
/6 = "Dressing high label transparent.png"
</item>


<item labellow>
/7 = "Bar low label transparent.png"
/8 = "Marmelade low label transparent.png"
/9 = "Müsli low label transparent.png"
/10 = "Smoothie low label transparent.png"
/11 = "Yoghurt low label transparent.png"
/12 = "Dressing low label transparent.png"
</item>

---------Manipulationen
<item manip1>
/1 = "Cereal Bar.gif"
/2 = "Marmelade.gif"
/3 = "Müsli.gif"
/4 = "Smoothie.gif"
/5 = "Yoghurt.gif"
/6 = "Dressing.gif"
</item>


<item manip2>
/1 = "Cereal Bar Kontrollgruppe.gif"
/2 = "Marmelade Kontrollgruppe.gif"
/3 = "Müsli Kontrollgruppe.gif"
/4 = "Smoothie Kontrollgruppe.gif"
/5 = "Yoghurt Kontrollgruppe.gif"
/6 = "Dressing Kontrollgruppe.gif"
</item>

---------------Produkte ohne label--------------------
<picture Productwithoutlabel1>
/ items = ("Bar ohne label.jpg","Marmelade ohne label.jpg","Müsli ohne label.jpg","Smoothie ohne label.jpg","Yoghurt ohne label.jpg","Dressing ohne label.jpg")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture Productwithoutlabel2>
/ items = ("Bar ohne label.jpg","Marmelade ohne label.jpg","Müsli ohne label.jpg","Smoothie ohne label.jpg","Yoghurt ohne label.jpg","Dressing ohne label.jpg")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>

--------------------------Labels high calorie---------------------------------
<picture highlabel1>
/ items = ("Bar high label transparent.png","Marmelade high label transparent.png","Müsli high label transparent.png","Smoothie high label transparent.png","Yoghurt high label transparent.png","Dressing high label transparent.png")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture highlabel2>
/ items = ("Bar high label transparent.png","Marmelade high label transparent.png","Müsli high label transparent.png","Smoothie high label transparent.png","Yoghurt high label transparent.png","Dressing high label transparent.png")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>



--------------------------labels low calorie-------------------------
<picture lowlabel1>
/ items = ("Bar low label transparent.png","Marmelade low label transparent.png","Müsli low label transparent.png","Smoothie low label transparent.png","Yoghurt low label transparent.png","Dressing low label transparent.png")
/ size = (100%, 100%)
/ select = video.manip1.currentindex
</picture>

<picture lowlabel2>
/ items = ("Bar low label transparent.png","Marmelade low label transparent.png","Müsli low label transparent.png","Smoothie low label transparent.png","Yoghurt low label transparent.png","Dressing low label transparent.png")
/ size = (100%, 100%)
/ select = video.manip2.currentindex
</picture>



--------- Manipulation---
<picture testbild1>
/ items = ("testbild.jpg")
/ size = (100%, 100%)
/ select = video.testvid1.currentindex
</picture>

<picture testbild2>
/ items = ("testbild.jpg")
/ size = (100%, 100%)
/ select = video.testvid1.currentindex
</picture>


<video testvid1>
/ items = ("TestVideoExp.gif")
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
</video>

<video testvid2>
/ items = ("TestVideoKontroll.gif")
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
</video>

<video manip1>
/ items = ("Cereal Bar.gif","Marmelade.gif","Müsli.gif","Smoothie.gif","Yoghurt.gif","Dressing.gif")
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
/ select = noreplace
</video>

<video manip2>
/ items = ("Cereal Bar Kontrollgruppe.gif","Marmelade Kontrollgruppe.gif","Müsli Kontrollgruppe.gif","Smoothie Kontrollgruppe.gif","Yoghurt Kontrollgruppe.gif","Dressing Kontrollgruppe.gif" )
/ playthrough = true
/ position = (50, 50)
/ size = (100%, 100%)
</video>




-----Fixation Cross--------
<item fixation>
/1 = "+"
</item>

<text fixation>
/ items = ("+")
/ fontstyle = ("Arial", 15%)
/ txcolor = black
/ size = (12%, 40%)
/ txbgcolor = white
</text>


----Question open end-----
<text Manipulationcheck>
/ items = ("Bitte beschreiben Sie, was Sie innerhalb des zuvor gezeigten Videos gesehen haben.")
/ position = (50%, 30%)
</text>

<openended Manipulationcheck>
/ stimulusframes=[1=Manipulationcheck]
/ position = (50, 80)
/ linelength = 90
/ numlines = 15
/required = true
</openended>

-------------------Question Kaufintention---------------------------------

<radiobuttons Kaufintention>
/caption = "Wie wahrscheinlich wäre es, dass Sie das Produkt kaufen würden?"
/ options = (" 1 ~nsehr unwahrscheinlich", " 2 ", " 3 ", " 4 ", " 5 ", " 6 ", " 7 ~nsehr wahrscheinlich")
/ optionvalues = ("1", "2", "3", "4", "5", "6", "7")
/required = true
/orientation = horizontalequal
</radiobuttons>

<surveypage Kaufintention>
/ questions = [1 = Kaufintention]
/ showpagenumbers = false
/ branch = [
openended.Manipulationcheck;]
</surveypage>

-----trial Exp------------------
<trial fixation1>
/stimulustimes = [1= text.fixation]

/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.bild1_hi]
</trial>

<trial fixation2>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.bild1_lo]
</trial>

<trial fixation3>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.bild2_hi]
</trial>

<trial fixation4>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.bild2_lo]
</trial>


<trial fixation1high>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.manip1_hi]
</trial>

<trial fixation1low>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.manip1_lo]
</trial>

<trial fixation2high>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.manip2_hi]
</trial>

<trial fixation2low>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.manip2_lo]
</trial>



-----trial Exp------------------
<trial manip1_hi>
/stimulustimes = [1=manip1]
/ timeout = manip1
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [trial.fixation1 ]
</trial>

<trial manip1_lo>
/stimulustimes = [1=manip1]
/ timeout = manip1
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [trial.fixation2]
</trial>


<trial bild1_hi>
/stimulustimes = [1=Productwithoutlabel1,highlabel1]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>


<trial bild1_lo>
/stimulustimes = [1=Productwithoutlabel1,lowlabel1]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>


<trial manip2_hi>
/stimulustimes = [1=manip2]
/ timeout = manip2
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [trial.fixation3 ]
</trial>

<trial manip2_lo>
/stimulustimes = [1=manip2]
/ timeout = manip2
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [trial.fixation4;]
</trial>


<trial bild2_hi>
/stimulustimes = [1=Productwithoutlabel2,highlabel2]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>


<trial bild2_lo>
/stimulustimes = [1=Productwithoutlabel2,lowlabel2]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>

--------------------Introduction task--------------------------
<trial fixationgroup1>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.testvid1]
</trial>

<trial testvid1>
/stimulustimes = [1=testvid1]
/ timeout = testvid1
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [trial.trialfixation1 ]
</trial>

<trial trialfixation1>
/stimulustimes = [1= text.fixation]
/ inputdevice = eyetracker
/ validresponse = (fixation)
/ datastreams = eyetracker
/ branch = [trial.testexp]
</trial>

<trial testexp>
/stimulustimes = [1=picture.testbild1]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ branch = [surveypage.Kaufintention;]
</trial>



------------
<block testexp>
/trials = [1=fixationgroup1]
/preinstructions = (welcome, vorgehensweise)
</block>

<block testkon>
/trials = [1=fixationgroup2]
/preinstructions = (welcome,vorgehensweise)
</block>


<block exp>
/trials = [1-6=noreplace(fixation1high,fixation1low)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>

<block con>
/trials = [1-6=noreplace(manip2_hi,manip2_lo)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>

----------------Experiment---------

<expt>
/blocks = [1=testexp; 2=exp]
/subjects = (1 of 2)
</expt>

<expt>
/blocks = [1=testexp; 2=con]
/subjects = (2 of 2)
</expt>

Sorry, I don't understand what the actual question is. Could you please clarify?

In addition, I'm unclear what this code is supposed to do:

<block exp>
/trials = [1-6=noreplace(fixation1high,fixation1low),(fixation2high,fixation2low),(fixation3high,fixation3low),(fixation4high,fixation4low),(fixation5high,fixation5low),(fixation6high,fixation6low)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>

That simply is not valid Inquisit syntax.

Sorry, i will try to clarifiy what my actual problem is.

The eye-tracking data that inquisit sends to the Data Viewer is based on the trials in inquisit. Usually if i open the trial in the Data Viewer i should be able to see the stimulus/product/picture and the gaze pattern for that specific trial in the Data Viewer. However, this is not the case because i have used trials like this.

<trial bild1_lo>
/stimulustimes = [1=Productwithoutlabel1,lowlabel1]
/trialduration = 25000
/ inputdevice = eyetracker
/ datastreams = eyetracker
/ screencapture = true
/ branch = [surveypage.Kaufintention]
</trial>

Here inquisit will choose one of the six products that are part of Productwithoutlabel1 and this is the reason why the Data Viewer can't display which picture/product participants were actually looking at and only displays a black screen with the gaze data of the eye-tracker.

What would work is using a trial for every product.(6 in total) for both high nutritioon an low nutrition labels. For example.

<trial bild1_lo>
/stimulustimes = [1=Product1,lowlabel1]
</trial>
<trial bild2_lo>
/stimulustimes = [1=Product2,lowlabel2]
</trial>
<trial bild3_lo>
/stimulustimes = [1=Product3,lowlabel3]
</trial>
<trial bild4_lo>
/stimulustimes = [1=Product4,lowlabel4]
</trial>
<trial bild5_lo>
/stimulustimes = [1=Product5,lowlabel5]
</trial>
<trial bild6_lo>
/stimulustimes = [1=Product6,lowlabel6]
</trial>

<trial bild1_hi>
/stimulustimes = [1=Product1,highlabel1]
</trial>
<trial bild2_hi>
/stimulustimes = [1=Product2,highlabel2]
</trial>
<trial bild3_hi>
/stimulustimes = [1=Product3,highlabel3]
</trial>
<trial bild4_hi>
/stimulustimes = [1=Product4,highlabel4]
</trial>
<trial bild5_hi>
/stimulustimes = [1=Product5,highlabel5]
</trial>
<trial bild6_hi>
/stimulustimes = [1=Product6,highlabel6]
</trial>

Here the Data Viewer displays the product that participants gazed at during the trial.However as i said before i need 3 of these products to be displayed in their low calorie and 3 in their high calorie version, which product is low or high should be randomized, but also evenly distributed. The old way of doing this was:
<block exp>
/trials = [1-6=noreplace(bild1_high,bild1_lo)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>
However because of the Data Viewer problem i can`t use this anymore. My attempt so far was doing this (sorry i copied the wrong attempt)
/trials = [1-6=noreplace(bild1_hi,bild1_lo,bild2_hi,bild2_lo,bild3_hi,bild3_lo,bild4_hi,bild4_lo,bild5_hi,bild5_lo,bild6_hi,bild6_lo)]
/preinstructions = (Zwischentext)
/ postinstructions = (end)
</block>
This obviously doesn't work. So i need to find another way to randomize the products (while they are evenly distributed) or find another way to tell the Data Viewer which picture was displayed in the trial.

I hope this was more understandable :)

Thank you, this makes the issue much clearer. You can achieve the necessary trial selection via nested <list> elements:

<block example>
/trials = [1-6=trialselector]
</block>

// sample a trial type (hi or lo) from list.trialtypes
// sample a product from list.productnumbers
// branch to the appropriate trial element representing the two above choices
<trial trialselector>
/ ontrialbegin = [
values.trialtype = list.trialtypes.nextvalue;
values.productnumber = list.productnumbers.nextvalue;
]
/ branch = [
list.trial_list.nextvalue;
]
/ validresponse = (0)
/ trialduration = 0
/ recorddata = false
</trial>

<values>
/ trialtype = 1
/ productnumber = 1
</values>

// 1 = hi trial
// 2 = lo trial
// we want to run three hi trials and three lo trials
<list trialtypes>
/ items = (1,1,1,2,2,2)
/ selectionmode = random
/ replace = false
</list>

// we have six products
<list productnumbers>
/ items = (1,2,3,4,5,6)
/ selectionmode = random
/ replace = false
</list>

// sample either from the hi trial list or the lo trial list according to selected value of values.trialtype
<list trial_list>
/ items = (list.hi_trials.nextvalue, list.lo_trials.nextvalue)
/ selectionmode = values.trialtype
</list>

// selects the trial according to the chose product number
<list hi_trials>
/ items = (trial.bild1_hi, trial.bild2_hi, trial.bild3_hi, trial.bild4_hi, trial.bild5_hi, trial.bild6_hi)
/ selectionmode = values.productnumber
</list>

// selects the trial according to the chose product number
<list lo_trials>
/ items = (trial.bild1_lo, trial.bild2_lo, trial.bild3_lo, trial.bild4_lo, trial.bild5_lo, trial.bild6_lo)
/ selectionmode = values.productnumber
</list>

// these are just dummy trials for demonstration purposes;
// replace with your own
*** hi ***
<trial bild1_hi>
/ trialduration = 10
</trial>
<trial bild2_hi>
/ trialduration = 10
</trial>
<trial bild3_hi>
/ trialduration = 10
</trial>
<trial bild4_hi>
/ trialduration = 10
</trial>
<trial bild5_hi>
/ trialduration = 10
</trial>
<trial bild6_hi>
/ trialduration = 10
</trial>

*** lo ***
<trial bild1_lo>
/ trialduration = 10
</trial>
<trial bild2_lo>
/ trialduration = 10
</trial>
<trial bild3_lo>
/ trialduration = 10
</trial>
<trial bild4_lo>
/ trialduration = 10
</trial>
<trial bild5_lo>
/ trialduration = 10
</trial>
<trial bild6_lo>
/ trialduration = 10
</trial>

Thanks so much again Dave, it works!