Millisecond Forums

To elaborate a bit, I can't tell you if the "out of range" warnings point to a problem (in the sense of preventing the script from working as intended) or not. It depends on when / where they arise. Consider this example based on code posted previously in this thread. It will run 4 wordA trials -- thus there will be 4 item numbers in <list wordorder>.
<text e>, however, references a non-existent 5th item

<text e>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(5))%>: <%openended.five.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 80%)
/ erase = false
</text>

and -- when run --  the code will throw a warning similar to the ones you've reported. It's important to note here that this does not prevent this particular piece of code from working correctly. The situation may -- or may not -- be different in your case. So, to judge whether the warnings ought to be taken seriously or can be safely ignored, the first thing to do would be to assess whether your script (still) works as you intend it to despite the warnings.

Here's the example to illustrate:

<item wordA>
/1 = "smile"
/2 = "year"
/3 = "sea"
/4 = "peace"
/5 = "mud"
</item>

<item rhymeA_cue>
/1 = "isle"
/2 = "tier"
/3 = "three"
/4 = "geese"
/5 = "flood"
</item>

<text wordA>
/ items = wordA
/ fontstyle = ("Arial", 7%, false, false, false, false, 5, 0)
/ txcolor = (250, 34, 34)
</text>

<openended one>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 42%)
</openended>

<openended two>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 52%)
</openended>

<openended three>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 62%)
</openended>

<openended four>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 72%)
</openended>

<openended five>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 82%)
</openended>

<text a>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(1))%>: <%openended.one.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 40%)
/ erase = false
</text>

<text b>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(2))%>: <%openended.two.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 50%)
/ erase = false
</text>

<text c>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(3))%>: <%openended.three.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 60%)
/ erase = false
</text>

<text d>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(4))%>: <%openended.four.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 70%)
/ erase = false
</text>

<text e>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(5))%>: <%openended.five.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 80%)
/ erase = false
</text>

<trial wordA>
/ ontrialend = [
    list.wordorder.appenditem(text.wordA.currentindex)
]
/ stimulustimes = [0 = wordA]
/ timeout = 1000
/ posttrialpause = 500
</trial>

<list wordorder>
</list>

``
**********************************************************************************************
**********************************************************************************************
<block Group1_A>
/ trials = [1-4 = worda; 5=sequence(one,two,three,four)]
</block>

**********************************************************************************************
**********************************************************************************************
EXPERIMENT
**********************************************************************************************
**********************************************************************************************

<expt decisionMakingTask>
/ blocks = [1 = Group1_A]
</expt>

Ok, thanks,

Elena

Those are warnings, not errors. This will happen if there is no item in <item semanticA_cue> at whatever index list.wordorder.item(3) returns.

That's fine now thanks. I have tried with another computer and it works fine.
Error evaluating function'item.semanticA_cue.item(list.wordorder.item(3))':A parameter or result was out of range.
Any possible solution?

Thanks,

Elena

> When I start the experiment the images on the screen stay there...

What images?

> for instance I can see the dock of the Mac while playing the experiment.

Not sure how that relates to the above unless you consider the dock to be "image." I think you providing a screenshot could clarify. Overall, though, this sounds like a malfunctioning graphics card driver -- you may want to check if an update is available.

Thanks, It works.

Just a last thing. When I start the experiment the images on the screen stay there...for instance I can see the dock of the Mac while playing the experiment.
Any solution?

Thank you,

Elena

This is covered in the documentation for the <openended> element:

"

The openended element controls the timing and the content of stimulus presentation as well as how open-ended responses are obtained. Every time a openended element is executed, a line of data is written to the data file.

The respondent can advance past this trial by hitting ENTER if openended is single line expecting keyboard input, and Ctrl+ENTER if it's multiline or set to mouse input. The default input for openended is mouse input, which enables the respondent to advance by clicking the openended element's button."

Hi! Thank you for your reply, it works well thanks!!
How now can I make a participant go to the next openended just pressing the enter key of the keyboard without having to click the mouse?
Thanks,

Elena

This essentially still works exactly as outline previously. You need to record the order of presentation in a <list>, then you can display the corresponding cues:

<item wordA>
/1 = "smile"
/2 = "year"
/3 = "sea"
/4 = "peace"
/5 = "mud"
</item>

<item rhymeA_cue>
/1 = "isle"
/2 = "tier"
/3 = "three"
/4 = "geese"
/5 = "flood"
</item>

<text wordA>
/ items = wordA
/ fontstyle = ("Arial", 7%, false, false, false, false, 5, 0)
/ txcolor = (250, 34, 34)
</text>

<openended one>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 42%)
</openended>

<openended two>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 52%)
</openended>

<openended three>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 62%)
</openended>

<openended four>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 72%)
</openended>

<openended five>
/ stimulusframes = [1=a,b,c,d,e]
/ position = (60%, 82%)
</openended>

<text a>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(1))%>: <%openended.one.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 40%)
/ erase = false
</text>

<text b>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(2))%>: <%openended.two.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 50%)
/ erase = false
</text>

<text c>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(3))%>: <%openended.three.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 60%)
/ erase = false
</text>

<text d>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(4))%>: <%openended.four.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 70%)
/ erase = false
</text>

<text e>
/ items = ("<%item.rhymeA_cue.item(list.wordorder.item(5))%>: <%openended.five.response%>")
/ size = (40%, 5%)
/ hjustify = left
/ position = (50%, 80%)
/ erase = false
</text>

<trial wordA>
/ ontrialend = [
    list.wordorder.appenditem(text.wordA.currentindex)
]
/ stimulustimes = [0 = wordA]
/ timeout = 1000
/ posttrialpause = 500
</trial>

<list wordorder>
</list>

``
**********************************************************************************************
**********************************************************************************************
<block Group1_A>
/ trials = [1-5 = worda; 6=sequence(one,two,three,four,five)]
</block>

**********************************************************************************************
**********************************************************************************************
EXPERIMENT
**********************************************************************************************
**********************************************************************************************

<expt decisionMakingTask>
/ blocks = [1 = Group1_A]
</expt>

Thank you Supreme being,

Sorry I did not explain what I wanted well enough.
I would like to present randomly the 5 words from the list:
<item wordA>
/1 = "smile"
/2 = "year"
/3 = "sea"
/4 = "peace"
/5 = "mud"
</item>
And this is already done. (In the real experiment I would need to present 4 numbers_top or down between a word and another...but I have cut this now just to keep things simpler...I don't know if it helps).

I would like to record the presentation order of the words of that list and presenting the corresponding words (that rhyme with the previous list) from list <item rhymeA_cue>
<item rhymeA_cue>
/1 = "isle"
/2 = "tier"
/3 = "three"
/4 = "geese"
/5 = "flood"
</item>
These words should be presented on the left part of the screen all together from the beginning of the second block (myblock) and aligned on the right with the openended question where the participant will type what he/she recalls (and rhyme with the word on the left). After the participant presses "enter" key, the typed word will stay in that position and will be able to proceed to type the next word.
I attached an example of it ("test.png" and the inquisit file).

Many thanks,

Elena