Millisecond Forums

+x

 

Dave - 4/23/2025

+x

 

Dave - 4/23/2025

+x

 

wmfang - 4/23/2025

+x

 

Dave - 4/23/2025

+x

 

wmfang - 4/23/2025

+x

 

Dave - 4/23/2025

+x

 

wmfang - 4/23/2025

+x

 

Dave - 4/23/2025

+x

 

wmfang - 4/23/2025

I am designing a study where participants are providing their evaluation 8 different social media profiles. 
These 8 profiles should be randomly selected from 16 profiles that I created in Inquisit (see screenshot below).

The four conditions to the 8 chosen profiles are:
- 4 should be high in Economic, 4 should be low in Economic,
- 4 should be high in Social, 4 should be low in Social
- All 4 locations should be represented in the high Economic profiles
- All 4 locations should be represented in the low Economic profiles
- All 4 locations should be represented in high Social profiles
- All 4 locations should be represented in low Social profiles

I currently have it such that there are 16 possible combinations of the 8 profiles, and participants see 1 combination that is randomly chosen. 

Thus, I would like to code this in Inquisit with conditional statements choosing from lists of profiles. How would I do this?

Thanks in advance!

Here are 2 examples of possible combinations:
<block combination1>
/ trials = [
1=high_econ_high_social_AR;
2=high_econ_high_social_SC;
3=high_econ_low_social_ID;
4=high_econ_low_social_TN;
5=low_econ_high_social_ID;
6=low_econ_high_social_TN;
7=low_econ_low_social_AR;
8=low_econ_low_social_SC;
]
</block>

<block combination2>
/ trials = [
1=high_econ_high_social_AR;
2=high_econ_high_social_ID;
3=high_econ_low_social_SC;
4=high_econ_low_social_TN;
5=low_econ_high_social_SC;
6=low_econ_high_social_TN;
7=low_econ_low_social_ID;
8=low_econ_low_social_AR;
]
</block>

Based on your description and the two <block> snippets, I have no idea what you actually set up or want to do. Please be more specific.

As seen in the screenshot, there are 16 possible profiles (1 per row). The profiles are from 1 of 4 Location, high or low in Economic, high or low in Social. I have created all 16 of these profiles in Inquisit as <surveypages> titled "high_econ_low_social_AR," etc. 

Of these 16 profiles, I would like to present 8 profiles to each subject/participant.

I would like the 8 profiles to be randomly selected, however, they must align with these conditions:
- 4 should be high in Economic, 4 should be low in Economic,
- 4 should be high in Social, 4 should be low in Social
- All 4 locations should be represented in the high Economic profiles
- All 4 locations should be represented in the low Economic profiles
- All 4 locations should be represented in high Social profiles
- All 4 locations should be represented in low Social profiles

Or in other words, the 8 profiles shown to participants should comprise of: 
- 4 high in Economic (2 high in Social, 2 low in Social, each from 1 of the 4 Locations (no repeat))
- 4 low in Economic (2 high in Social, 2 low in Social, each from 1 the 4 Locations (no repeat))
- The 4 high in Social profiles should also each be from 1 of the 4 Locations (no repeat). Same for the 4 low in Social profiles.  

I hope I explained it more clearly here.

Post at least one full example of a profie, i.e. the surveypage and anything it displays.

<surveypage high_econ_high_social_ID>
/ questions = [1=backgroundImage_ID_1; 2=profileImage; 3=companyImage_perkins; 4=schoolImage_columbia; 5=slider_bar]
/ stimulusframes = [
1=background_outer;
2=background;
3=nameImage;
4=schoolText_high_columbia;
5=companyText_high_perkins;
6=followersText;
7=connectionsText_high;
8=locationText_ID;
9=occupationText_high_JD;
10=dot_high]
/ nextlabel = "Next"
/ showpagenumbers = false
/ recorddata = true
/ navigationbuttonfontstyle = ("Arial", 12pt, false)
</surveypage>


<surveypage high_econ_low_social_ID>
/ questions = [1=backgroundImage_ID_1; 2=profileImage; 3=companyImage_perkins; 4=schoolImage_columbia; 5=slider_bar]
/ stimulusframes = [
1=background_outer;
2=background;
3=nameImage;
4=schoolText_high_columbia;
5=companyText_high_perkins;
6=connectionsText_low;
7=locationText_ID;
8=occupationText_high_JD]
/ nextlabel = "Next"
/ showpagenumbers = false
/ recorddata = true
/ navigationbuttonfontstyle = ("Arial", 12pt, false)
</surveypage>

I asked for everything. That means the surveypage and any and all elements it dispalys. The question elements, the <image> elements, any <text> elements, <picture> etc.

That includes any files as well.

Point being, it does not make any sense whatsoever to define a separate surveypage etc. for each and every econ status / social status / location combination.

You need at most 8 surveypages: high_econ_high_social_A, high_econ_high_social_B, high_econ_low_social_C, high_econ_low_social_D, low_econ_low_social_A, low_econ_low_social_B, low_econ_high_social_C, low_econ_high_social_C.

A, B, C, and D are the location, for which you just use variables. The logic of this whole thing dictates that a location randomly selected for a high/high trial MUST then also be used in a low/low trial.

<surveypage high_econ_high_social_ID>
/ questions = [1=backgroundImage_ID_1; 2=profileImage; 3=companyImage_perkins; 4=schoolImage_columbia; 5=slider_bar]
/ stimulusframes = [
1=background_outer;
2=background;
3=nameImage;
4=schoolText_high_columbia;
5=companyText_high_perkins;
6=followersText;
7=connectionsText_high;
8=locationText_ID;
9=occupationText_high_JD;
10=dot_high]
/ nextlabel = "Next"
/ showpagenumbers = false
/ recorddata = true
/ navigationbuttonfontstyle = ("Arial", 12pt, false)
</surveypage>

<surveypage high_econ_low_social_ID>
/ questions = [1=backgroundImage_ID_1; 2=profileImage; 3=companyImage_perkins; 4=schoolImage_columbia; 5=slider_bar]
/ stimulusframes = [
1=background_outer;
2=background;
3=nameImage;
4=schoolText_high_columbia;
5=companyText_high_perkins;
6=connectionsText_low;
7=locationText_ID;
8=occupationText_high_JD]
/ nextlabel = "Next"
/ showpagenumbers = false
/ recorddata = true
/ navigationbuttonfontstyle = ("Arial", 12pt, false)
</surveypage>

<text schoolText_high_columbia>
/ items = ("Columbia University in the ~nCity of New York")
/ position = (64%, 58%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = black
/ halign = left
</text>

<text companyText_high_perkins>
/ items = ("Perkins Coie LLP")
/ position = (64%, 52%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = black
/ halign = left
</text>

<text followersText>
/ items = ("<% round(rand(2000, 5000)) %> followers")
/ position = (20%, 65%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = steelblue
/ halign = left
</text>

<text connectionsText_high>
/ items = ("500+ connections")
/ position = (30%, 65%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = steelblue
/ halign = left
</text>

<text connectionsText_low>
/ items = ("<% round(rand(0, 150)) %> connections")
/ position = (20%, 65%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = steelblue
/ halign = left
</text>

<shape dot_high>
/ shape = circle
/ color = steelblue
/ position = (29%, 65%)
/ size = (7, 7)
</shape>

<text locationText_ID>
/ items = ("Boise, ID")
/ position = (20%, 61%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = dimgrey
/ halign = left
</text>

<text occupationText_high_JD>
/ items = ("Associate, J.D.")
/ position = (20%, 58%)
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
/ color = black
/ halign = left
</text>

<slider slider_bar>
/ labels=("Low status", "High status")
/ range = (0, 100)
/ showticks = false
/ slidersize = (70%, 15%)
/ position = (10%, 80%)
/ responsefontstyle = ("Arial", 3%, false, false, false, false, 5, 0)
</slider>

<image schoolImage_columbia>
/ items = ("LINKEDIN_profileS_INQUISIT/SCHOOL/columbia.png")
/ imagesize = (5, 5)
/ position = (60%, 56%)
</image>

<image companyImage_perkins>
/ items = ("LINKEDIN_PROFILES_INQUISIT/company/perkins_coie.png")
/ imagesize = (5, 5)
/ position = (60%, 50%)
</image>

<image profileImage>
/ items = ("LINKEDIN_profileS_INQUISIT/profile_IMAGE/profile_CROPPED.png")
/ imagesize = (20, 20)
/ position = (25%, 30%)
</image>

<image backgroundImage_ID_1>
/ items = ("LINKEDIN_profileS_INQUISIT/BACKGROUND/boise_id_1_cropped.png")
/ imagesize = (60, 60)
/ position = (20%, 10%)
</image>

<shape background>
/ shape = rectangle
/ color = white
/ size = (80%, 70%)
/ position = (50%,40%)
</shape>

<shape background_outer>
/ shape = rectangle
/ color = navy
/ size = (81%, 71%)
/ position = (50%,40%)
</shape>

<shape nameImage>
/ shape = rectangle
/ color = lightgrey
/ size = (20%, 5%)
/ position = (30%,53%)
</shape>

Those aren't all files.

Can you please just put them in a ZIP and then attach it. Thanks.

Anyhow: Since you already have all the surveypages and I don't feel like rewriting the whole thing from scratch, here's how you can make do with what you have.

(1) Arrange all the surveypages into <list>s by trial type -- hi/hi, lo/lo, hi/lo, lo/hi -- ordered alphabetically by location.

<list hi_hi>
/ items = (
    surveypage.high_econ_high_social_AR, surveypage.high_econ_high_social_ID,
    surveypage.high_econ_high_social_SC, surveypage.high_econ_high_social_TN)
</list>

<list lo_lo>
/ items = (
  surveypage.low_econ_low_social_AR, surveypage.low_econ_low_social_ID,
  surveypage.low_econ_low_social_SC, surveypage.low_econ_low_social_TN)
</list>

<list hi_lo>
/ items = (
    surveypage.high_econ_low_social_AR, surveypage.high_econ_low_social_ID,
    surveypage.high_econ_low_social_SC, surveypage.high_econ_low_social_TN)
</list>

<list lo_hi>
/ items = (
    surveypage.low_econ_high_social_AR, surveypage.low_econ_high_social_ID,
    surveypage.low_econ_high_social_SC, surveypage.low_econ_high_social_TN)
</list>

(2) Create a <list> of the 4 locations (alphabetical order).

<list locations>
/ items = (
    "AR", "ID",
    "SC", "TN")
/ selectionrate = always
</list>

(3) Create an empty <list> to hold the pages we'll end up selecting and actually running.

<list trialList>
</list>

(4) Poplulate that list /onBlockBegin and then run it.

<block exampleBlock>
/ onBlockBegin = [
    // pick location for hi_hi #1 & lo_lo #1
    var loc = list.locations.nextindex;
    list.trialList.appenditem(list.hi_hi.item(loc));
    list.trialList.appenditem(list.lo_lo.item(loc));
    // pick location for hi_hi #2 & lo_lo #2
    loc = list.locations.nextindex;
    list.trialList.appenditem(list.hi_hi.item(loc));
    list.trialList.appenditem(list.lo_lo.item(loc));
    // pick location for hi_lo #1 & lo_hi #1
    loc = list.locations.nextindex;
    list.trialList.appenditem(list.hi_lo.item(loc));
    list.trialList.appenditem(list.lo_hi.item(loc));
    // pick location for hi_lo #2 & lo_hi #2
    loc = list.locations.nextindex;
    list.trialList.appenditem(list.hi_lo.item(loc));
    list.trialList.appenditem(list.lo_hi.item(loc));
]
/ trials = [1-8 = list.trialList]
</block>