Millisecond Forums

Yes, you need to pair your primes and target -- i.e., encode the desired combinations using e.g. <list> elements -- and then sample from those combinations. You'll find pairing stimuli covered in the "How to present stimulus pairs topic" in the Inquisit documentation.

For the sake of example, suppose you have 2 primes, 4 words and 4 nonwords. You want each prime to precede each word and nonword exactly once (16 combinations):

<values>
/ primeitem = 1
/ worditem = 1
/ nonworditem = 1
</values>

<block myblock>
/ trials = [1-16 = noreplace(wordtrial, nonwordtrial)]
</block>

<trial wordtrial>
/ ontrialbegin = [values.primeitem=list.wordprimelist.nextvalue; values.worditem=list.wordlist.nextvalue; ]
/ stimulustimes = [0=prime; 200=word]
/ validresponse = (57)
/ timeout = 500
</trial>

<trial nonwordtrial>
/ ontrialbegin = [values.primeitem=list.nonwordprimelist.nextvalue; values.nonworditem=list.wordlist.nextvalue; ]
/ stimulustimes = [0=prime; 200=nonword]
/ validresponse = (57)
/ timeout = 500
</trial>

<text prime>
/ items = ("Prime 1", "Prime 2")
/ select = values.primeitem
</text>

<text word>
/ items = ("Word 1", "Word 2", "Word 3", "Word 4")
/ select = values.worditem
</text>

<text nonword>
/ items = ("Nonword 1", "Nonword 2", "Nonword 3", "Nonword 4")
/ select = values.nonworditem
</text>

*** combinations of prime and word ***

<list wordprimelist>
/ items = (1,1,1,1,2,2,2,2)
</list>

<list wordlist>
/ items = (1,2,3,4,1,2,3,4)
/ selectionmode = list.wordprimelist.currentindex
</list>

*** combinations of prime and nonword ***

<list nonwordprimelist>
/ items = (1,1,1,1,2,2,2,2)
</list>

<list nonwordlist>
/ items = (1,2,3,4,1,2,3,4)
/ selectionmode = list.nonwordprimelist.currentindex
</list>

Thank you so much for your help!

Hi Dave,

I am trying to scale the example you gave up to experiment I am working on.  I am running into a couple of problems.

I think the main one is that my stimuli for the prime come from a bank of images that all fall into discrete categories, however we would like to randomize the exact image being presented.  I have attached a scaled down code and essentially the banks consist of 300 images.  When I run the code I think the number selection formatting means it selects the same image and presents it 10 times.

Is the fix to list out all 1-100 numbers in the list so that a unique image is selected each time?

I also am still not getting the precise randomization (1 unique word to 1 unique image per condition) to work out fully.

Thank you for your help with this.

Best,
Nicholas

I can see that you have 10 category words (serving as targets), 10 neutral word targets, 10 nonword targets, and 10 nonword2 targets. It is unclear to me how you want those paired or otherwise combined with the various prime-categories (consisting of 300 items per prime category) in your script.

> When I run the code I think the number selection formatting means it selects the same image and presents it 10 times.

Yes, because that's exactly what you specified.

<list categoryprimelist>
/items =   (1,1,1,1,1,1,1,1,1,1,
            2,2,2,2,2,2,2,2,2,2,
            3,3,3,3,3,3,3,3,3,3,
            4,4,4,4,4,4,4,4,4,4,
            5,5,5,5,5,5,5,5,5,5,
            6,6,6,6,6,6,6,6,6,6,
            7,7,7,7,7,7,7,7,7,7,
            8,8,8,8,8,8,8,8,8,8,
            9,9,9,9,9,9,9,9,9,9,
            10,10,10,10,10,10,10,10,10,10)
</list>

<list categorylist>
/items = (1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10,
          1,2,3,4,5,6,7,8,9,10)
/selectionmode = list.categoryprimelist.currentindex
</list>

You're only ever selecting items 1-10 for the "category" primes. You've paired those 10 items to the 10 category *targets*.

It seems to me that you actually want something like this, taking just two of your <trial>s as example:

<trial ldtcategory_0men>
/ ontrialbegin = [values.primeitem=list.0MFaceItemnumbers.nextindex; values.categoryitem=list.category_0M.nextindex;]
/ stimulustimes = [0=ready; 200=0MFace; 659=blank2; 700=category; 950=blank]
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/beginresponsetime = 700
</trial>

with

<list 0MFaceItemnumbers>
/ poolsize = 300
</list>

<list category_0M>
/ poolsize = 10
</list>

and

<trial ldtcategory_3men>
/ ontrialbegin = [values.primeitem=list.3MFaceItemnumbers.nextindex; values.categoryitem=list.category_0M.nextindex;]
/ stimulustimes = [0=ready; 200=3MFace; 659=blank2; 700=category; 900=blank]
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/beginresponsetime = 700
</trial>

<list 3MFaceItemnumbers>
/ poolsize = 300
</list>

<list category_0M>
/ poolsize = 10
</list>

and so forth.

In case I'm still misunderstanding your setup, it would be great if you could scale things down further to, say, only two or three categories with fewer items per category. Also, since I obviously don't have the images you'll be using, use only <text> elements in the example if possible (the type of stimulus you'll be using eventually -- <text>, <picture>, <video> and/or any combination thereof -- is immaterial to the randomization issue).

Thanks.

Hi Dave,

That worked wonderfully.  Thank you so much for your help with this!