Millisecond Forums

There are several issues here:

#1: The general flaw in the <trial> code you posted is the /validresponse attribute. It specifies the keys which are considered as valid response options. A press on *either one of them* will terminate the trial. So, you need not only care about evaluating *correct* responses, but first and foremost about *valid* responses.

#2: By default, a <trial> element collects a *single* response (here: a single keypress), not several. It is possible to get a <trial> to register several, but that requires some trickery using /isvalidresponse and /iscorrectresponse. The simple /validresponse and /correctresponse attributes are not applicable.

#3: You will have to work with keyboard scancodes -- not "literal" key values ("e", "i", etc.) -- because ultimately what the <trial>'s response property returns. See the "Keyboard Scan Codes" topic in the documentation as well as Tools -> Keyboard Scancodes... in Inquisit Lab's menu.

#4: There remains a certain risk that one of the key presses is not detected *if* both keys are indeed pressed at the exact same time. I don't see any sure-fire way to eliminate this risk entirely.

A short example is below:

<values>
/ first_key = 0
/ first_key_latency = 0
/ second_key = 0
/ second_key_latency = 0
/ correctkeys = ""
</values>

Relevant scancodes:
e = 18
r = 19
d = 32
f = 33

i = 23
o = 24
k = 37
l = 38

<trial one_1>
/ ontrialbegin = [values.first_key=0; values.first_key_latency=0;
    values.second_key=0; values.second_key_latency = 0;
    values.correctkeys = "18, 23"; ]
/ stimulusframes=[1=one]
/ validresponse = (18,19,32,33,23,24,37,38)
/ isvalidresponse = [if(values.first_key==0) {
    values.first_key=trial.one_1.response;
    values.first_key_latency=trial.one_1.latency;
    false; };
    if (values.first_key != 0 && trial.one_1.latency>values.first_key_latency) {
    values.second_key=trial.one_1.response;
    values.second_key_latency = trial.one_1.latency;
    false; };
    values.first_key != 0 && values.second_key != 0]
/ iscorrectresponse = [contains(values.correctkeys, values.first_key) && contains(values.correctkeys, values.second_key)]
/ trialduration = 1500
</trial>

<text one>
/ items = ("1")
</text>

<block myblock>
/ trials = [1-5 = one_1]
</block>

<data>
/ columns = [date time subject blocknum blockcode trialnum trialcode response latency correct values.first_key values.first_key_latency values.second_key values.second_key_latency]
/ separatefiles = true
</data>

Hope this helps.

Thank you very much for your help! :)