Millisecond Forums

You can concatenate anything, including items in <text> elements. However, you should simply do

<item someitem>
/1 = "1. You are about to board a plane. The chance of this plane crashing is <%text.sometext2.currentitem%>"
</item>

Thanks Dave that works great. The last thing i need to do is have it so that "sometext2" randomly selects an item from "someitem2", rather than just going with the first item in the list. So far I have the following

<item practice_item>
/1 = "1. You are about to board a plane. The chances of this plane crashing are <%text.sometext2.currentitem%>."
</item>

<text sometext2>
/ items = someitem2
/select = noreplace
</text>

<item someitem2>
/1 = "L_w"
/2 = "Lo_"
/3 = "_ow"
</item>

I was thinking that because I used /select = noreplace that either /1, /2, or/3 would be randomly selected from "someitem2" to add to the end of "someitem". But it still always choses /1 (L_w) to add to the end. How do I make it randomly select from someitem2's list?

thanks

Selections on a <text> element will only be performed if you actually *use* the respective element in a given <trial> element's /stimulusframes or /stimulustimes:

<block myblock>
/ trials = [1-3=mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=sometext2,sometext1]
/ validresponse = (57)
</trial>

<text sometext1>
/ items = practice_item
</text>

<item practice_item>
/1 = "1. You are about to board a plane. The chances of this plane crashing are <%text.sometext2.currentitem%>."
</item>

<text sometext2>
/ items = someitem2
/select = noreplace
/ position = (50%, 60%)
</text>

<item someitem2>
/1 = "L_w"
/2 = "Lo_"
/3 = "_ow"
</item>

If you want to keep using <text> elements, you'll want to position <text sometext2> offscreen or give it a /txcolor equal to the screen's background color (so it's invisible). Otherwise, use e.g. a <counter> for which a simple *reference* will suffice to execute a selection:

<block myblock>
/ trials = [1-3=mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=sometext1]
/ validresponse = (57)
</trial>

<text sometext1>
/ items = practice_item
</text>

<item practice_item>
/1 = "1. You are about to board a plane. The chances of this plane crashing are <%counter.sometext2.selectedvalue%>."
</item>

<counter sometext2>
/ items = ("L_w", "Lo_", "_ow")
/select = noreplace
</counter>

Regards,

~Dave

Thanks dave, that's perfect!

Hi Dave,
I have a brief question:

I want to concatenate the answer string of an openended element with the letters "DONE" and then have this new concatenated string written in my data file. Could you help me out by telling me the correct syntax for this?
I tried the following approaches:

<text VPtext>
/items = ("bla")
/position = (50,40)
</text>

<openended VP>
/ stimulusframes = [1=VPtext]
/ position = (50, 55)
/ linelength = 20
/ numlines = 1
/ mouse = true
/ inputdevice = keyboard
/ buttonlabel = "OK"
/ ontrialend = [concat(openended.vp.response,"DONE")]
</openended>

or:
<openended VP>
/ stimulusframes = [1=VPtext]
/ position = (50, 55)
/ linelength = 20
/ numlines = 1
/ mouse = true
/ inputdevice = keyboard
/ buttonlabel = "OK"
/ ontrialend = [openended.vp.response =(concat(openended.vp.response,"DONE"))]
</openended>
=> got a "this is read-only content" error, well I coud have imagined that

furthermore I tried to set an external value:
<values>
/ vpcode = concat(openended.vp.response,"DONE")
</values>

But somehow the strings never concatenate. It's always the response only in the column for the response and always only "DONE" in the column for the value.

Would greatly appreciate if you could help me out here.

> I want to concatenate the answer string of an openended element with the letters "DONE" and then have this new concatenated string
> written in my data file.

The correct way to do this is

<values>
/ oe_response = ""
</values>

<openended VP>
...
/ ontrialend = [values.oe_response = concat(openended.vp.response,"DONE")]
</openended>

with

<data>
/ columns = [... values.oe_response ...]
...
</data>

This worked out and I got why.
Thank you very much, Dave.