|
Group: Awaiting Activation
Posts: 7,
Visits: 38
|
Hi,
I have four categories of text items, I'll call them groups A & B and 1 & 2. I want for the items to appear in word pairs, with four possible pairings: A1, A2, B1, B2. A's and B's should always be on top and 1's and 2's should always be on bottom when the words pairs are presented. Further, I want the pairings to appear randomly in different locations on the screen (doesn't really matter in how many different places, 3-4 would be fine).
I am having trouble figuring out how to program it so the words from each category are randomly paired and the words pairs are randomly placed (with the words in their proper top/bottom positions). I have been told I can use the 'counter' element to do this but after trying to understand how to implement this I am still stuck. Please help - thank you!
|
|
Group: Administrators
Posts: 13K,
Visits: 108K
|
For example:
<block myblock>
/ trials = [1-8=noreplace(a1,a2,b1,b2)]
</block>
<trial a1>
/ ontrialbegin = [text.cat_1.hposition=text.cat_a.hposition;
text.cat_1.vposition=text.cat_a.vposition + 5%;]
/ stimulusframes = [1=cat_a, cat_1]
/ validresponse = (57)
</trial>
<trial a2>
/ ontrialbegin = [text.cat_2.hposition=text.cat_a.hposition;
text.cat_2.vposition=text.cat_a.vposition + 5%;]
/ stimulusframes = [1=cat_a, cat_2]
/ validresponse = (57)
</trial>
<trial b1>
/ ontrialbegin = [text.cat_1.hposition=text.cat_b.hposition;
text.cat_1.vposition=text.cat_b.vposition + 5%;]
/ stimulusframes = [1=cat_b, cat_1]
/ validresponse = (57)
</trial>
<trial b2>
/ ontrialbegin = [text.cat_2.hposition=text.cat_b.hposition;
text.cat_2.vposition=text.cat_b.vposition + 5%;]
/ stimulusframes = [1=cat_b, cat_2]
/ validresponse = (57)
</trial>
<text cat_a>
/ items = cat_a_items
/ select = list.cat_a_itemnumbers.nextvalue
/ hposition = list.randomhposition.nextvalue
/ vposition = list.randomvposition.nextvalue
</text>
<text cat_b>
/ items = cat_b_items
/ select = list.cat_b_itemnumbers.nextvalue
/ hposition = list.randomhposition.nextvalue
/ vposition = list.randomvposition.nextvalue
</text>
<text cat_1>
/ items = cat_1_items
/ select = list.cat_1_itemnumbers.nextvalue
</text>
<text cat_2>
/ items = cat_2_items
/ select = list.cat_2_itemnumbers.nextvalue
</text>
<list cat_a_itemnumbers>
/ items = (1,2,3,4)
/ selectionmode = random
/ selectionrate = trial
</list>
<list cat_b_itemnumbers>
/ items = (1,2,3,4)
/ selectionmode = random
/ selectionrate = trial
</list>
<list cat_1_itemnumbers>
/ items = (1,2,3,4)
/ selectionmode = random
/ selectionrate = trial
</list>
<list cat_2_itemnumbers>
/ items = (1,2,3,4)
/ selectionmode = random
/ selectionrate = trial
</list>
<list randomhposition>
/ items = (25%, 50%, 75%)
/ selectionmode = random
/ replace = true
/ selectionrate = trial
</list>
<list randomvposition>
/ items = (40%, 60%)
/ selectionmode = random
/ replace = true
/ selectionrate = trial
</list>
<item cat_a_items>
/ 1 = "cat_a_item_1"
/ 2 = "cat_a_item_2"
/ 3 = "cat_a_item_3"
/ 4 = "cat_a_item_4"
</item>
<item cat_b_items>
/ 1 = "cat_b_item_1"
/ 2 = "cat_b_item_2"
/ 3 = "cat_b_item_3"
/ 4 = "cat_b_item_4"
</item>
<item cat_1_items>
/ 1 = "cat_1_item_1"
/ 2 = "cat_1_item_2"
/ 3 = "cat_1_item_3"
/ 4 = "cat_1_item_4"
</item>
<item cat_2_items>
/ 1 = "cat_2_item_1"
/ 2 = "cat_2_item_2"
/ 3 = "cat_2_item_3"
/ 4 = "cat_2_item_4"
</item>
As you can see, it's not that hard...
|
|
Group: Awaiting Activation
Posts: 7,
Visits: 38
|
Fantastic, thank you so very much!
|