Millisecond Forums

To provide immediate error feeback, you need to specify the /errormessage attribute at either the <trial> or <block> level. To require a correct response before allowing to move on to the next trial, you need to set the /response attribute to correct.

<page practicepage>
This is practice.
</page>

<page testpage>
This is test.
</page>

<expt>
/ blocks = [1=practice; 2=test]
</expt>

<block practice>
/ preinstructions = (practicepage)
/ bgstim = (wordlabel, nonwordlabel)
/ trials = [1-4 = noreplace(wordtrial, nonwordtrial)]
/ response = correct
/ errormessage = true(errortxt, 500)
</block>

<block test>
/ preinstructions = (testpage)
/ bgstim = (wordlabel, nonwordlabel)
/ trials = [1-4 = noreplace(wordtrial, nonwordtrial)]
</block>

<trial wordtrial>
/ stimulusframes = [1=wordstim]
/ validresponse = ("w", "n")
/ correctresponse = ("w")
</trial>

<trial nonwordtrial>
/ stimulusframes = [1=nonwordstim]
/ validresponse = ("w", "n")
/ correctresponse = ("n")
</trial>

<text wordstim>
/ items = ("word 1", "word 2")
</text>

<text nonwordstim>
/ items = ("nonword 1", "nonword 2")
</text>

<text errortxt>
/ items = ("wrong answer")
/ position = (50%, 60%)
/ txcolor = red
</text>

<text wordlabel>
/ items = ("press w for word")
/ position = (25%, 10%)
</text>

<text nonwordlabel>
/ items = ("press n for nonword")
/ position = (75%, 10%)
</text>

Hi Dave,
So here is what I have for the practice trial block:
<block lexicalDecisionTaskPractice>
/preinstructions = (practicepage)
/ trials = [1=instructions; 2-11=noreplace(ldtneutralPractice, ldtnonwordPractice)]
/ response = correct
/ errormessage = true(errortxt, 500)
</block>

In the instructions, participants are told what buttons on the keyboard to press in order to identify words vs. non-words. Then they are told to press the spacebar in order to begin the practice trials. Right now, with the above script, when I press the spacebar to begin the practice trials, the red "x" is appearing and will not let me advance. Is there a way that I can have the instructions appear without that happening?

Thanks!

Yes. Simply make the spacebar the correct response in the <trial instructions>.

<trial instructions>
...
/ correctresponse = (57)
...
</trial>