Millisecond Forums

/trials = [1-48=noreplace(block1); 49=break; 50-98=noreplace(block2)]

Sampling randomly without replacement from a pool consisting of one element is equivalent to

1-48 = block1;

It does not "make sense". It is also equivalent to

1-48 = replace(block1); or
1-48 = sequence(block1);

If you have a deck of 48 *perfectly* identical cards, it does not matter whether you draw those with or without replacement or even sequentially.

In the above, you are sampling *<trial>* elements. It has *nothing whatsoever* to do with how those <trial> elements might sample from any *stimulus elements* (<text>, <picture>, etc.) they might display.

If you have a stimulus with several, *different* items

<text mytext>
/ items = ("A", "B", "C")
...
</text>

obviously the way you sample from that element makes a difference. noreplace, replace, sequence will all give you different results as they should. Try this for yourself.

As for your "combinations" question: What you ought to do is set up the picture / question pairs you want / need (please review the "How to Present Stimulus Pairs" topic in the documentation thoroughly) and then sample from those combinations without replacement.

Thanks Dave!

I did read the documentation (http://www.millisecond.com/support/docs/v4/Inquisit.pdf) and the specific part but the explanation was very short for me completely understand how paired stimuli can be presented. I understand that was trial attribute if there is only one trial, it really doesn't matter if you add the function of 'noreplace' or not. However, for presenting the stimuli in pairs, as in my case, 12 faces with 4 Qs each (48 trials) would the following ensure that each face has been presented with each of the 4 Qs?

/trials = [1-48=block1; 49=break; 50-98=block2]

<trial block1>
/ pretrialpause = 1000
/ validresponse = ("d", "k")
/ stimulustimes = [0 = fixation; 1000 = block1faces; 1500 = Questions1]
</trial>

<trial block2>
/ pretrialpause = 1000
/ validresponse = ("d", "k")
/ stimulustimes = [0 = fixation; 1000 = block2faces; 1500 = Questions2]
</trial>

<picture block1faces>
/ items = block1faces
/ size = (250, 250)
/ position = (50, 50)
/ select = noreplace
</picture>

<picture block2faces>
/ items = block2faces
/ size = (250, 250)
/ position = (50, 50)
/ select = noreplace
</picture>

<text Questions1>
/ items = questions1
/ select = noreplace
/ position = (50, 50)
/ size = (5 in, 3 in)
/ vjustify = center
/ fontstyle = ("Garamond", 3%, true)
</text>

<text Questions2>
/ items = questions2
/ select = noreplace
/ position = (50, 50)
/ size = (5 in, 3 in)
/ vjustify = center
/ fontstyle = ("Garamond", 3%, true)
</text>

<item questions1>
/1 = "QQQ?"
/2 = "AAA?"
/3 = "MMM?"
/4 = "VVV?"
</item>

<item questions2>
/1 = "nnn?"
/2 = "ooo?"
/3 = "fff?"
/4 = "hhh?"
</item>

<item block1faces>
/1 = "face1.jpg"
/2 = "face2.jpg"
/3 = "face3.jpg"
/4 = "face4.jpg"
/5 = "face5.jpg"
/6 = "face6.jpg"
/7 = "face7.jpg"
/8 = "face8.jpg"
/9 = "face9.jpg"
/10 = "face10.jpg"
/11 = "face11.jpg"
/12 = "face12.jpg"

<item block2faces>
/1 = "face1.jpg"
/2 = "face2.jpg"
/3 = "face3.jpg"
/4 = "face4.jpg"
/5 = "face5.jpg"
/6 = "face6.jpg"
/7 = "face7.jpg"
/8 = "face8.jpg"
/9 = "face9.jpg"
/10 = "face10.jpg"
/11 = "face11.jpg"

Thanks,
-G

No. Nowhere do you define any relationship between the pictures and the questions. Instead you sample from both without replacement (noreplace). You need to fix that. This isn't hard:

<block myblock>
/ trials = [1-48=mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=face,question]
/ validresponse = (57)
</trial>

<text face>
/ items = faceitems
/ select = list.facelist.nextvalue
/ position = (50%, 40%)
</text>

<text question>
/ items = questionitems
/ select = list.questionlist.nextvalue
/ position = (50%, 60%)
</text>


*** Each face must be displayed 4 times, once with every of the 4 questions ***
<list facelist>
/ items = (1,1,1,1,2,2,2,2,3,3,3,3,4,4,4,4,5,5,5,5,6,6,6,6,7,7,7,7,8,8,8,8,9,9,9,9,10,10,10,10,11,11,11,11,12,12,12,12)
</list>

<list questionlist>
/ items = (1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4)
/ selectionmode = list.facelist.currentindex  
</list>



<item faceitems>
/ 1 = "Face 1"
/ 2 = "Face 2"
/ 3 = "Face 3"
/ 4 = "Face 4"
/ 5 = "Face 5"
/ 6 = "Face 6"
/ 7 = "Face 7"
/ 8 = "Face 8"
/ 9 = "Face 9"
/ 10 = "Face 10"
/ 11 = "Face 11"
/ 12 = "Face 12"
</item>

<item questionitems>
/ 1 = "Question 1"
/ 2 = "Question 2"
/ 3 = "Question 3"
/ 4 = "Question 4"
</item>

Ah! OK. That was very helpful! Thanks Dave!

One last quick Q: So when I set up the experiment as you have explained below, are the faces paired with each item occur randomly? As in, I do not want the same face (e.g., 1) to be presented serially 4 times for Qs 1, 2, 3, and 4 and then face 2 with the 4 Qs etc. I do not see anywhere specified that the pairs be presented randomly. Thanks a to, again! - G

<list facelist>
/ items = (1,1,1,1,2,2,2,2,3,3,3,3,4,4,4,4,5,5,5,5,6,6,6,6,7,7,7,7,8,8,8,8,9,9,9,9,10,10,10,10,11,11,11,11,12,12,12,12)
</list>
<list questionlist>
/ items = (1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4)
/ selectionmode = list.facelist.currentindex   
</list>

<list> elements -- just like any other element -- will sample randomly without replacement by default.

It is perfectly possible for the same item to be sampled on consecutive trials -- after all, every item is present 4 times in the pool. If you want to avoid that, make use of the /maxrunsize attribute.

Great! Thanks again Dave!

So, if I do the following, then it is assured that each face is presented 4 times, once with each of the 4 Qs and without being repeated consecutively, did I get this correct?

<list facelist>
/ items = (1,1,1,1,2,2,2,2,3,3,3,3,4,4,4,4,5,5,5,5,6,6,6,6,7,7,7,7,8,8,8,8,9,9,9,9,10,10,10,10,11,11,11,11,12,12,12,12)
/ maxrunsize = 1
</list>

<list questionlist>
/ items = (1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4,1,2,3,4)
/ selectionmode = list.facelist.currentindex   
/ maxrunsize = 1
</list>

Thanks again,
-G

You don't need maxrunsize on the second list. It's selection depends on the 1st one anyway.

I thought so, but wanted to check. Thanks you very much Dave!