Millisecond Forums

Yes, it's possible. You need to use the <trial> element's insertstimulustime() etc. functions to do this. You cannot use <values> in the way you sketched.

See e.g. https://www.millisecond.com/forums/Topic10374.aspx#bm11148

For further details, see the language reference for the functions mentioned above.

That's perfect Dave!

One other (I think simple) question: In my code do you know why I am receiving the 'Expression " is invalid. Expression is empty.' error message?  I have a text element declared that gets filled when a list cycles values, which I've done before, but it isn't working this time.

/ontrialbegin = [if ((values.diceoutcome > 50 ) values.highnumcolor = list.highdemandcolor.nextvalue]


Notice the additional (superfluous / unmatched) parenthesis.

My mistake I had since fixed that error.  The other error is unrelated to that I think.

It is the element "text.highnumber" showing the error.

This won't work / is invalid syntax:

<text highnumber>
/items = ("")
/position = (50%, values.numbery)
/fontstyle = ("Arial", values.focussize, true, false, false, false, 5, 0)
/txcolor = (values.highnumcolor)
/txbgcolor = (white)
/select = values.numberget
</text>

The way to do this is defining

<text highnumber>
/items = ("")
/position = (50%, values.numbery)
/fontstyle = ("Arial", values.focussize, true, false, false, false, 5, 0)
/txbgcolor = (white)
/select = values.numberget
</text>

and then doing

/ ontrialbegin = [text.highnumber.textcolor=values.highnumcolor]

Also, you need to get rid of the double-quotes in

<list highdemandcolor>
    /items = (yellow, blue)
    /replace = false
    /selectionrate = trial
</list>

for the items to be interpreted as colors.

Ah got it.  It's working now.  

For your previous post I need to declare each stimulus frame as a separate line correct?  When I separated them by semi-colons it didn't work.

For example)
"/ontrialbegin = [if ((values.randomposition == 1) && (trial.InitialSelect.response == "patch1") && (values.randomdemand == "lowpatch1")) trial.patchtrial.setstimulusframe(focus, 1);]
/ontrialbegin = [if ((values.randomposition == 1) && (trial.InitialSelect.response == "patch1") && (values.randomdemand == "lowpatch1")) trial.patchtrial.setstimulusframe(choose, 1);]"

No, you do not. You need to use curly braces to bundle all the statements to be executed under the if-condition;

/ ontrialbegin = [if (true) { do stuff; do more stuff; do even more stuff; }]

Also, it's not clear to me why you use setstimulusframe() in both statements. You would only use it in the 1st and then insertstimulusframe() in all subsequent ones:

<list fixationduration>
/ items = (500, 5000, 10000)
</list>


<trial mytrial>
/ ontrialbegin = [if (true) {trial.mytrial.setstimulustime(text.a, list.fixationduration.nextvalue);
    trial.mytrial.insertstimulustime(text.b, list.fixationduration.nextvalue); }]
/ ontrialend = [trial.mytrial.resetstimulusframes()]
/ stimulustimes = [0=fixation]
/ validresponse = (57)
</trial>

<text fixation>
/ items = ("+")
</text>

<text a>
/ items = ("A")
/ position = (45%, 50%)
</text>

<text b>
/ items = ("B")
/ position = (55%, 50%)
</text>

<block myblock>
/ trials = [1-3=mytrial]
</block>