Hi Sean,
This is the script we are using that functions on a mac, but not on our PC running Windows 8. I think it only has a few modifications from the original script in the task library. Thank you for being willing to assist!
Amanda
---------------------------------------------------------------------------------------
*** STROOP TASK WITH VOICE RECORDING *****
---------------------------------------------------------------------------------------
This script implements an example Stroop test with voice recordings.
All responses are saved in audio files that can be analyzed after the experiment is over.
last updated: 09-06-2013 by K. Borchert for Millisecond Software LLC
---------------------------------------------------------------------------------------
*** DEFAULTS *****
---------------------------------------------------------------------------------------
requires Inquisit 4.0.2.0 or higher
<defaults>
/minimumversion = "4.0.2.0"
/ fontstyle = ("Arial", 10.00%, false, false, false, false, 5, 1)
/ inputdevice = voicerecord
/ posttrialpause = 1000
</defaults>
---------------------------------------------------------------------------------------
*** VALUES *****
---------------------------------------------------------------------------------------
/congruence: 1 = congruent in color and word ; 2 = incongruent
<values>
/congruence = 0
</values>
---------------------------------------------------------------------------------------
*** DATA *****
---------------------------------------------------------------------------------------
/congruence: 1 = congruent in color and word ; 2 = incongruent
---------
raw data
---------
<data>
/file = "StroopWithVoiceRecording_raw.iqdat"
/separatefiles = true
/ columns = [date time subject blockcode blocknum trialcode trialnum values.congruence
stimulusitem stimulusitem latency response ]
</data>
---------
summary data
---------
<summarydata >
/file = "StroopWithVoiceRecording_summary.iqdat"
/columns = [script.startdate, script.starttime, script.subjectid]
</summarydata>
------------------------------------------------------------------------------------
*** TEXTS AND TARGETS *****
------------------------------------------------------------------------------------
<text false>
/ items = ("false")
/ color = (255, 0, 0)
/ position = (50,80)
</text>
<item words>
/2 ="red"
/3 ="blue"
/4 ="green"
</item>
<text green>
/ items = words
/ color = (0, 255, 0)
</text>
<text blue>
/ items = words
/ color = (0, 0, 255)
</text>
<text red>
/ items = words
/ color = (255, 0, 0)
</text>
<text target>
/ items = ("*")
/ color = (255, 255, 255)
</text>
<text instructleft>
/ items = ("Say the ink color.")
/ position = (10, 20)
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 1)
/ color = (0,0,0)
/ txbgcolor = (255, 255, 255)
</text>
------------------------------------------------------------------------------------
*** INSTRUCTION PAGES *****
------------------------------------------------------------------------------------
<instruct>
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 1)
/ nextkey = (" ")
/ lastlabel = "Press the spacebar to continue"
/ nextlabel = "Press the spacebar to continue"
/ wait = 500
</instruct>
<page welcome>
^^^^
Welcome to the Stroop Color Task.
</page>
<page page1>
Your task is to determine whether the word that appears on the screen is green, red or blue. Say the color of the word (not the meaning of the word). You will have 50 trials. Try to respond as quickly as you can, because you will be timed.
</page>
<page end>
This is the end. Thank you for your participation.
</page>
------------------------------------------------------------------------------------
*** TRIALS *****
------------------------------------------------------------------------------------
<trial wordsred>
/ stimulustimes = [0=target;1=red;2=instructleft]
/ontrialend = [if (text.red.currentitemnumber == 2) values.congruence = 1 else values.congruence = 2]
</trial>
<trial wordsgreen>
/ stimulustimes = [0=target;1=green;2=instructleft]
/ontrialend = [if (text.green.currentitemnumber == 4) values.congruence = 1 else values.congruence = 2]
</trial>
<trial wordsblue>
/ stimulustimes = [0=target;1=blue;2=instructleft]
/ontrialend = [if (text.blue.currentitemnumber == 3) values.congruence = 1 else values.congruence = 2]
</trial>
------------------------------------------------------------------------------------
*** BLOCKS *****
------------------------------------------------------------------------------------
<block series1>
/preinstructions =(page1)
/ trials = [1-50 =noreplace(wordsred,wordsgreen,wordsblue)]
</block>
------------------------------------------------------------------------------------
*** EXPERIMENT*****
------------------------------------------------------------------------------------
<expt>
/ blocks = [1=series1]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>
------------------------------------------------------------------------------------
*** End of File*****
------------------------------------------------------------------------------------