showing randomly paired stimuli again in a second round in the same combination


showing randomly paired stimuli again in a second round in the same...
Author
Message
AKathryn
AKathryn
Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)Partner Member (712 reputation)
Group: Forum Members
Posts: 4, Visits: 22

Dear Inquisit community,

I am currently desingning an experiment in which participants have to evaluate fictional project partners (in terms of how much they would like to work with that person). I am presenting several potential partners, and always show a picture next to a short CV. Attractiveness in the picture varies as well as the competence of the person as suggested in the CV. In the end, the task should measure the value a person places on attractiveness as compared to the competence of a person. Picture and CV are paired randomly, so that every participant gets a different „set“ of potentional project partners.
Now the challenge: After showing all the pictures of all project partners, randomly paired with CVs and asking everytime how much the participant would like to work with that person, I want to do ANOTHER round of showing the same pictures paired with the same CVs as before, this time asking the participant how attractive and how competent they perceive the person as a manipulation check.
Here is my question: Is it somehow possible for Inquisit to track which combination it randomly showed before and to show this exact combination again in the second round?

Thank you so much for your help!
Best,
Kathryn


Dave
Dave
Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)Supreme Being (1M reputation)
Group: Administrators
Posts: 12K, Visits: 85K
Yes, it's perfectly possible. Two options:

(1) Pair your items randomly *at the beginning* of the experiment and then proceed as you would normally. See e.g. https://www.millisecond.com/forums/Topic2623.aspx for an example.

(2) Store the pairs *at runtime* in empty, linked <item> or <list> elements. Sample from those <item>s or <lists> for the repetition. Example:

<values>
/ personitem = 1
/ cvitem = 1
</values>

<expt>
/ blocks = [1=showrandompairs; 2=repeatrandompairs]
</expt>

<block showrandompairs>
/ trials = [1-4=show]
</block>

<block repeatrandompairs>
/ trials = [1-4=repeat]
</block>

<trial show>
/ ontrialbegin = [values.personitem=list.randomperson.nextindex; values.cvitem=list.randomcv.nextindex;
    list.repeatperson.appenditem(values.personitem); list.repeatcv.appenditem(values.cvitem); ]
/ stimulusframes = [1=person, cv]
/ validresponse = (57)
</trial>

<trial repeat>
/ ontrialbegin = [values.personitem=list.repeatperson.nextvalue; values.cvitem=list.repeatcv.nextvalue; ]
/ stimulusframes = [1=person, cv]
/ validresponse = (57)
</trial>

<text person>
/ items = personitems
/ select = values.personitem
/ position = (40%, 50%)
</text>

<text cv>
/ items = cvitems
/ select = values.cvitem
/ position = (60%, 50%)
</text>

<item personitems>
/ 1 = "Person A"
/ 2 = "Person B"
/ 3 = "Person C"
/ 4 = "Person D"
</item>

<item cvitems>
/ 1 = "CV 1"
/ 2 = "CV 2"
/ 3 = "CV 3"
/ 4 = "CV 4"
</item>

<list randomperson>
/ poolsize = 4
</list>

<list randomcv>
/ poolsize = 4
</list>

<list repeatperson>
</list>

<list repeatcv>
/ selectionmode = list.repeatperson.currentindex
</list>


GO

Merge Selected

Merge into selected topic...



Merge into merge target...



Merge into a specific topic ID...




Reading This Topic

Explore
Messages
Mentions
Search