Millisecond Forums

Wonderful... this works great!
Thanks a lot!

You retrieve it via the stimulus element's currentitem property. Going back to my original example:

<block myblock>
/ trials = [1-2=mytrial]
</block>

<values>
/ myvalue = ""
</values>


<trial mytrial>
/ ontrialend = [if (trial.mytrial.response == "a") values.myvalue = text.a.currentitem]
/ ontrialend = [if (trial.mytrial.response == "b") values.myvalue = text.b.currentitem]
/ ontrialend = [if (trial.mytrial.response == "c") values.myvalue = text.c.currentitem]
/ stimulusframes = [1=a,b,c]
/ validresponse = (a,b,c)
/ inputdevice = mouse
</trial>

<text a>
/ items = ("A1", "A2")
/ hposition = list.hpos.nextvalue
</text>

<text b>
/ items = ("B1", "B2")
/ hposition = list.hpos.nextvalue
</text>

<text c>
/ items = ("C1", "C2")
/ hposition = list.hpos.nextvalue
</text>

<list hpos>
/ items = (35%, 50%, 65%)
/ selectionrate = always
</list>

<data>
/ columns = [response latency values.myvalue]
</data>

I meant to include the script in the original post but had problems with the upload. 
Here is the dropbox link to the task and stimuli - please enter 3000 for subject number. 
https://www.dropbox.com/s/h1jh66q4a5dk3v7/GardnerMatrix.zip?dl=0 

I didn't describe the script right... it does assign a position to stimuli, as you mention. However, I can't figure out how to get the stimuli that was associated to each "distractor" at each trial. 

Thanks!!

> The script randomly assigns the stimuli to spots in the 3 x 3 grid

Instead of assigning stimuli to positions (as the above suggests), you should assign positions to stimuli. Example:

<trial mytrial>
/ stimulusframes = [1=a,b,c]
/ validresponse = (a,b,c)
/ inputdevice = mouse
</trial>

<text a>
/ items = ("A")
/ hposition = list.hpos.nextvalue
</text>

<text b>
/ items = ("B")
/ hposition = list.hpos.nextvalue
</text>

<text c>
/ items = ("C")
/ hposition = list.hpos.nextvalue
</text>

<list hpos>
/ items = (35%, 50%, 65%)
/ selectionrate = always
</list>


Then you have the information you want directly.