Stroop task - repeat practice + randomise with constraints


Author
Message
KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Hello


I am pretty new to Inquisit, so I apologise if the following questions are stupid.


I have managed to modify the verbal stroop task (downloaded from Inquisit task library) so it runs 3 blocks: word reading, colour naming and incongruent colour naming. Each block is preceded by a practice block of 3 trials.


I have 2 questions:


1. I would like to be able to repeat the practice for each block by pressing a key on the keyboard (i.e. "r"). That is, when the practice block ends, I would like to present a screen saying something like "Would you like to repeat the practice". Then depending on what key I press, the practice will be repeated or the experiment will continue to the test block. I don't know how to do this.


2. I would like to randomise the trials in my test blocks, so that no trial type is repeated more than 3 times in a row (e.g., the red square is presented max 3 times in a row).  I have looked on the forum, but couldn't find a way to do this. Ideally for the incongruent stimuli I would like to make sure that both the colour and meaning for the word is not repeated more than 3 times in a row, but that might end up being to complicated...


Any help much appreciated - thanks!


My script looks like this so far:


---------------------------------------------------------------------------------------
                    *** STROOP TASK WITH VOICE RECORDING *****
---------------------------------------------------------------------------------------           

I have modified this script in accordance with Leon-Carrion et al. 2004.

This version includes three tasks administered in a set order:

1. Word reading (WR)
2. Colour naming (CN)
3. Incongruent colour naming of colour words (INC)

Each condition is preceded by 3 practice trials in a set sequence.
Following practice 20 trials are presented in each condition.

Stimulus colours: Blue, Red, Green


---------------------------------------------------------------------------------------
*** DEFAULTS *****
---------------------------------------------------------------------------------------           
requires Inquisit 4.0.2.0  or higher

<defaults>
/minimumversion = "4.0.2.0"
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 1)
/ inputdevice = voicerecord
/ posttrialpause = 500
</defaults>
---------------------------------------------------------------------------------------
*** DATA *****
---------------------------------------------------------------------------------------           
---------
raw data
---------
<data>
/file = "StroopWithVoiceRecording_raw.iqdat"
/separatefiles = true
/ columns = [date time subject trialcode blockcode blocknum trialnum latency response stimulusitem stimulusitem]
</data>
---------
summary data
---------
<summarydata >
/file = "StroopWithVoiceRecording_summary.iqdat"
/columns = [script.startdate, script.starttime, script.subjectid]
</summarydata>

------------------------------------------------------------------------------------
*** TEXTS AND TARGETS *****
------------------------------------------------------------------------------------
<text false>
/ items = ("false")
/ color = (255, 0, 0)
/ position = (50,80)
</text>

<item fixation>
/1 ="+"                 
</item>

<item square>
/1 ="■"                 
</item>

<text fixationblack>
/ items = fixation
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text fixationwhite>
/ items = fixation
/ color = white
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text bluegreen>
/ items = ("blue")
/ color = green
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redgreen>
/ items = ("red")
/ color = green
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenblue>
/ items = ("green")
/ color = blue
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redblue>
/ items = ("red")
/ color = blue
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenred>
/ items = ("green")
/ color = red
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text bluered>
/ items = ("blue")
/ color = red
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redblack>
/ items = ("red")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenblack>
/ items = ("green")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text blueblack>
/ items = ("blue")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text target>
/ items = ("*")
/ color = (255, 255, 255)
</text>

<text greensquare>
/ items = square
/ color = (0, 255, 0)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text bluesquare>
/ items = square
/ color = (0, 0, 255)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text redsquare>
/ items = square
/ color = (255, 0, 0)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text targetsquare>
/ items = ("*")
/ color = (255, 255, 255)
</text>

------------------------------------------------------------------------------------
*** INSTRUCTION PAGES *****
------------------------------------------------------------------------------------

<instruct>
/ nextkey = (" ")
/ lastlabel = "Press the spacebar to continue"
/ nextlabel = "Press the spacebar to continue"
/ wait = 500
</instruct>

<page welcome>
^^^^
Welcome to the Stroop Color Task. In the following you will be doing three
short tasks. You will receive instructions before each task.
</page>

<page page1>
In the following your task is to read the word you see on the screen (green, red or blue). Read the word as accurately and quickly as you can.
</page>

<page page2>
In the following your task is to say the colour of the square you see on the screen. The square is either green, red or blue. Say the name of the colour as accurately and quickly as you can.
</page>

<page page3>
In the following task you will see words written in green, red or blue. Your task is to say the colour of the word (not the meaning of the word). For example, if you see the word "red" written in blue, you should say "blue". Is that clear? Name the colour that the word is written in as accurately and quickly as you can.
</page>

<page end>
This is the end. Thank you for your participation.
</page>

------------------------------------------------------------------------------------
*** TRIALS *****
------------------------------------------------------------------------------------

<trial wordsredblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redblack]
</trial>

<trial wordsgreenblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenblack]
</trial>

<trial wordsblueblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=blueblack]
</trial>

<trial bluegreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluegreen]
</trial>

<trial redgreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redgreen]
</trial>

<trial greenblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenblue]
</trial>

<trial redblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redblue]
</trial>

<trial greenred>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenred]
</trial>

<trial bluered>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluered]
</trial>

<trial squaresred>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redsquare]
</trial>

<trial squaresgreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greensquare]
</trial>

<trial squaresblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluesquare]
</trial>

------------------------------------------------------------------------------------
*** BLOCKS *****
------------------------------------------------------------------------------------

<block WRprac>
/preinstructions =(page1)
/ trials = [1 =sequence(wordsredblack,wordsgreenblack,wordsblueblack)]
</block>

<block WR>
/preinstructions =(page1)
/ trials = [1-6 =noreplace(wordsredblack,wordsgreenblack,wordsblueblack)]
</block>

<block CNprac>
/preinstructions =(page2)
/ trials = [1 =sequence(squaresgreen,squaresblue,squaresred)]
</block>

<block CN>
/preinstructions =(page2)
/ trials = [1-6 =noreplace(squaresred,squaresgreen,squaresblue)]
</block>

<block INCprac>
/preinstructions =(page3)
/ trials = [1 =sequence(bluered,redgreen,greenblue)]
</block>

<block INC>
/preinstructions =(page3)
/ trials = [1-6 =noreplace(bluegreen,redgreen,greenblue,redblue,greenred,bluered)]
</block>

------------------------------------------------------------------------------------
*** EXPERIMENT*****
------------------------------------------------------------------------------------

<expt>
/ blocks = [1=WRprac; 2=WR; 3=CNprac; 4=CN; 5=INCprac; 6=INC]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>
------------------------------------------------------------------------------------
*** End of File*****
------------------------------------------------------------------------------------


Dave
Dave
Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)
Group: Administrators
Posts: 12K, Visits: 100K

1. I would like to be able to repeat the practice for each block by pressing a key on the keyboard (i.e. "r"). That is, when the practice block ends, I would like to present a screen saying something like "Would you like to repeat the practice". Then depending on what key I press, the practice will be repeated or the experiment will continue to the test block. I don't know how to do this.


You need a /branch in your practice <block> that runs the practice block again in case of a "repeat" response.


2. I would like to randomise the trials in my test blocks, so that no trial type is repeated more than 3 times in a row (e.g., the red square is presented max 3 times in a row).  I have looked on the forum, but couldn't find a way to do this. Ideally for the incongruent stimuli I would like to make sure that both the colour and meaning for the word is not repeated more than 3 times in a row, but that might end up being to complicated...


You will need to use <list> elements and define the appropriate /maxrunsize.



KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Re. 1: The task records voice responses (to be coded later). I understand the /branch command, but how do I add a key response to rerun to the practice (without interfering wit the voice recording)?


Dave
Dave
Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)
Group: Administrators
Posts: 12K, Visits: 100K

Add a <trial> with /inputdevice set to keyboard or mouse and run it as the last trial in the practice block. You may refer to the below example re. both your questions:


<expt>
/ blocks = [1=myblock]
</expt>

<block myblock>
/ trials = [1-20=list.triallist; 21=repeattrial]
/ branch = [if(trial.repeattrial.response=="yes")block.myblock]
</block>

<list triallist>
/ items=[trial.atrial; trial.btrial;]
/ poolsize=20
/ selectionmode=random
/ maxrunsize = 3
</list>

<trial atrial>
/ timeout = 10
</trial>

<trial btrial>
/ timeout = 10
</trial>

<trial repeattrial>
/ stimulusframes = [1=ask,yes,no]
/ inputdevice = mouse
/ validresponse = (yes,no)
</trial>

<text ask>
/ items = ("Wanna repeat the block?")
</text>

<text yes>
/ items = ("Yes, I do.")
/ position = (40%, 60%)
</text>

<text no>
/ items = ("No, I don't.")
/ position = (60%, 60%)
</text>


Regards


~Dave



KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Thanks Dave!


I'll have a go at it...


KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Hi Dave


I all works quite nicely now, thanks so much for your help!


When I use the randomisation method you suggest I get the following message:


In order to more precisely satisfy the probabilities specified in /itemsprobabilities, the size of the selection pool was adjusted from 20 to 21.


What does that mean?


I was also wondering how this randmisation actually works. Does the programme simply select the stimulus randomly on each trial (with the constraint of max 3 repeats), or does it make a list which is randomised with constraints and then presented? I would prefer the latter method because otherwise I could in principle end up with some stimuli not being presented (e.g., I could get red-green-red-green the whole experiment). I think in your post on randomisation with constraints you mentioned something about generating a number of randomised lists (with constraints) and then selecting one of these randomly for each participant. How would I go about doing this?


Sorry for asking so many questions!


Thanks!


KH


Dave
Dave
Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)
Group: Administrators
Posts: 12K, Visits: 100K


When I use the randomisation method you suggest I get the following message:


In order to more precisely satisfy the probabilities specified in /itemsprobabilities, the size of the selection pool was adjusted from 20 to 21.


What does that mean?



I cannot answer that without you posting the relevant pieces of the code.


Does the programme simply select the stimulus randomly on each trial (with the constraint of max 3 repeats),


You are sampling *trials* here, not stimuli. How those trials then go on to sample from any stimulus elements is another matter entirely. How the sampling works is detailed in the documentation for the /maxrunsize attribute.


I could in principle end up with some stimuli not being presented (e.g., I could get red-green-red-green the whole experiment).


No, not when you set up your <list> element properly.



KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Ok, sorry for not posting the script, it's posted below.


When I read the maxrunsize documentation it is not clear to me whether EVERY trial in the list is used (selected randomly with constraints) or whether trials a simply picked randomly from the different trial types?


Each trial only have one associated stimulus in the script below.


Thanks!



---------------------------------------------------------------------------------------
                    *** STROOP TASK WITH VOICE RECORDING *****
---------------------------------------------------------------------------------------           

I have modified this script in accordance with Leon-Carrion et al. 2004.

This version includes three tasks administered in a set order:

1. Word reading (WR)
2. Colour naming (CN)
3. Incongruent colour naming of colour words (INC)

Each condition is preceded by 3 practice trials in a set sequence.
Following practice 20 trials are presented in each condition.

Stimulus colours: Blue, Red, Green


---------------------------------------------------------------------------------------
*** DEFAULTS *****
---------------------------------------------------------------------------------------           
requires Inquisit 4.0.2.0  or higher

<defaults>
/minimumversion = "4.0.2.0"
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 1)
/ inputdevice = voicerecord
/ posttrialpause = 500
</defaults>
---------------------------------------------------------------------------------------
*** DATA *****
---------------------------------------------------------------------------------------           
---------
raw data
---------
<data>
/file = "StroopWithVoiceRecording_raw.iqdat"
/separatefiles = true
/ columns = [date time subject trialcode blockcode blocknum trialnum latency response stimulusitem stimulusitem]
</data>
---------
summary data
---------
<summarydata >
/file = "StroopWithVoiceRecording_summary.iqdat"
/columns = [script.startdate, script.starttime, script.subjectid]
</summarydata>

------------------------------------------------------------------------------------
*** TEXTS AND TARGETS *****
------------------------------------------------------------------------------------
<text false>
/ items = ("false")
/ color = (255, 0, 0)
/ position = (50,80)
</text>

<item fixation>
/1 ="+"                 
</item>

<item square>
/1 ="■"                 
</item>

<text fixationblack>
/ items = fixation
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text fixationwhite>
/ items = fixation
/ color = white
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text bluegreen>
/ items = ("blue")
/ color = green
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redgreen>
/ items = ("red")
/ color = green
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenblue>
/ items = ("green")
/ color = blue
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redblue>
/ items = ("red")
/ color = blue
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenred>
/ items = ("green")
/ color = red
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text bluered>
/ items = ("blue")
/ color = red
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text redblack>
/ items = ("red")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text greenblack>
/ items = ("green")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text blueblack>
/ items = ("blue")
/ color = black
/ fontstyle = ("Arial", 8.00%, false, false, false, false, 5, 1)
</text>

<text target>
/ items = ("*")
/ color = (255, 255, 255)
</text>

<text greensquare>
/ items = square
/ color = (0, 255, 0)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text bluesquare>
/ items = square
/ color = (0, 0, 255)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text redsquare>
/ items = square
/ color = (255, 0, 0)
/ fontstyle = ("Arial", 15.00%, false, false, false, false, 5, 1)
</text>

<text targetsquare>
/ items = ("*")
/ color = (255, 255, 255)
</text>

------------------------------------------------------------------------------------
*** LISTS *****
------------------------------------------------------------------------------------

<list WRpractriallist>
/ items=[trial.wordsredblack; trial.wordsgreenblack; trial.wordsblueblack]
/ poolsize=3
/ selectionmode=sequence
</list>

<list CNpractriallist>
/ items=[trial.squaresgreen; trial.squaresblue; trial.squaresred]
/ poolsize=3
/ selectionmode=sequence
</list>

<list INCpractriallist>
/ items=[trial.bluered; trial.redgreen; trial.greenblue]
/ poolsize=3
/ selectionmode=sequence
</list>

<list WRtriallist>
/ items=[trial.wordsredblack; trial.wordsgreenblack; trial.wordsblueblack]
/ poolsize=20
/ selectionmode=random
/ maxrunsize = 3
</list>

<list CNtriallist>
/ items=[trial.squaresgreen; trial.squaresblue; trial.squaresred]
/ poolsize=20
/ selectionmode=random
/ maxrunsize = 3
</list>

<list INCtriallist>
/ items=[trial.bluegreen; trial.redgreen; trial.greenblue; trial.redblue; trial.greenred; trial.bluered]
/ poolsize=20
/ selectionmode=random
/ maxrunsize = 3
</list>

------------------------------------------------------------------------------------
*** INSTRUCTION PAGES *****
------------------------------------------------------------------------------------

<instruct>
/ nextkey = (" ")
/ lastlabel = "Press the spacebar to continue"
/ nextlabel = "Press the spacebar to continue"
/ wait = 500
</instruct>

<page welcome>
^^^^
Welcome to the Stroop Color Task. In the following you will be doing three
short tasks. You will receive instructions before each task.
</page>

<page page1prac>
In the following your task is to read the word you see on the screen (green, red or blue). Read the word as accurately and quickly as you can. We will start by practicing a few trials.
</page>

<page page1>
In the following your task is to read the word you see on the screen (green, red or blue). Read the word as accurately and quickly as you can.
</page>

<page page2prac>
In the following your task is to say the colour of the square you see on the screen. The square is either green, red or blue. Say the name of the colour as accurately and quickly as you can. We will start by practicing a few trials.
</page>

<page page2>
In the following your task is to say the colour of the square you see on the screen. The square is either green, red or blue. Say the name of the colour as accurately and quickly as you can.
</page>

<page page3prac>
In the following task you will see words written in green, red or blue. Your task is to say the colour of the word (not the meaning of the word). For example, if you see the word "red" written in blue, you should say "blue". Is that clear? Name the colour that the word is written in as accurately and quickly as you can. We will start by practicing a few trials.
</page>

<page page3>
In the following task you will see words written in green, red or blue. Your task is to say the colour of the word (not the meaning of the word). For example, if you see the word "red" written in blue, you should say "blue". Is that clear? Name the colour that the word is written in as accurately and quickly as you can.
</page>

<page end>
This is the end. Thank you for your participation.
</page>

------------------------------------------------------------------------------------
*** TRIALS *****
------------------------------------------------------------------------------------

<trial wordsredblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redblack]
</trial>

<trial wordsgreenblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenblack]
</trial>

<trial wordsblueblack>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=blueblack]
</trial>

<trial bluegreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluegreen]
</trial>

<trial redgreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redgreen]
</trial>

<trial greenblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenblue]
</trial>

<trial redblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redblue]
</trial>

<trial greenred>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greenred]
</trial>

<trial bluered>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluered]
</trial>

<trial squaresred>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=redsquare]
</trial>

<trial squaresgreen>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=greensquare]
</trial>

<trial squaresblue>
/ stimulustimes = [0=target;500=fixationblack;1000=fixationwhite;1500=bluesquare]
</trial>

<trial repeattrial>
/ stimulusframes = [1=ask,yes,no]
/ inputdevice = mouse
/ validresponse = (yes,no)
</trial>

<text ask>
/ items = ("Do you want to repeat the practice?")
</text>

<text yes>
/ items = ("Yes")
/ position = (40%, 60%)
/ txbgcolor = (255, 255, 255)
/ txbgcolor = yellow
</text>

<text no>
/ items = ("No ")
/ position = (60%, 60%)
/ txbgcolor = yellow
</text>


------------------------------------------------------------------------------------
*** BLOCKS *****
------------------------------------------------------------------------------------

<block WRprac>
/preinstructions =(page1prac)
/ trials = [1-3 =list.WRpractriallist; 4=repeattrial]
/ branch = [if(trial.repeattrial.response=="yes")block.WRprac]
</block>

<block WR>
/ trials = [1-20 =list.WRtriallist]
</block>

<block CNprac>
/preinstructions =(page2prac)
/ trials = [1-3 =list.CNpractriallist; 4=repeattrial]
/ branch = [if(trial.repeattrial.response=="yes")block.CNprac]
</block>

<block CN>
/ trials = [1-20 =list.CNtriallist]
</block>

<block INCprac>
/preinstructions =(page3prac)
/ trials = [1-3 =list.INCpractriallist; 4=repeattrial]
/ branch = [if(trial.repeattrial.response=="yes")block.INCprac]
</block>

<block INC>
/ trials = [1-20 =list.INCtriallist]
</block>

------------------------------------------------------------------------------------
*** EXPERIMENT*****
------------------------------------------------------------------------------------

<expt>
/ blocks = [1=WRprac; 2=WR; 3=CNprac; 4=CN; 5=INCprac; 6=INC]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>
------------------------------------------------------------------------------------
*** End of File*****
------------------------------------------------------------------------------------


Dave
Dave
Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)
Group: Administrators
Posts: 12K, Visits: 100K

<list WRtriallist>
/ items=[trial.wordsredblack; trial.wordsgreenblack; trial.wordsblueblack]
/ poolsize=20
/ selectionmode=random
/ maxrunsize = 3
</list>


Think about the above for a minute. A pool of 20 items consisting of 3 elements in equal proportions. The math doesn't check out. You need a size of 21 to do that (i.e., every element is included 7 times in the pool).


When I read the maxrunsize documentation it is not clear to me whether EVERY trial in the list is used (selected randomly with constraints) or whether trials a simply picked randomly from the different trial types?


Selection is *random without replacement* from the given pool. Constraints are applied at runtime, satisfied if possible and relaxed if not.


KarlaHolmboe
KarlaHolmboe
Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)Esteemed Member (2.1K reputation)
Group: Forum Members
Posts: 12, Visits: 1

Brilliant - many thanks again for all your help. Does Inquisit pay you to give all this support? They ought to!


Have a nice weekend!


KH


GO

Merge Selected

Merge into selected topic...



Merge into merge target...



Merge into a specific topic ID...




Reading This Topic

Explore
Messages
Mentions
Search