Millisecond Forums

You need two <trial> elements to do that. One that displays the sentence (and accepts the spacebar response), followed by one that displays the associated picture.

Hi,

I have no idea how to present a pair of trials. In my experiment there should be about 100 of such pairs. The sentence-picture items should be presented in random order, but the pairing is predetermined. Could you give me some guidance?

Thanks,
Diane

Sure, it's pretty easy:

<block myblock>
/ trials = [1-4=sequence(sentencetrial, picturetrial)]
</block>

<trial sentencetrial>
/ stimulusframes = [1=mysentence]
/ validresponse = (57)
</trial>

<trial picturetrial>
/ stimulusframes = [1=mypicture]
/ validresponse = (57)
</trial>

<text mysentence>
/ items = ("Sentence A", "Sentence B", "Sentence C", "Sentence D")
/ position = (50%, 25%)
/ select = noreplace
/ erase = false
</text>

<text mypicture>
/ items = ("Picture A", "Picture B", "Picture C", "Picture D")
/ position = (50%, 50%)
/ select = text.mysentence.currentindex
</text>

or alternatively

<block myblock>
/ trials = [1-4=sentencetrial]
</block>

<trial sentencetrial>
/ stimulusframes = [1=mysentence]
/ validresponse = (57)
/ branch = [trial.picturetrial]
</trial>

<trial picturetrial>
/ stimulusframes = [1=mypicture]
/ validresponse = (57)
</trial>

<text mysentence>
/ items = ("Sentence A", "Sentence B", "Sentence C", "Sentence D")
/ position = (50%, 25%)
/ select = noreplace
/ erase = false
</text>

<text mypicture>
/ items = ("Picture A", "Picture B", "Picture C", "Picture D")
/ position = (50%, 50%)
/ select = text.mysentence.currentindex
</text>

Great, thanks a lot!